ＶＢＡでテキストファイルの読み書き

質問

ＥｘｃｅｌＶＢＡで、テキストファイルの読み込みと書き換えについて教えてください。
現在は「LINE　Input」で一行を読み込み、MIDで文字列を読み込んだり、書き換えていました。
が・・・それは「１文字目から５文字目まで」と決まった位置で書いてあるというのが大前提です。
でも、いつもそうとは決まっていません。当然いろいろな形があるわけです。

５００▲▲６．５４▲９９９９９▲▲▲▲ＤＤＤ▲▲
３０００▲４０▲▲▲▲ＰＰＰ▲６０．４５▲▲
ＡＡＡ▲ＣＣＣ▲８０．４５▲６６６▲７７７▲

（見にくいのですが▲はスペースです）などかなり不規則に並んでいる物があります。
「１行目の３番目の数値」（この場合だと９９９９９）をうまく取り出すにはどうしたら良いのでしょうか？
当然その前の５００と６．５４はどんな数値になっているかわかりませんし、スペースの数も不規則です。
取り出す値の桁数だって決まっている訳じゃありません。
この場合は▲をスペースとしていますが、当然タブで区切られていることも予想できます。
かなりいい加減なデータテキストファイルなのですが、決まっているのは「１行目の３番目の数値」ということだけなのです。
一文字一文字、スペースかタブか文字か？と認識する必要があるのはわかるのですが、切り貼りがうまくできないのです。
文字とスペース（もしくはタブ）を認識してそれを変数に取っておいて、文字をくっつけたりするのでしょうが・・・なかなかうまくいきません。
変数とかもいろいろ用意しているのに・・・根本ができていないようです。
何かわかりやすくて、いい方法を教えていただけないでしょうか？昨日はずっとこれをしていたのですが、目当ての物を取り出せずにいました。どうかお力をお貸しください。よろしくお願いします。

回答No.8

imogasi · ベストアンサー

＃７について。
（データ）スペースは全角で、▲の数だけいれてます。
OKWEBでは、崩れるようですがご留意を。
５００ ６．５４ ９９９９９ ＤＤＤ
３０００ ４０ ＰＰＰ ６０．４５
ＡＡＡ ＣＣＣ ８０．４５ ６６６ ７７７
（コード）
Sub test01()
g = InputBox("何行目＝")
n = 0
Open "c:\My Documents\aaa11.txt" For Input As #1
While Not EOF(1)
n = n + 1
Line Input #1, a
a = WorksheetFunction.Trim(a)
If n = Val(g) Then
c = Split(a, " ") '半角スペース
b = InputBox("何番目＝1-" & UBound(c) + 1 & "以下")
r = Val(b) - 1
MsgBox c(r)
End If
Wend
Close #1
End Sub
ではうまく行くようですが。
何番目と言う、入力数字の範囲を表示するように変えました。この範囲の正整数を入れて見てください。

お礼

回答ありがとうございます。遅い時間にまで答えてくださって本当に助かりました。動作完璧です。きちんと取れました。明日の月曜日が先ほどまで憂鬱で仕方がなかったのですが、おかげさまで解消しました。どれほどお礼を申し上げたらよいのやら・・・・。私のポイントを削ってもいっぱい差し上げたいのですが、２０ｐｔで許してください。本当にありがとうございました。

回答No.7

imogasi

＃６です。訂正版を上げます。
Sub test01()
g = InputBox("何行目＝")
n = 0
Open "c:\My Documents\aaa11.txt" For Input As #1
While Not EOF(1)
n = n + 1
Line Input #1, a
a = WorksheetFunction.Trim(a)
If n = Val(g) Then
b = InputBox("何番目＝")
c = Split(a, " ") '半角スペース
r = Val(b) - 1
MsgBox c(r)
End If
Wend
Close #1
End Sub
エクセルのTRIM関数は文字列間の複数スペースを
半角１スペースにしてくれると言うのを思い出して
使ってみましたので、１行増だけです。

お礼

回答ありがとうございます。何度も教えて頂いて本当に嬉しいです。早速貼り付けて見ましたところ・・・・「MsgBox c(r)」でインデックスエラーが出てしまいました。それがなぜだかわからない・・・・。私の力不足でいつも聞いてばかりですみません。

回答No.6

imogasi

#3,#5です。
済みません。間違えていました。
c = Split(a, "　")
は１全角スペースごとに分割して、配列にいれるようです。
５００▲▲６．５４▲９９９９９▲▲▲▲ＤＤＤ▲▲
の場合C(0)に500,C(1)に空白、C(2)に6.54と言う風に。
そのためずれる場合が出てきます。
取りあえず、お手数をお掛けしたことをお詫びします。
訂正分は機会があればまた載せます。

回答No.5

imogasi

#3です。
＞ずれているようなのですが
そうですね。テストデータでテストした時私も経験しました。スペースに半角と全角が混じったりしているのでは
と思い、統一して見ましたら、ズレがなくなりました。
データについて、その辺をチェックして見てください。

お礼

回答ありがとうございます。スペースの代わりに最初のテキスト通り「▲」で試してみましたが、やっぱりずれてしまいました。なぜだろう・・・。もうちょっと研究してみます。ありがとうございます。助かりました。

回答No.4

nishi6

メニューから、ファイル→開く　でファイルの種類をテキストファイルにして『開く』

テキストファイルウイザード1/3で
　　カンマやタブなどの区切り・・・　にチェック　→次へ

テキストファイルウイザード2/3で
　　タブとスペースにチェック
　　連続した区切り文字は１文字として扱う　にチェック　→次へ

テキストファイルウイザード3/3で
　　不要な項目があれば削除します。→完了

　　　しかし、
　　　「１行目の３番目の数値」が理解に苦しみます。（特に『目』の意味）

