エクセルで横表記の日付を縦に取得するには？

質問

以下のような生産予定表があるとします。
　　　Ａ　　　　Ｂ　　　　Ｃ　　　　Ｄ　　　Ｅ　　　　Ｆ　　　　Ｇ　　　Ｆ
１　日程　生産日　３／１　３／２　３／３　３／４　３／５　３／６
２〔兵器〕月合計　　
３　戦車　　１０　　　１０
４　空母　　　５　　　　　　　　５
５　爆弾　１００　　　　　　　　　　　　　３０　　７０
６機関銃　　５０　　　　　　　　　　　　　　　　　５０
７潜水艦　　　４　　　　　　　　　　　　　　　　　　２　　　
８　軍艦　　　３　　　　　　　　　　　　　　　　　　　　　　　３
９　零戦　　３０　　　　　　　　　　　　　　　　　　　　　　　２０　　１０

この生産表から兵器名の横に列を挿入して、横表記の生産日を縦に追加表記したく、IF関数にLOOKUP+MAXまたはMIN関数、OFFSET+MATCH関数で取得できたのですが、生産が2日にまたがっている爆弾と零戦は数量の大小関係なく、先に予定の入っている日を取得したいのですが、この条件の付け方、関数表記が分からず、2日間に渡る生産兵器の場合は若い日を表記させるにはどういう条件区別が必要でしょうか?

　MAXやMIN、LARGE等の関数では先に取得したい日が、台数変動に伴い、後の日が取得されてしまいます。
　　　　Ａ　　　　Ｂ　　　　Ｃ　　　　Ｄ　　　Ｅ　　　　Ｆ　　　　Ｇ　　　Ｆ
　　　　　　　　　　　　　３／１　３／２　３／３　３／４　３／５　３／６
　　　　　　月合計
３　3/1戦車　　１０　　
４　3/2空母　　　５　　　　　
５　3/3爆弾　１００　　　　　　　　　　　　
６3/4機関銃　　５０　　　　　　　　　　　　　　
７3/4潜水艦　　　４　　　　　　　　　　　　　　　　　
８　3/5軍艦　　　３　
９　3/5零戦　　３０　
　※2日間の数量大小に影響されず、2日またがり生産兵器の初日を必ず取得する方法を教えていただけませんか？

回答No.2

noname#52504 · ベストアンサー

こんな感じでいかがでしょう。

　=INDEX($C$1:$N$1,MATCH(TRUE,INDEX(C3:N3<>"",),0))

Excel2003で動作確認済。

C3:N3の各セルについて「空白でない」か否かの判定を行い、
TRUEが返る最初の要素の位置を取得して、C1:N1から対応するセルを返す。

内側のINDEXは、配列として処理させるためのダミー関数です。
　=INDEX($C$1:$N$1,MATCH(TRUE,C3:N3<>"",0))
をCtrl＋Shift＋Enterで確定してもOK。

あるいは、判定でTRUEが返るセルについて、列番号の逆数をとり、
MAXで最初のセルを選んでから逆数を取り直せば、列番号が得られます。
　=OFFSET($A$1,0,1/MAX(INDEX((C2:N2<>"")/COLUMN(C2:N2),))-1)

以上ご参考まで。

■日経PC21 / エクセル「配列数式」講座
http://pc.nikkeibp.co.jp/pc21/special/hr/index.shtml

お礼

回答有難うございます。早々、ご教導いただいた方法を試してみます。

補足

補足の欄をお借りして、お礼申し上げます。回答者様のお答えで空白でないC3:F9までの配列の、各行の先頭の数値を取得できたのですが、どうも配列数式を普段、殆ど使わないもので、今一、理解に苦しんでいます。（INDEX関数の列番号、行番号のどちらから取得するのか？日付行のC1:F1にOFFSET関数と複合しましたが、エラーばかり出ます。）

　配列数式を使わないのは、後からの数式変更、編集がやりにくいのでは？と私個人が思っているだけなんですが。

　任意のセル領域、配列の中で、各行にある、1個または2個、複数の数値の内、空白以外の先頭の数値をMATCH関数で取得することです。
　配列数式を使わない、セル参照方式で式を組めば、どうなるか今考えております。
　有難うございました。

回答No.1

kosouitom

生産予定表の列数がこれ以上増えないという前提なら、
日付を取得したい列に

=IF(ISBLANK(E4),IF(ISBLANK(F4),IF(ISBLANK(G4),IF(ISBLANK(H4),IF(ISBLANK(I4),IF(ISBLANK(J4),"-",$J$2),$I$2),$H$2),$G$2),$F$2),$E$2)

という式を作成すれば取得できます。
ただ、列数がさらに増える場合はネストできるレベルに限界がある為、この方法では無理ですが・・・

お礼

回答有難うございました。参考にさせていただきます。
日が一ヶ月分あるので、この方法も考えましたが、無理みたいです。どちらか2日間の先の日を取得する（数量無関係に）方法を今も検討中です。
　LOOKUP(MAX(C3:F3,C3:F3,$C$1:$F$1)
またはOFFSET($B$1,0,MATCH(MIN(C3:F3),C3:F3,0)でも出せたのですが初日取得するための条件区別を考えています。