エクセルのsetphonetic関数

質問

たとえば「和家 利代」をsetphonetic関数で振り仮名をつけると「ワイエ　リダイ」になりました。正しくは「ワケ　トシヨ」です。「和家」を「ワケ」と読ませるようにできるのでしょうか。

回答No.3

cj_mover · ベストアンサー

こんにちは。お邪魔します。
＃投稿文を書いている間に＃２さんの投稿が追加されていて、
＃ネタ的には被ってしまって恐縮ですが、、、。

とりあえずは、.SetPhonetic メソッドでフリガナを設定してみて、
望んだものと違っているセルを選択してから、下に挙げたのマクロを実行してみて下さい。
次々とフリガナの候補を切り替えていきます。

ボタンに登録しておけば、そこそこの編集効率は達成できるでしょう。

元々のセルのフリガナ表示は小さなフォントなので、見難い場合は
フリガナ編集作業中は、どこか空いているセルに、
ワークシート関数を設定しておくといいでしょう。
例えば、仮にＣ列にフリガナを表示させるなら
'　　With ActiveCell
　　　　With .EntireRow.Cells(1, "C")
　　　　　　If .FormulaLocal = "" Then .FormulaLocal = "=PHONETIC(" & .Address & ")"
　　　　End With
' ・
' ・
' ・
'　　End With
のような要領で、書き加えておいたものを実行して、編集が終ったら、
（手作業や他にボタンを用意して）この数式を消去するような運用で、、、。

今回はボタンを押す度に次のフリガナ候補に切り替えるようにしていますが、
アイディアとしては、フリガナ候補をリスト化して、
CommandBarやListBoxなどに全候補表示されたものから選ぶ、
ということも可能です。
ただ、候補があまり多くなると、却って実用的でなくなりますから、
（ツリー構造などの」）体系的な候補表示が必要になると思います。
今回はそこまで考える余裕もないので、
ＶＢＡでの基本的なフリガナの扱い、を一通り理解して貰えそうな
簡易なものでお応えします。

' ' /// フリガナを設定。実行の度に次の候補にて設定。

Sub Re8768439()
Dim v
Dim sS As String
Dim sD As String

　　With ActiveCell　'　※　必ず、対象セルをアクティブにしてから実行。
　　　　' ' フリガナを表示する
　　　　If Not .Phonetic.Visible Then .Phonetic.Visible = True

　　　　' ' フリガナが設定されているか、判別
　　　　If .Phonetics.Count > 0 Then　'　フリガナが設定されているなら

　　　　　　' ' セルの値（漢字？相当）
　　　　　　v = .Value
　　　　　　' ' 現在設定されているフリガナ　を取得
　　　　　　sS = .Phonetic.Text
　　　　　　' ' 統一する為、スペースを全角で統一
　　　　　　If InStr(sS, " ") Then sS = Replace(sS, " ", "　")

　　　　　　' ' Application.GetPhonetic メソッドで　最初のフリガナ候補　を取得
　　　　　　sD = Application.GetPhonetic(v)
　　　　　　' ' 現在のフリガナ と フリガナ候補 が 一致するまでループ
　　　　　　Do Until sD = sS
　　　　　　　　sD = Application.GetPhonetic()　'　次のフリガナ候補　を取得
　　　　　　Loop
　　　　　　' ' 現在のフリガナ と フリガナ候補 が 一致したら 次のフリガナ候補　を取得
　　　　　　If sS = sD Then sD = Application.GetPhonetic()

　　　　　　If sD = "" Then　'　フリガナ候補 が 空の文字列 なら
　　　　　　　　.Phonetics.Delete　'　フリガナ設定を削除
　　　　　　Else
　　　　　　　　.Phonetic.Text = sD　'　フリガナ候補 を フリガナに設定
　　　　　　End If

　　　　Else　'　フリガナが設定されていないなら

　　　　　　.SetPhonetic　'　フリガナを設定（最初のフリガナ候補）
　　　　End If
　　End With
End Sub