-PR-
解決済み

複数社員の名字により識別をさせ決まった記号を入れる

  • すぐに回答を!
  • 質問No.9280044
  • 閲覧数147
  • ありがとう数3
  • 気になる数0
  • 回答数4
  • コメント数0

お礼率 75% (3/4)

お世話になります、全くの素人で何もわかりませんがご教授お願いいたします。
社員の名字により識別をさせ決まった記号を入れる

藤井、藤巻、藤瀬、藤城田、秋川、秋丸田、丸山、春田、春日、田中、田丸

藤から始まる人には○、秋から始まる人には△、丸から始まる人は×、それ以外の人は除外
といれたいのですが、どのようにしたらいいのでしょうか。
通報する
  • 回答数4
  • 気になる
    質問をブックマークします。
    マイページでまとめて確認できます。

質問者が選んだベストアンサー

  • 回答No.1
レベル10

ベストアンサー率 48% (63/131)

Excel(エクセル) カテゴリマスター
こんな感じでどうでしょう、B2以降に名前が入っていて、A列に記号を表示するとします。
今後、変更や追加がある事を考慮してE2:F6を定義用エリアとしました。
A2セルに↓を入れて下にコピーしてください。
=IFERROR(VLOOKUP(LEFT(B2,1),$E$2:$F$6,2,FALSE),"除外")
お礼コメント
yaoya-san

お礼率 75% (3/4)

ありがとうございました。
説明不十分なものにかんしご対応いただき感謝いたします。
本当にありがとうございました。
投稿日時 - 2017-01-12 23:40:35
-PR-
-PR-

その他の回答 (全3件)

  • 回答No.4
レベル14

ベストアンサー率 44% (3093/7025)

Excel(エクセル) カテゴリマスター
既に3つの方法が提示されていますが他にもあります。
B2以下へ名字を入力したものとし、A2以下へ記号を代入する数式を設定するものとしたとき下記の数式を使うと同じ結果が得られます。
既に提示された関数を使う方法
回答No.1のVLOOKUP関数を使うとき
A2=IFERROR(VLOOKUP(LEFT(B2),{"藤","◯";"秋","△";"丸","×";"",""},2,FALSE),"除外")
回答No.2のCHOOSE関数を使うとき
A2=CHOOSE(MAX(({"藤";"秋";"丸";""}=LEFT(B2))*{1;2;3;4}+1),"除外","○","△","×","")
回答No.3のMID関数を使うとき
A2=IFERROR(MID(" ○△×",FIND(LEFT(B2)," 藤秋丸"),1),"除外")
今回のINDEX関数を使うとき
A2=IFERROR(INDEX({"○";"△";"×";""},MATCH(LEFT(B2),{"藤";"秋";"丸";""},0)),"除外")
回答No.1では「E2:F6を定義用エリア」を使っていますが質問の分類条件が少ないので数式内に配列を{}で括れば定義用エリアが不要になります。
また、定義用エリアの代わりに名前の定義を使うとセル番地の定義ミスを防げます。

定義名:Data
配列:={"藤","○";"秋","△";"丸","×";"",""} または =$E$2:$F$7 (但し、$F$7には ="" と言う数式を設定する)
尚、比較データのLEFT(B2)は正式な書式はLEFT(B2,1)ですが第2引数の1を省略できます。
また、MID関数の例で回答No.3と違う点はIF関数を省略するために対象文字列の先頭に空白を追加することでB列が未入力の行に対する帰り値を" "(空白1文字)にしています。(但し、最終処理ではTRIM関数で空白の1文字を削除して""に置き換えます)
更に、OFFSET関数を使う方法もありますが省略します。
仕事に使うのであればこのサイトで質問するよりExcelの入門書や応用の参考書で学習すべきです。
他人が組み立てた数式は解読ができなければ他の用途に転用できませんので毎回質問しなければならなくなり甘えから抜けきれなくなります。
お礼コメント
yaoya-san

お礼率 75% (3/4)

わかりやすいご説明ありがとうございました。
今後は質問をしないよう勉強させていただきます。
ありがとうございました。
投稿日時 - 2017-01-12 23:31:45

  • 回答No.3
レベル10

ベストアンサー率 34% (66/192)

=IF(A1="","",IFERROR(MID("○△×",FIND(LEFT(A1),"藤秋丸"),1),"除外"))

でも。
お礼コメント
yaoya-san

お礼率 75% (3/4)

お忙しい所ご教授ありがとうございました。
こちらの方法もためさせていただきます。
投稿日時 - 2017-01-12 23:39:22
  • 回答No.2
レベル10

ベストアンサー率 34% (66/192)

=CHOOSE(SUM((LEFT(A1)={"藤","秋","丸"})*{1,2,3})+1,"除外","○","△","×")

とか。
このQ&Aで解決しましたか?
AIエージェント「あい」

こんにちは。AIエージェントの「あい」です。
あなたの悩みに、OKWAVE 3,500万件のQ&Aを分析して最適な回答をご提案します。

関連するQ&A
-PR-
-PR-
このやり方知ってる!同じこと困ったことある。経験を教えて!
このQ&Aにはまだコメントがありません。
あなたの思ったこと、知っていることをここにコメントしてみましょう。

その他の関連するQ&A、テーマをキーワードで探す

キーワードでQ&A、テーマを検索する
-PR-
-PR-
-PR-

特集


新大学生・新社会人のパソコンの悩みを解決!

-PR-

ピックアップ

-PR-
ページ先頭へ