秀丸マクロの作成方法

質問

• 秀丸マクロを使って、巨大なログファイルから特定の文字列を抽出しましょう。
• ログファイルから特定の文字列を抜き出し、新しいファイルに保存する方法を紹介します。
• マクロを使って、ログファイル内の特定の行を抽出しましょう。

回答No.2

Bo_Bo

下記のマクロで、質問文の条件では動作すると思います。
参考になれば幸いです。

●検索オプション
　　検索オプションは、「オプションなし」の状態で検索しています。
　　大文字小文字の区別や単語単位、正規表現などで検索するには、
　　それようのフラグを記述しなければなりません。それらは、
　　・「秀丸エディターヘルプ」の「秀丸起動時のオプション」の /g 項目
　　・「マクロヘルプ」の「grep」項目
　　を参照してください。

●検索するファイル（$findType）の指定方法

　　ログファイルの拡張子が .log で、
　　格納ディレクトリ・パスが c:\foo\bar\log なら、
　　$findType = "c:\\foo\\bar\\log\\*.log";
　　となる。
　　円記号（\）が二重になっていることに注意！

●検索キーワード
　　検索キーワードに二重引用符や円記号など、特殊な文字を含める場合は、
　　「マクロヘルプ」の「式について」→「文字列」を参照してください。

●秀丸の話題
　　秀丸についての質問などは、
　　「秀シリーズサポートフォーラム」http://www.maruo.co.jp/hidesoft/
　　に投稿した方が、迅速、丁寧です。
　　そこの常連さんは親切な人が多いので、訪問することをお勧めします。
　　このマクロを持っていって、『こう改造したいけどどうするの？』
　　でも良いですよ。
　　「秀丸エディタ マクロ作者会議室」http://www.maruo.co.jp/hidesoft/4/

//== ▼マクロここから =========================================

$findType = ""; // 検索するファイル
$keyword1 = ""; // １回目の検索キーワード
$keyword2 = ""; // ２回目の検索キーワード

//-- 上記３つを設定後に実行すること ---------------------------

$sb = searchbuffer;
#so = searchoption;
$rb = replacebuffer;
#parentHD = hidemaruhandle(0);

openfile "/h /g,\"" + $findType + "\"" + $keyword1;
#hd1 = hidemaruhandle(0);
if( code == eof ) call NoMatch #hd1, "1";
replaceallfast "^[^:]+: +", "", regular;

localgrep $keyword2, icon;
#hd2 = hidemaruhandle(0);
if( code == eof ) call NoMatch #hd2, "2";
replaceallfast "^[^:]+: +", "", regular;
gofiletop;
clearupdated;
closehidemaruforced #hd1;

setsearch $sb, #so;
setreplace $rb;
message str(linecount2-1) + " 行を抽出しました。";
SAVEAS;
endmacro;

NoMatch:
setactivehidemaru #parentHD;
closehidemaruforced ##1;
setsearch $sb, #so;
setreplace $rb;
message $$2 + " 個目の検索キーワードにマッチなし！";
endmacro;

//== ▲マクロここまで =========================================