ExcelVBAでの配列処理について

質問

処理速度向上を目的に配列を利用したいのですが、結果の書きだし処理で悩んでいます。

Dim aa(10000,2) as Double

for i = 1 to 10000
for j = 1 to 2
aa(i,j)=Rnd()
next j
next i

上記の処理で、10000行と2列の乱数表データが配列として出来、そのデータをシートに書き出しするときに、列を2つほど飛ばして書き出したいのですが、どうすればよいのでしょうか？

range("A1:B10000") = aa　　という連続した列ではなく、A列に1万行、D列に1万行書き出したいと思っています。

処理速度を向上させたいので、またFor分処理するのではなく、一気に書き出したいと思っています。

ご教授のほどよろしくお願い申し上げます。

回答No.2

mitarashi · ベストアンサー

最初から列毎に分けて処理する事をお勧めします。（B,C列が0になってしまって良いなら別ですが）
まとめて書き込んでいるので、Application云々の必要性は不明ですが、ご参考まで。
Sub test()
Dim aa As Variant, ad As Variant
Dim rngA As Range, rngD As Range
Dim i As Long
Const maxNo As Long = 10000

Randomize (Time)
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Set rngA = Range("A1").Resize(maxNo, 1)
Set rngD = Range("D1").Resize(maxNo, 1)
aa = rngA
ad = rngD
For i = 1 To 10000
aa(i, 1) = Rnd()
ad(i, 1) = Rnd()
Next i
rngA = aa
rngD = ad
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub

お礼

ありがとうございます。

かなり高速に処理できそうです。

ただ、列数も可変の場合はもっとややこしいですよね。
教えていただいた方法で工夫すればできそうですが、別途ご教授していただけると助かります。

回答No.6

mitarashi

#2です。
列数が可変なら、どうせ一列ずつの処理ですので、自分なら次の様な関数にして、列毎に処理します。ここでは、先頭のセルと、データ数を渡す様にしてみました。
ご参考まで。

Sub test3(startCell As Range, maxNo As Long)
Dim aa As Variant
Dim rngA As Range
Dim i As Long

Randomize (Time)
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Set rngA = startCell.Resize(maxNo, 1)
aa = rngA
For i = 1 To maxNo
aa(i, 1) = Rnd()
Next i
rngA = aa
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub

回答No.5

imogasi

確かにエクセルは、普通は画面のセルの値を修正を伴うのですが、それを
Application.ScreenUpdating = False
で抑止すれば、どちら（配列もセルも）もメモリへ書き込む処理になって、ForNexｔで書き込む（２列に分けてになる）のと、大きな差は無いのではないですか。自己満足ではないですかね。よく検証してみてください。結果的にセルの値を後ほどセットするならなおさら。
＞処理速度を向上させたいので、なんていっているが質問者はプログラムのベテランですか？観念的な考えで左右されないように、テストでもして、実証しつつ、考えられんことを。
私はInsideエクセルのことは知りませんが（普通の人はこの点勉強して無いでしょう）。

お礼

当然こういったサイトに技術的なことを質問しているぐらいですからベテランではありませんよ。

皆様のおかげて処理速度が速くなりました。

ありがとうございました。

回答No.4

mitarashi

#2です。
#3さんの手がありましたね。.Value=.Valueを入れないで、再計算に入り悲惨な目にあった事を思い出しました。
試みに、60000行にして処理時間を計測してみました。当方PentiumM1.33Ｇという古いマシン、xl2000です。
#2のコードで、実行2～6回目の平均時間が448msec、改造して#3さんの方法を取り入れたもので、511msecと、配列による方法も満更でもない結果でした。

ところで、For i = 1 to 10000 のところは、to maxNo の直し損ねですので、言わずもがなですがお知らせしておきます。（恥）

回答No.3

hallo-2007

お役にたてるかどうかですが
＞処理速度を向上させたいので、またFor分処理するのではなく、一気に書き出したいと思っています。
With Range("A2:A10000")
.FormulaR1C1 = "=RAND()"
.Value = .Value
End With
With Range("D2:D10000")
.FormulaR1C1 = "=RAND()"
.Value = .Value
End With
といった方法では如何でしょうか。

お礼

ありがとうございます。

これは早いですね。
こんなやり方があったとは知りませんでした。

この方法でも検討してみます。

回答No.1

D-Matsu

私なら一次配列に入れ直すか、最初から10000x4の配列を使って1と4だけ値を入れることを考えます。

後者の場合、こんな感じになりますか。

Dim aa(10000, 4) as double
for i = 1 to 10000
for j = 1 to 4 step 3
aa(i, j) = Rnd()
next j
next i

メモリをバカ食いするので配列サイズによっては不可能ですが、これくらいならたぶんなんとか。

お礼

ありがとうございます。

1次配列に入れ直す方法も教えてもらえると助かります。