Actionscript3.0 ストップウォッチ

質問

こんにちは
Flash　Actionscript3.0 についての質問です。

こちらのサイト
http://labs.cybridge.jp/2009/10/actionscript30.html

のストップウォッチの、
ボタン部分を自作のシンボルボタンに変えたいのですが、
その場合はコードをどのように書けばいいのでしょうか。
スタートボタンのインスタンス名startbtn
ストップボタンのインスタンス名stopbtn　です。

よろしくお願いします。

回答No.3

BlurFiltan · ベストアンサー

＃１ ＆ ＃２ です。

＃２ のお礼(補足の方ではないです) を読ませていただきましたが，
フレームによって違うボタンなどが登場して
そのボタンクリックによって別々の動作をさせるのでしたら
その フレーム・フレーム… ごとにスクリプトを書いた方が良いと思います。

少なくともドキュメントクラスのスクリプトだけでするのは難しいでしょう。

とりあえずは
ステージ上の各フレームに用意するインスタンスを書きます。
「 」内はインスタンス名です。

◎ フレーム1 に用意するもの
　・ボタンインスタンス「start_btn」

◎ フレーム2 に用意するもの
　・ボタンインスタンス「ok_btn」
　・ボタンインスタンス「cancel_btn」
　・ダイナミックテキストフィールド「time_txt」
　 ※↑これは フレーム3 と 4 でも継続表示させる

◎ フレーム3 に用意するもの
　・ダイナミックテキストフィールド「judge_txt」
　 ※↑これは フレーム4 でも継続表示させる
　・ダイナミックテキストフィールド「time_txt」
　 ※↑これは フレーム2 から継続表示させる

◎ フレーム4 に用意するもの
　・ダイナミックテキストフィールド「judge_txt」
　 ※↑これは フレーム3 から継続表示させる
　・ダイナミックテキストフィールド「time_txt」
　 ※↑これは フレーム2 から継続表示させる

※下の【添付図】をご参考に。

ドキュメントクラスは無くします。
各フレームに書くスクリプト例です。

//---フレーム1--------------------------
//このフレームで再生を停止
stop();

//経過時間を代入する変数の宣言
var old_time:uint;
var now_time:uint;

//「start_btn」クリック時に 関数 clockStart を実行
start_btn.addEventListener(MouseEvent.CLICK,clockStart);

//関数 clockStart の定義
function clockStart(e:MouseEvent) {
//変数 old_time にスタート時の時間を代入
old_time = getTimer();
//このイベントリスナーを削除
start_btn.removeEventListener(MouseEvent.CLICK,clockStart);
//次のフレーム(フレーム2)で停止
nextFrame();
}
//------------------------------------

//---フレーム2--------------------------
//毎フレーム進む時間で 関数 tick を実行
this.addEventListener(Event.ENTER_FRAME,tick);

//関数 tick の定義
function tick(e:Event):void {
//変数 now_time に今の時間を代入
now_time = getTimer();
//スタート時からの時間差を取得
var mili_sec = now_time - old_time;
//～時間の表示文字列を算出～
var s:int = Math.floor(mili_sec / 1000);
var minutes:int = Math.floor(s / 60);
var seconds:int = s % 60;
var mili:int = mili_sec % 1000;
//「time_txt」に経過時間を表示
time_txt.text = minutes + ":" + ("0" + seconds).substr(-2,2) +":"+ ("00" + mili).substr(-3,2);
}

//「ok_btn」クリック時に 関数 okFunc を実行
ok_btn.addEventListener(MouseEvent.CLICK,okFunc);

//関数 okFunc の定義
function okFunc(e:MouseEvent) {
//このイベントリスナーを削除
ok_btn.removeEventListener(MouseEvent.CLICK,okFunc);
//フレーム3 で停止
gotoAndStop(3);
}

//「cancel_btn」クリック時に 関数 cancelFunc を実行
cancel_btn.addEventListener(MouseEvent.CLICK,cancelFunc);

//関数 cancelFunc の定義
function cancelFunc(e:MouseEvent) {
//このイベントリスナーを削除
cancel_btn.removeEventListener(MouseEvent.CLICK,cancelFunc);
//フレーム4 で停止
gotoAndStop(4);
}
//------------------------------------

//---フレーム3--------------------------
//毎フレーム進む時間で 関数 tick を実行するのをやめる
this.removeEventListener(Event.ENTER_FRAME,tick);

//「judge_txt」に 正 を表示
judge_txt.text = "正";
//------------------------------------

//---フレーム4--------------------------
//毎フレーム進む時間で 関数 tick を実行するのをやめる
this.removeEventListener(Event.ENTER_FRAME,tick);

//「judge_txt」に 誤 を表示
judge_txt.text = "誤";
//------------------------------------

以上のように
「何がどうなったときに，何をどうするのか。」
ということを具体的にしっかりとイメージして
１つずつ確実に動作するようにスクリプトを考えて行けばできると思います。

お礼

おそくなってしまい申し訳ありません。
確認しました。問題なく操作できました！
丁寧な説明・画像付きでありがとうございます。
すごく分かりやすくて助かりました。
スクリプト見直してひとつひとつ自分でまた噛み砕いてみますね。
本当にありがとうございました！