【AS3】ループ処理で関数名を作成するには？

質問

ActionScript3.0についてご教授ください。

forなどを使い、ループ処理を使って変数名を作成する要領で
関数名を作ることは可能なのでしょうか？

やりたい処理を記述させて頂きますと次の通りです。
ステージにある３つのボタン「btn0」「btn1」「btn2」に対して
マウスクリック時の処理を書こうとしている例文です。

もちろん、これではエラーになります。

for( var i:int; i<3; i++ ){
　　this["btn"+i].addEventListener( MouseEvent.MOUSE_DOWN,"on"+i );
　　function "on"+i( e:MouseEvent ):void{
　　　　trace( e.target.name );
　　}
}

こうした処理を実現したい場合、"on"+i 部分をどのように記述すると良いのでしょうか？
もしご存知でしたらお知恵をいただけないでしょうか。
よろしくお願い致します。

回答No.1

DPE · ベストアンサー

関数はメモリのどこかに存在していて、呼び出す時はその所在地が必要になります。
メモリ内での所在地を表す情報を”参照”といい、関数の名前はその関数のメモリ内での所在地を表す参照になっています。

関数を定義する function キーワードでは、名前を定めない関数（匿名関数といいます）を作ることもできます。
匿名関数を作った時は、作られた関数の参照（＝メモリ内での所在地）が返されます。
返された参照を変数に保存しておけば、この変数を関数の名前の代わりに使うことができます。

ループを利用して匿名関数と連番の名前の付いた変数を作ると、連番の関数のようにすることができます。
合わせますと、関数 on0 ～ on2 を定義し、これらをボタン btn0 ～ btn2 のイベント処理関数に指定するスクリプトは次のようになります。

（↓　各行頭に全角のスペースが入っています。コピーする際は、全て半角のスペースかタブに置き換えてください）

//***

　//btn0～btn2のイベントリスナーを登録
　for( var i:int = 0 ; i < 3 ; i++ )
　{
　　//匿名関数を作り、連番の変数に参照を保存する
　　this[ "on" + i ] = function( e:MouseEvent ):void
　　{
　　　trace( e.target.name );
　　};

　　//イベントリスナーを登録
　　this[ "btn" + i ].addEventListener( MouseEvent.MOUSE_DOWN , this[ "on" + i ] );
　}

//***

↑　この場合は関数が３つ作られ、on0 ～ on1 という名前で呼び出せます。
ただし、全く同じ内容の関数が３つ存在することになり、メモリを無駄に占有してしまいます。

－ － － － －

ActionScript 3.0 では、イベントが発生した時に呼び出される関数に、イベントに関する様々な情報を１つにまとめたものが渡されるようになりました。
渡される情報の１つに、イベントを検出した対象を表す情報があります。上記の例では仮引数 e を介して参照している e.target の部分がそれで、対象がどんなインスタンス名であっても対応できるようになっています。

動作は全く同じで対象だけが異なる場合は、この e.target という表現を利用すると、関数は１つだけで済みます。

//***

　//イベント処理関数
　function onButton( e:MouseEvent ):void
　{
　　//ボタンの名前を出力
　　trace( e.target.name );
　}

　//btn0～btn2のイベントリスナーを登録
　for( var i:int = 0 ; i < 3 ; i++ )
　{
　　this[ "btn" + i ].addEventListener( MouseEvent.MOUSE_DOWN , onButton );
　}

//***

↑　このスクリプトでは、どのボタンが押されても omButton 関数が呼び出されます。
omButton 関数内の e.target は、btn0 でイベントが検出された時には btn0 を、btn1 で検出された時には btn1 を表しますので、同じ関数を登録していてもボタンに応じた名前が出力されます。

お礼

お礼が遅くなり、申し訳ございませんでした！
非常にご丁寧なご説明ありがとうございます！
おかげで助かりました。