　　　５００▲▲６．５４▲９９９９９▲▲▲▲ＤＤＤ▲▲
　　　３０００▲４０▲▲▲▲ＰＰＰ▲６０．４５▲▲
　　　ＡＡＡ▲ＣＣＣ▲８０．４５▲６６６▲７７７▲

　　　の『３０００▲４０▲▲▲▲ＰＰＰ▲６０．４５▲▲　』は２行目？
　　　それとも、『６０.４５』も３番目の数字でしょうか。

『９９９９９』、『６０．４５』、『７７７』を求めるなら、
データがある箇所を選択しておいて、
　編集→ジャンプ→セル選択→定数だけを選択し、文字のみにチェック→ＯＫ
　文字列が選択された箇所で、右クリックして削除→左方向にシフト　でＯＫ
これで３番目がすぐ分かります。

上の機能を書いてみると、下のようになりました。
3番目の項目のみをA1セルから下方向に書き出します。
『Filename=』を書き換えてください。（当方、Excel2000です）

解答すると、2個続きの半角スペースが書き換わるので、" " & " " と表現しています。

Sub FileRead()
　　Dim Filename As String　　　　　　　'// ファイル名
　　　　Filename = "D:\009\TEST.txt"

　　Dim FileNo As Integer　　　　　　　 '// ファイル番号
　　Dim rw As Integer　　　　　　　　　 '// 行カウンタ
　　Dim Rec As String　　　　　　　　　 '// レコード
　　Dim ary As Variant　　　　　　　　　'// 分割後レコードデータ
　　Dim k As Integer　　　　　　　　　　'// 項目カウンタ(ループ)
　　Dim kT As Integer　　　　　　　　　 '// 項目カウンタ

　　FileNo = FreeFile
　　Open Filename For Input As #FileNo

　　'// ファイルの最後まで読み込む。（該当データをA1から書き出す）
　　While Not EOF(FileNo)
　　　　Line Input #FileNo, Rec

　　　　　　'// タブを半角スペースに置き換え
　　　　　　Rec = Application.Substitute(Rec, Chr(9), " ")

　　　　　　'// 複数の半角スペースを１つにする
　　　　　　While InStr(Rec, " " & " ")
　　　　　　　　Rec = Application.Substitute(Rec, " " & " ", " ")
　　　　　　Wend

　　　　'// データレコードを分割する
　　　　If Rec <> "" Then
　　　　　　ary = Split(Rec, " ")

　　　　　　'// 数値と評価した３個目のデータをセルに書き出す
　　　　　　kT = 0
　　　　　　For k = 0 To UBound(ary)
　　　　　　　　If IsNumeric(ary(k)) Then
　　　　　　　　　　kT = kT + 1
　　　　　　　　　　If kT = 3 Then
　　　　　　　　　　　　rw = rw + 1: Cells(rw, 1) = Val(ary(k))
　　　　　　　　　　　　Exit For
　　　　　　　　　　End If
　　　　　　　　End If
　　　　　　Next
　　　　End If

　　Wend
　　Close

End Sub

お礼

回答ありがとうございます。用意されているファイルは私にも解読不明なのですが、本当にバラバラにひょうじされているのです。が・・・お客様からはちゃんと意味がある物のようです。文字列も数値も合わせてこういうファイルなのです。ただ私はスペースやタブで区切ってあるものを認識して取り出せと言われています。
私のバージョンはXPですが、残念ながらＡ１のセルには表示されないみたいです。教えて頂いたので、いろいろ試してみたいと思います。ありがとうございます。

回答No.3

imogasi

Sub test01()
g = InputBox("何行目＝")
n = 0
Open "c:\My Documents\aaa11.txt" For Input As #1
While Not EOF(1)
n = n + 1
Line Input #1, a
If n = Val(g) Then
' MsgBox a
b = InputBox("何番目＝")
c = Split(a, "　")
r = Val(b) - 1
MsgBox c(r)
End If
Wend
Close #1
End Sub
を標準モジュールに貼りつけて実行して見てください。
ファイル名、フォルダ名は適当に変えてください。
Split(a, "　")の“　”の中は全角スペースです。
データも全角スペースで統一されているものとします。
問題のテキストファイルでテスト済み。

お礼

回答ありがとうございます。こういう方法で・・・・と早速貼り付けてみました。
２行目の「ＰＰＰ」を取り出そうとすると・・・なぜか空白になってしまうのですが・・・・。
「１行目の３番目」と入力すると、「６．５４」が表示されます。ずれているようなのですが、どうしてなのか・・・わかりませんでした。すみません。

回答No.2

karl1205

VBAは知りませんが、

Excelでメニューから「.txt」ファイルを開くとき、区切り文字はカンマやタブを選択できて、

それらが連続している場合は１つとみなす設定もできますよね

それを使えば問題なく取り込めるのではないでしょうか。

お礼

回答ありがとうございます。仰っている方法は多分お客様のお望みとは違う気がして・・・・なかなか難しいところなのです。ありがとうございます。また何かありましたらよろしくお願いします。

回答No.1

hana-hana3

１．スペースが区切り（＝データではない）の意味なら、一個になるようにする。
２．区切り文字（スペースやタブ等）を統一する。

という処理を読み込んだデータに行えばデータのフォーマットを統一できると思います。

あとは、Split関数関数で区切り文字を指定すれば、一括して配列に取り込めます。

参考URL：

http://www.moug.net/skillup/opm/opm02-02.htm

お礼

回答ありがとうございます。
データファイルは・・・それはＶＢＡ上で統一すると言うことでしょうか？ならできるのですが、そのファイルそのものはお客様のものなので、私の方では一切いじることはできません。
教えて頂いたＵＲＬでSplit関数の勉強をさせて頂きます。ありがとうございました。