エクセルで、複数年にまたがる期間を、年ごとに日数計算できないかと思って

質問

エクセルで、複数年にまたがる期間を、年ごとに日数計算できないかと思っています。

例：平成２０年３月１日～平成２１年５月１０日を
(1)平成２０年３月１日～平成２０年１２月３１日＝○○日
(2)平成２１年１月１日～平成２１年５月１０日＝○○日

といった感じで、年ごとに自動的に分けて計算できる方法を探しています。（期間については、２～３年にまたがることもあります。）

どなたか良い方法を教えていただけませんか？

回答No.4

soixante

＃１の者です。
＞Stday = Cells(1, 1).Value、Edday = Cells(1, 2).Valueの部分を変えればいいのでしょうか？

はい。Stday はスタート日、Edday はエンド日としています。
他の部分もそれにあわせて変える必要はありますが、Cells　というのは、R1C1形式ですので、丁寧に見ていただければ分かると思います。
念のため、簡単な解説コメントを足したコードを以下に記します。
＃１の回答の代わりに以下を貼っても構いません。
VBAでは、文頭に’がついている文は解説文として色が変わりますのでコードには影響が出ません。
---------------------------------------------------------------------
Sub 日数計算()

'変数宣言
Dim r As Integer, c As Integer, p As Integer
Dim Stday As Date, Edday As Date
On Error GoTo ErrShori

'開始日、終了日のセット
Stday = Cells(1, 1).Value
Edday = Cells(1, 2).Value

'前回分の内容を消す
Range(Cells(2, 1), Cells(Rows.Count, 3)).ClearContents
Cells(1, 3).ClearContents

'開始日、終了日の関係によって場合分け処理

'開始日より終了日のほうが古い場合、エラーメッセージを出して終了
If Stday > Edday Then
MsgBox "開始日と終了日の設定が間違っています。"
Exit Sub

'開始日と終了日が同じ場合
ElseIf Stday = Edday Then
Range(Cells(2, 1), Cells(2, 2)).Value = Stday
Cells(2, 3).Value = 0

'開始日と終了日が同じ年の場合
ElseIf Year(Stday) = Year(Edday) Then
Cells(2, 1).Value = Stday
Cells(2, 2).Value = Edday
Cells(2, 3).Value = Cells(2, 2).Value - Cells(2, 1).Value + 1

'開始日と終了日が年が異なる場合
Else
p = Year(Edday) - Year(Stday) + 1
Cells(2, 1).Value = Stday
Cells(2, 2).Value = DateSerial(Year(Stday), 12, 31)
Cells(2, 3).Value = Cells(2, 2).Value - Cells(2, 1).Value + 1

For r = 2 To p
Cells(r + 1, 1).Value = DateSerial(Year(Stday) + r - 1, 1, 1)
Cells(r + 1, 2).Value = DateSerial(Year(Stday) + r - 1, 12, 31)
Cells(r + 1, 3).Value = Cells(r + 1, 2) - Cells(r + 1, 1) + 1
Next r
Cells(p + 1, 2).Value = Edday
Cells(p + 1, 3).Value = Cells(p + 1, 2) - Cells(p + 1, 1)
End If

'A列、B列、C列の書式設定
Range(Columns(1), Columns(2)).NumberFormatLocal = "ggge年m月d日"
Columns(3).NumberFormatLocal = "0"

'経過日数の合計
With Cells(1, 3)
.Value = Application.WorksheetFunction.Sum(Range(Cells(2, 3), Cells(Rows.Count, 3)))
.NumberFormatLocal = "#,###"
End With
Exit Sub

'エラー（開始日・処理日に文字などを入力されたなど）発生時は終了させる
ErrShori:
MsgBox "エラーのため終了します"

End Sub

お礼

説明込みでわかりやすいです。ありがとうございます。
試してみます。