flashで作るhtmlなしでswfのみの縦横サイズ可変フォトギャラリー

質問

PCのディスプレイサイズによってサイズの変わる、
フォトギャラリーをflashで作ろうとしています。
CDに置いたswfファイルのみをユーザーに開かせ、ギャラリーを再生させます。
ですので、htmlへのパブリッシュもせず、ネットにつながっていない環境でも再生される、
という仕様にしたいと考えています。
外部から写真を読み込む、ということもしません。

配置する要素としては、背景画像、写真、前へボタン、次へボタンです。
やりたい事としては。

・背景画像はディスプレイに対して100%で表示。つまり開いたswf自体が100%で表示。
・写真はディスプレイに対して約50%ぐらいで表示。この写真は縦長の物と横長の物があります。
・ボタンはサイズ固定でイメージとしては、下から30pxぐらいの位置に配置。

どうしたものか困っています。。
よろしくお願いします。

回答No.2

BlurFiltan · ベストアンサー

＃１です。

写真をムービークリップ内の各フレームに配置し
たとえば「photo_mc」というインスタンス名を付け
その他のインスタンスも図のように配置し
それらがあるフレームに次のように書けば良いのではないかと思います。

-------------------------
//ムービー内の拡大縮小なし
stage.scaleMode = StageScaleMode.NO_SCALE;
//ステージの左上を基準に整列
stage.align = StageAlign.TOP_LEFT;

//写真入り「photo_mc」の再生停止
photo_mc.stop();

//インスタンスを配置する関数 arrangeInstance を定義
function arrangeInstance():void{
//
//---背景の「back_mc」に関して---
//ｘｙ座標を0にする
back_mc.x=back_mc.y=0;
//横幅をステージ幅に合わせる
back_mc.width = stage.stageWidth;
//高さをステージ高に合わせる
back_mc.height = stage.stageHeight;
//
//---写真入り「photo_mc」に関して---
//縦横比を求める
var hpw:Number = photo_mc.height/photo_mc.width;
//横幅をステージ幅の半分にする
photo_mc.width = stage.stageWidth/2;
//高さをその比に合わせる
photo_mc.height = photo_mc.width*hpw;
//x座標をステージ中央にする
photo_mc.x = stage.stageWidth/2;
//
//---ボタン「prev_btn」に関して---
//x座標をステージ中央より60px左にする
prev_btn.x = stage.stageWidth/2-60;
//ｙ座標をステージ下より30px上にする
prev_btn.y = stage.stageHeight-30;
//
//---ボタン「next_btn」に関して---
//x座標をステージ中央より60px右にする
next_btn.x = stage.stageWidth/2+60;
//ｙ座標をステージ下より30px上にする
next_btn.y = stage.stageHeight-30;
}

//関数 arrangeInstance を実行
arrangeInstance();

//リサイズしたときに関数 sizeChange を実行するリスナーを登録
stage.addEventListener(Event.RESIZE, sizeChange);

//関数 sizeChange を定義
function sizeChange(evt:Event):void {
//関数 arrangeInstance を実行
arrangeInstance();
}

//「prev_btn」にクリックでprevClickを実行するリスナーを登録
prev_btn.addEventListener(MouseEvent.CLICK,prevClick);

//関数 prevClick の定義
function prevClick(evt:MouseEvent):void{
//写真入り「photo_mc」内を前のフレームに戻して停止
photo_mc.prevFrame();
}

//「next_btn」にクリックでnextClickを実行するリスナーを登録
next_btn.addEventListener(MouseEvent.CLICK,nextClick);

//関数 nextClick の定義
function nextClick(evt:MouseEvent):void{
// 写真入り「photo_mc」内を次のフレームに戻して停止
photo_mc.nextFrame();
}
-------------------------

なおSWFはHTMLに縦横100％で貼り付けること。
(パブリッシュ設定でHTMLタブを選択して サイズ を パーセント にして 幅：100％ 高さ：100％ にするとか)

以上で回答字数制限ほとんどいっぱいです

お礼

