Flashでログファイルの呼び出しのようなプログラム

質問

タイトルのとおりです。

PHPのようにFlashでログファイルの呼び出しのようなプログラムはできますか？

PHPの場合、
あるcsvファイルに、
画像ファイル名・URL・コメント
とを書き、それをリスト化して配列に組み込み、
それを取り出して表示。
といった感じのプログラムをフラッシュでもできないかなと考えています。

環境はFlash CS3です。
アクションスクリプトは2.0を使用していますが、
3.0でもOKです。

回答No.2

BlurFiltan · ベストアンサー

＃１ の方の補足になると思いますが，
CSV の区切り記号(カンマ とか 改行 とか Tab)で split すると，
勝手に配列ができて区切り記号間がその配列の要素になりますから，
それを使えば良いだけです。

SWF(Flash)ファイル，それを表示するHTMLファイル，CSVファイル が同じフォルダにあったとして，
CSV ファイルのファイル名が「log.xml」であったとします。

そして，その「log.xml」内の文字コードが Shift-JIS で，
内容が次のようになっていたとします。

---「log.xml」内データ---------------
aaa.jpg,aaa.html,面白い
bbb.jpg,bbb.html,カッコ良い
ccc.jpg,ccc.html,すばらしい
ddd.jpg,ddd.html,可愛い
------------------------------------

その場合に書くフレームのスクリプト例です↓。
----------------------------------------------------------
// 外部テキストデータを Shift-JIS として読み込む設定
System.useCodepage = true;

// CSV データを格納する配列を作成(後に２次元配列になる)
var csvArr:Array = new Array();

// CSV をロードする LoadVarsクラス のインスタンスを作成
var csvLV:LoadVars = new LoadVars();

// CSVがロードされたときに実行する関数を定義
csvLV.onData = function(myData:String):Void {
// 改行コードを \n に統一
myData = myData.split("\r\n").join("\n").split("\r").join("\n");
// CSVデータを改行コードで区切った配列を一時的に作成
tmpArr = myData.split("\n");
// tmpArr の要素数分ループ
for (var i:Number = 0; i<tmpArr.length; i++) {
// tmpArr の各要素をカンマで区切って csvArr[○] の要素に代入
csvArr[i] = tmpArr[i].split(",");
}
// 出力検証してみる
trace("csvArr[0][0]…"+csvArr[0][0]);
trace("csvArr[0][1]…"+csvArr[0][1]);
trace("csvArr[0][2]…"+csvArr[0][2]);
trace("---------------");
trace("csvArr[3][2]…"+csvArr[3][2]);
};

// csvLV に 「log.csv」 をロード
csvLV.load("log.csv");
----------------------------------------------------------

split 以外のポイントは，

csvLV.onData = function(myData:String):Void {};

です。

この function の引数部分に myData のような適当な変数を書いておくと，
その変数に外部テキストデータが格納されますから，
「データの名指し」が可能になります。

改行コードはデータ作成の時点でわかると思いますから，
本来は「改行コードを\nで統一」の部分は不要だと思います。

私は質問者さんのデータの改行コードなど知りませんから，
改行コードが 「\n」 であっても 「\r\n」 であっても 「\r」 であっても無事に動作するように改行コードを 「\n」 に統一しているだけです。

お礼

ありがとうございました。
大変詳しく教えていただき、助かりました。

お礼が遅くなって申し訳ございませんでした。

回答No.1

Hardking

LoadVarsクラスでテキストファイルを読み込み、その画像ファイルの件数分
動的に配列オブジェクト変数（Arrayクラス）に格納する。
画像ファイル表示する場合は。LoadMovieクラスで表示する。

お礼

ありがとうございました。
無事作成できました。