エクセルのマクロでセルを自動的にクリアにする方法

質問

（休日登録）
　A20～25セルを”休日”と定義
　A20に9/3と入っているとします。

（シート）
　 　　A　　　B　　　　C
1　　日付　　曜日　　合計時間　　
2　　 9/1　（金）　　　8：30　
3 9/2 (土）　　　8：00　←この日が休日だとすると・・・
4　　 9/3　　休　←自動で休みと入るようにしてあります。　　

このようなシート入力があるとして
休日を9/3と登録し、入力規則のユーザー設定で
=COUNTIF(休日,A4)=0と入力し休日を判定して
休日のC4セルには入力不可に設定してあります。
ところが、9/2も休日だとあとで分かり、9/2もA21のセルに休日として追加したとします。
しかし、9/2のC3セルにはあらかじめ数字が入っているため、休日に変更しても
数字は残ってしまいます。
これをマクロの機能を使って、曜日欄が休日となったら
自動的にC3セルを自動クリアにするというような事は出来ませんか？
それかマクロを使わなくても可能であれば宜しくお願いします。

回答No.2

ka_na_de · ベストアンサー

補足説明ありがとうございます。

前回紹介したマクロは、"休"と新たに入力した際に、
その変化を捉えて、隣のセルを空欄にするようになっています。

つまり、マクロを貼り付ける前にすでに、
"休"と入力されている場合は機能しません。
（クリックなどで、もう一度変化させないと）

もし、すでに大量のデータがあるのなら、新たにマクロを
作りましたので、標準モジュールに登録して実行してください。
Ｂ列に"休"があれば、隣とその隣のセルを空欄にします。

'=============標準モジュールに記述===========================
Sub test()
　Dim LastRow As Long, r As Long

　LastRow = Cells(Rows.Count, "A").End(xlUp).Row

　For r = 1 To LastRow
　　If Range("B" & r).Value = "休" Then
　　　Range("B" & r).Resize(, 2).Offset(, 1).Value = ""
　　End If
　Next r

End Sub

なお、前回紹介したマクロについても、
隣とその隣が空欄になるように変更しておきました。
（エラー処理も１行追加してます。
　前回のものは削除してください。不具合が出ます。）

'=============シートモジュールに記述===========================
Private Sub Worksheet_Change(ByVal Target As Range)
　If Target.Count > 1 Then Exit Sub
　If Target.Column <> 2 Then Exit Sub

　Application.EnableEvents = False
　　If Target.Value = "休" Then Target.Resize(, 2).Offset(, 1).Value = ""
　Application.EnableEvents = True

End Sub

お礼

返事が遅れましたが、回答有難うございました。

ちなみにシートモジュールに記述した場合は
マクロ→実行をさせる必要があるようですね。
まだまだマクロは自動記録プラスαくらいしか出来無く
モジュールに記述されたものを応用しようとすると難しいので
これから少しずつ覚えていきたいと思います。

回答No.1

ka_na_de

>これをマクロの機能を使って、曜日欄が休日となったら
>自動的にC3セルを自動クリアにするというような事は出来ませんか？

例のように、Ｂ列に休と入力確定されたら、右横を空欄にします。

'=============シートモジュールに記述===========================
Private Sub Worksheet_Change(ByVal Target As Range)

　If Target.Column <> 2 Then Exit Sub　'B列の変化以外はスルー

　Application.EnableEvents = False
　　If Target.Value = "休" Then Target.Offset(, 1).Value = ""
　Application.EnableEvents = True

End Sub

>それかマクロを使わなくても可能であれば宜しくお願いします。

もし、見た目だけで良ければ、条件付書式で、
Ｃ列を選択し、上部メニューで
「書式」→「条件付書式」
「数式が」にして「=B1="休"」と入力し、
「書式」ボタンを押して「フォント」の色を「白」にして「ＯＫ」

でどうでしょうか？

補足

ka_na_deさん
早速の回答ありがとうございます。

見た目だけではなく、入力された日数でアベレージを算出しているので
マクロの方の回答を参考にさせてもらいます。

ただ、実際にやってみたところ
”B列に入力確定されたら”という上記のマクロだと
”休”と入った曜日欄のB3セルをマウスでクリックするまで
C3セルが空欄とならないようなので、
クリックしなくても、B列に”休”と表示された時点で空欄と変わるようにするには
どのようにしたら良いでしょうか？

また、その際、右隣のD3セルも同時に空欄にするには
Then Target.Offset(, 1).
のところをどのように変えるとうまくいきますか？
C3、D3セルでなく、B列に”休”と入ったらC列＆D列というように列単位で空欄にするというものでも良いです。

宜しくお願い致します。