大変ご丁寧に書いていただきありがとうございます！
感謝いたします！

ここまでは教えていただいた通りにし、
作ることができました！

ですがひとつ重要なことを書き忘れておりました。。
あつかましいのですが追記させていただきます。

写真なのですが、ギザギザになってしまうのをキレイにできないでしょうか？
人物写真ですのでどうにかできないものかと。。

あとこれは僕の作り方がおかしいのかもしれませんが、
2枚目以降の写真を表示した状態で、ウインドウをマウスでドラッグして
拡大縮小すると写真が元の大きいサイズになってしまい、
ボタンが隠れてしまいます。
その状態からブラウザを更新すると正しいサイズで表示されます。

何卒何卒よろしくお願いします！

回答No.1

BlurFiltan

> CDに置いたswfファイルのみをユーザーに開かせ、
> ギャラリーを再生させます。

それ自体が普通無理でしょう。
SWFなんて普通は（極一般的なPCユーザは）開けませんよ。

開けるとしたら，
ブラウザ用の Flash Player(いわゆるプラグイン) をブラウザにインストールしていて，
なおかつ，
そのブラウザでSWFを開く場合です。

SWF を単独で開けるのは，
Flash 作成ツール(Flash CS4 や CS3 や 8 や MX 2004 や MX など)を持っていて，
スタンドアローン用の Flash Player もしくはデバッグ用の スタンドアローン Flash Player を持っているからですよ。
まずそこを自覚してください。
普通の人はそんなもの(スタンドアローンFlash Player)など持っていないので，
いわゆる一般的な Flash Player(ブラウザのプラグイン)で開くしかありません。
したがって，ブラウザのプラグインで開くのであれば，HTML に貼り付けるのが普通です。
またそうでないと SWF を単独でブラウザで開けない場合もあります。

> htmlへのパブリッシュもせず、ネットにつながっていない環境でも再生される、

それだったら，
SWF ではなくて プロジェクタ をパブリッシュすべきでしょう。
プロジェクタとは，
Windows の場合は EXE で，Mac の場合は HQX でパブリッシュされる実行ファイルのことです。
ファイル→パブリッシュ設定 で「形式」タブを選択して，
Windowsプロジェクタ or Macintoshプロジェクタ にチェックを入れてパブリッシュすると，
SWF と同時に プロジェクタ もパブリッシュされます。
それを CD などに入れて配布すべきです。

> やりたい事としては。…

それは HTML に貼り付けた場合とどこが変わるのでしょうか？
私にはその違いがわかりません（違う部分は違うかもしれないが違いが１つに特定できない。）。

また…，
これは最初に書くべき事項なのですが，
「バージョンを全く書かれていません！」 よ。
これじゃぁ，したいことがわかったとしても回答のしようがありません。

「バージョン」とは，
Flash 作成ツールのバージョン，ActionScript のバージョン です。
バージョンが１つ違えば全く別世界的なことが Flash ではざらに起こりますから，
何が何でも最も重要な物は「バージョン」です。

※ご質問は CD であるので
　自動的に 携帯 は除外されますが
　それも絡んでくると，
　パブリッシュする Flash Player のバージョンや
　Flash Lite のバージョンも必要になります。
　とにかく「大前提の条件」がわからなければ，
　ActionScript １行たりとも，
　また
　線の描画１本たりともできないのです。
　そういう「大前提」をまずキッチリ押さえてください。

　簡単に言えば自分が見ている物が全てと思わない方が良いです。
　自分が見ている物は特殊な立場の特殊な条件が成り立った場合だけ
　言えることだと思った方が良いです。

お礼

諸々説明不足で失礼しました。。

> SWFなんて普通は（極一般的なPCユーザは）開けませんよ。

知りませんでした。。htmlに貼り付けようと思います。。
swfだけにしようとした理由は、なるべくファイル数を少なくして
ユーザーに分かりやすくするためでした。

バージョンも抜けてまして、すみません。。
ActionScript3
Flash Player9
を考えています。

その他制作環境は、
Win XP
Flash CS3
です。