actionscript2.0で動的な位置変化

質問

• actionscript2.0を使い、bg0～bg9と配列で並んだムービークリップに対して、動的な位置変化を実現したい。
• 動的なムービークリップの移動と配置を行いたい。
• ムービークリップの配置に関するスクリプトがあり、それを使用していますが、上手くいきません。

回答No.4

BlurFiltan · ベストアンサー

＃１です。
返事が遅くなってしまいましたが。

> ０１２３４
> ５６７８９
>
> が
>
> □□□３ ４
> ５ ６ ７ ８ ９
> ０ １ ２

なるほど，
＃１のスクリプトだと確かにそうなりますね。
私の確認不足でした。
すみません。

それではスクリプトを次のように変更してみてください。

//-----------------------------------------------
//「bg○」の参照を入れる配列を用意
var objA:Array = new Array(2*5);

//「bg○」の座標を入れる配列を用意
var posA:Array =[
[70, 112], [106, 112], [142, 112], [178, 112], [214, 112],
[70, 148], [106, 148], [142, 148], [178, 148], [214, 148],
[70, 184], [106, 184], [142, 184], [178, 184], [214, 184],
[70, 220], [106, 220], [142, 220], [178, 220], [214, 220]
];

//「bg○」の入る位置番号を入れる配列を用意
var numA:Array = new Array(objA.length);

//「bg○」の生成＆配置
for (var i:Number=0; i<objA.length; i++) {
objA[i] = _root.attachMovie("bg", "bg"+i, i+100);
//●動作確認用(本題とは関係なし)
//objA[i].createTextField("tf",0,-15,-15,24,24);
//objA[i].tf.text = i;
objA[i]._x = posA[i][0];
objA[i]._y = posA[i][1];
}

//「hitBar」をドラッグできるようにする
hitBar.onPress = function():Void{
this.startDrag();
};
hitBar.onRelease
= hitBar.onReleaseOutside = function():Void{
this.stopDrag();
};

//毎フレーム実行
this.onEnterFrame = function():Void{
//配列「numA」の初期化と「bg○」の配置
for (var i:Number=0; i<objA.length; i++) {
numA[i] = i;
objA[i]._x = posA[numA[i]][0];
objA[i]._y = posA[numA[i]][1];
}
//
//「bg○」に関するループ
for (i=0; i<objA.length; i++) {
//「bg○」が「hitBar」にヒットしている間はループ
while(objA[i].hitTest(hitBar)){
//★ j:Number=0; を j:Number=i; に変更
for (var j:Number=i; j<objA.length; j++) {
numA[j]++;
//★座標移動をココから削除(下に移動)
}
//★この for 文を付け足し
for (j=0; j<objA.length; j++) {
//★座標移動
objA[j]._x = posA[numA[j]][0];
objA[j]._y = posA[numA[j]][1];
}
}
}
};
//-----------------------------------------------

変更したのは ★ を付けた部分で，その他は基本的にそのままです。
(● を付けてコメントアウトしてある部分は，私自身のための動作確認用スクリプトです。)

お礼

お礼が遅くなりまして申し訳ありません！
わざわざこちらの要望に合わせて改変してくださってありがとうございます…！
お陰様で無事に動作させることができました。
本当に感謝感激です。ありがとうございました！