mailのリストをtextでおとす

質問

MicroSoft OUTLOOKを使っています。Outlook Expressではない）。どんなメールが来ているかタイトルのリストを作成したいのです。どのようにすれば手に入りますか？
受信日時も同時に入ればよりありがたいです。

別の表現をすると、メールボックスのdirを取りたいのです。

よろしくお願い致します。

回答No.1

Wendy02 · ベストアンサー

Excel用に作ってみました。
Outlook　のセキュリティが働くので、途中で、はい(Y)を押します。

なお、この検索は受信箱のみです。

'<標準モジュール>
Option Explicit
Sub OutlookListup()
'Excel 用 Outlook のタイトル出力
'要参照設定:Microsoft Outlook xx Object Library
'Outlook のセキュリティが働いたら、はい(Y)を押す
Dim myOL　As Outlook.Application
Dim myNamespace As Outlook.NameSpace
Dim myFolder As MAPIFolder
Dim ml As MailItem, i As Long
Dim y As Long, m As Long, d As Long
'
On Error GoTo ErrHandler
Set myOL = New Outlook.Application
Set myNamespace = myOL.GetNamespace("MAPI")
Set myFolder = myNamespace.GetDefaultFolder(olFolderInbox)
'タイトル行を出力
　Range("A1").Resize(, 3).Value = Array("送信者", "タイトル", "送信日")
For i = 1 To myFolder.Items.Count
With myFolder.Items(i)
　 Cells(i + 1, 1).Value = .SentOnBehalfOfName
　 Cells(i + 1, 2).Value = .Subject
　 '.CreationTime をそのまま取れないことがある
　　y = Year(.CreationTime)
　　m = Month(.CreationTime)
　　d = Day(.CreationTime)
　 Cells(i + 1, 3).Value = y & "/" & m & "/" & d
End With
Next i
　Range("A1").Resize(, 3).EntireColumn.AutoFit
　On Error GoTo 0
ErrHandler:
　If Err.Number > 0 Then
　　MsgBox Err.Description
　End If
　Set myFolder = Nothing
　Set myNamespace = Nothing
　Set myOL = Nothing
　Beep
End Sub

お礼

遅くなりました。うまく行きました。ありがとうございます。1点問題があったのは、会議開催案内があると、エラーでとまってしまう事でした。これは、どのようにすれば、回避できるのでしょうか？