removeChild()についてご教授願います。

質問

AS3.0の初心者です。
Stratボタン、Stopボタンで以下のスクリプトで表示と非表示を繰返ししたいのですが、
Stopボタンで、単にremoveChild();にしますと、

「#2025: 指定した DisplayObject は呼び出し元の子でなければなりません。」

とエラーとなります。
色々と調べてみたのですが、よく判判りません。
Stopボタンの記述をどの様にすればよいのでしょうか？
初歩的質問で大変恐縮ですが、どうかご教授お願い致します。

[メインスクリプト]
var stageH = stage.stageHeight;
var stageW = stage.stageWidth;

//Stratボタン
start.addEventListener(MouseEvent.MOUSE_DOWN,gene);
function gene(e:Event):void
{
for (var i = 0; i < 20; i++)
{
var mc:Candy = new Candy();
mc.x = Math.random()*stageW + 10;
mc.y = Math.random()*stageH + 10;
addChild(mc);
}
}

//Stopボタン
stop.addEventListener(MouseEvent.MOUSE_DOWN,stp);
function stp(e:Event):void
{
removeChild(mc); この部分がよく判らないのですが、
どの様に記述したら良いのでしょうか？
}

---------------------------------------
[mc のスクリプト]
var mcH:int = this.height;
var mcW:int = this.width;
var stageH = stage.stageHeight;
var stageW = stage.stageWidth;
var speedY:uint = Math.random() * 5 + 5;
var speedX:uint = Math.random() * 2;

addEventListener(Event.ENTER_FRAME,loop);
function loop(Event):void
{
y += speedY;
x += speedX;

if ( y > stageH )
{
y = - mcH;
}
if ( x > stageW )
{
x = - mcW;
}
}
-----------------------------------------

回答No.1

BlurFiltan · ベストアンサー

問題点は，

var mc:Candy = new Candy();

のようにして
たくさんの違う Candy インスタンスを，その場しのぎの変数 mc に代入しているところです。

個々の Candy(MC) インスタンスには
その場しのぎではなくちゃんと個別の名前を付ける必要があります。
(個々のCandyインスタンスを参照する個別の変数が必要です。)
そうしないと個々のインスタンスを名指しで呼ぶことができません。

あと，ボタンの名前が少しよろしくないので
Stratボタンには「start_btn」というインスタンス名を付け
Stopボタンには「stop_btn」というインスタンス名を付けるものとします。

以下はその場合の変更例(２例)です。

【例１】
Stratボタン の連続クリックで
Candy インスタンスを何度も増殖させる場合

//---フレームのスクリプト例-----------------
var stageH:int = stage.stageHeight;
var stageW:int = stage.stageWidth;

//カウンタ用変数cnt
var cnt:int = 0;

//Stratボタン
start_btn.addEventListener(MouseEvent.MOUSE_DOWN,gene);
function gene(e:Event):void
{
for (var i:int = 0; i < 20; i++)
{
this["mc" + cnt] = new Candy();
this["mc" + cnt].x = Math.random() * stageW + 10;
this["mc" + cnt].y = Math.random() * stageH + 10;
addChild(this["mc" + cnt]);
//カウンタに1を加算
cnt++;
}
}

//Stopボタン
stop_btn.addEventListener(MouseEvent.MOUSE_DOWN,stp);
function stp(e:Event):void
{
for (var i:int = 0; i < cnt; i++)
{
//インスタンス内のイベントリスナーを削除
this["mc" + i].removeEventListener(Event.ENTER_FRAME,this["mc" + i].loop);
//インスタンスを表示リストから削除
removeChild(this["mc" + i]);
//インスタンスへの参照を切る
this["mc" + i] = null;
}
cnt = 0;
}
//------------------------------------------

【例２】
Stratボタン を連続クリックをさせない場合

//---フレームのスクリプト例-----------------
var stageH:int = stage.stageHeight;
var stageW:int = stage.stageWidth;

//Stopボタンのマウス反応を無効にしておく
stop_btn.mouseEnabled = false;

//Stratボタン
start_btn.addEventListener(MouseEvent.MOUSE_DOWN,gene);
function gene(e:Event):void
{
for (var i:int = 0; i < 20; i++)
{
this["mc" + i] = new Candy();
this["mc" + i].x = Math.random() * stageW + 10;
this["mc" + i].y = Math.random() * stageH + 10;
addChild(this["mc" + i]);
}
//Stratボタンのマウス反応を無効にする
start_btn.mouseEnabled = false;
//Stopボタンのマウス反応を無効にする
stop_btn.mouseEnabled = true;
}

//Stopボタン
stop_btn.addEventListener(MouseEvent.MOUSE_DOWN,stp);
function stp(e:Event):void
{
for (var i:int = 0; i < 20; i++)
{
//インスタンス内のイベントリスナーを削除
this["mc" + i].removeEventListener(Event.ENTER_FRAME,this["mc" + i].loop);
//インスタンスを表示リストから削除
removeChild(this["mc" + i]);
//インスタンスへの参照を切る
this["mc" + i] = null;
}
//Stratボタンのマウス反応を有効にする
start_btn.mouseEnabled = true;
//Stopボタンのマウス反応を無効にする
stop_btn.mouseEnabled = false;
}
//------------------------------------------

this["mc" + i] などで出てくる [] を
「配列アクセス演算子」と言いますが，
これを使わずに個々のインスタンスを配列の要素に入れても良いです。

そうすれば this などのタイムラインを参照するパスは不要になります。

//---例----------------------------------
var stageH:int = stage.stageHeight;
var stageW:int = stage.stageWidth;

//インスタンスの参照を格納する配列を作成
var mc_arr:Array = new Array();

　～ 中略 ～

function gene(e:Event):void
{
for (var i:int = 0; i < 20; i++)
{
//配列の各要素に作成したインスタンスを格納
mc_arr[i] = new Candy();

　～ 後略 ～
//---------------------------------------

その他諸々のことに関して
「[AS3] DisplayObjectインスタンスの削除とガベージコレクション 」
http://f-site.org/articles/2010/05/09072731.html

お礼

BlurFiltan様

本当にありがとうございます。
こんな初心者に図解までお付け頂き、
丁寧なご教授に感謝、感激しております。

一度はあきらめかけていたのですが、質問して良かったです。
BlurFiltan様な方がいらっしゃると、これからのFlashが楽しくなりました。
こんな初心者ですが、今後ともよろしくお願い致します。

本当にありがとうございます。
感激です。