Excelで、数字を条件付で記号にしたい。

質問

Excel2003です。

例えば、「１～８がX、９～１８がY、１９以上がZ」というように、数字の範囲をみて、記号に直したいのですが、IF関数だとなかなかうまくいきません。

どなたか、分かる方教えていただければと思います。

回答No.2

keithin · ベストアンサー

方法１：
添付図のように数字と記号の対応表を用意しておき，
Ｅ２セルに
=VLOOKUP(D2,A2:B5,2)
と数式を準備します。

なお，添付図のＢ２セルには「’」という記号を記入しておきます。

＃VLOOKUP関数が不自由なく使えるようになれば，Excel初級卒業です。

方法２：
IF関数しか使えないのでIF関数しか使いたくないご相談も，非常にしばしば寄せられます。
=IF(A1="","",IF(A1<9,"X",IF(A1<19,"Y","Z")))
=IF(A1="","",IF(A1>=19,"Z",IF(A1>=9,"Y","X")))
=IF(AND(1<=A1,A1<9),"X","") & IF(AND(9<=A1,A1<19),"Y","") & IF(19<=A1,"Z","")

方法３：
他にも色々な関数があります。
=LOOKUP(A1,{0,1,9,19},{"","X","Y","Z"})
=CHOOSE(MATCH(A1,{0,1,9,19},1),"","X","Y","Z")

お礼

できました！表を、添付図のように昇順ではなく、降順でつくっていました。昇順に直したら、綺麗にできました！ありがとうございました。

回答No.3

9der-qder

IF関数でも出来ると思います。
質問文の例であれば、
=IF(AND(A1>=1,A1<=8),"x",IF(AND(A1>8,A1<=18),"y","z"))
IF関数の中にIF関数となり、長くなってしまいますがで出来ます。

IF関数が複数入り乱れるときは、フローチャートを書くと整理できます。
【A1が１～８】－Yes→X
　　｜
　　No
　　↓
【A1が９～１８】－Yes→Y
　　｜
　　No
　　↓
　　Z
という具合です。

お礼

回答ありがとうございます。IF関数だと長くなりますが、便利ですね。早く使いこなせるようになりたいです。

回答No.1

entap

1.if関数を使う
2.変換テーブルをどこかに作ってvlookup関数を使う

変換が10種類以上あるなら2がおすすめ。

お礼

回答ありがとうございます。変換は15種あるので、vlookupの方がよさそうですね。