エクセルでの3つの条件の合計は出せるのでしょうか？

質問

エクセルにて下記の表があって、地域が「海外」で場所が「Ａ」の時「あ」の合計は出せるのでしょうか？
条件が2つの合計の場合はＳＵＭＩＦを使うことは分かるのですが、
3つでも可能なのでしょうか？
宜しくお願い致します。

地域　　　場所　　勘定科目　　合計
海外　　　Ａ　　　あ　　　　　1000
北海道　　Ｂ　　　い　　　　　100
東京　　　Ａ　　　あ　　　　　500
沖縄　　　Ｂ　　　い　　　　　100
海外　　　Ｂ　　　あ　　　　　200
北海道　　Ａ　　　い　　　　　300
東京　　　Ｂ　　　あ　　　　　500
沖縄　　　Ａ　　　い　　　　　400
地域が「海外」で場所が「Ａ」の時「あ」の合計は？

回答No.5

mu2011 · ベストアンサー

ご使用のエクセルバージョンによって、以下の様になります。
■Excel2007の場合
　=SUMIFS(D:D,A:A,"海外",B:B,"Ａ",C:C,"あ")
■Excel2007以外の場合
　=SUMPRODUCT((A2:A100="海外")*(B2:B100="Ａ")*(C2:C100="あ")*(D2:D100))
■配列数式の場合（共通）
　=SUM(IF(A2:A100="海外",IF(B2:B100="Ａ",IF(C2:C100="あ",D2:D100))))
　入力完了時にshift＋ctrl＋enterキーを同時押下します。

お礼

すみません。分かりました。
とても勉強になりました。ありがとうございます。

補足

数式入れると#num! と出るのですが、なぜでしょうか？
SUMPRODUCTについてはなんとなく理解できたのですが・・・

回答No.4

A88No8

mappamさん、こんにちは
　SUMIF関数で配列数式を使ったり色々方法があるみたいですけど、複数条件の場合はほとんどデータベース抽出と同じなのでデータベース関数 DSUM を使うのが自然かなと思います。

(1)元表がA1:D9にあるとすると、次のような検索条件のセルを A11:D12 に用意して

地域　　　場所　　勘定科目
海外　　　Ａ　　　あ　　　

(2)以下の式を立てます。
=DSUM(A1:D9,4,A11:D12)

　あと、データ分析作業の時などデータを手入力するのが面倒！というときは、ピボットテーブルで色々な条件をマウスでいじくり回す方法も手軽です。
　ご存じでしたらスルーして下さいm(__;m

お礼

教えていただきありがとうございます。
私が初心者の為、ＤＳＵＭがうまく理解できませんでした。
これを気にＤＳＵＭを理解したいと思います。
ありがとうございました。

回答No.3

ore-summer

A2からD10までデータがあるとする
=SUMPRODUCT((A2:A10="海外")*(B2:B10="A")*(C2:C10="あ"),D2:D10)

お礼

教えていただきありがとうございます。
SUMPRODUCTについて学びました。これは条件を増やすことが出来るので
応用がききそうですね。
ありがとうございます。

回答No.2

m_inoue222

＃１です

ごめんなさい．．．「海外　Ｂ　あ　200」は違いましたね

回答No.1

m_inoue222

私はエクセルに精通していない人にでも判るような表を作ることを心がけています
引き継いだ担当者に分かり易いように単純な最低限の関数を使用していますので参考になるかどうかは判りませんが．．．

＿＿A＿＿B＿C＿＿D＿＿E＿＿＿＿＿＿＿＿＿F＿＿＿＿＿＿＿G
1＿＿＿＿＿＿＿＿＿＿＿if A1=海外 then D1 　if B1=Ａ then E1 if C1=あ then F1
2＿海外＿Ａ＿あ＿500＿（５００）＿＿＿＿（５００）＿＿＿＿（５００）　
3＿北海道Ｂ＿い＿100
4＿東京＿Ａ＿あ＿500
5＿沖縄＿Ｂ＿い＿100
6＿海外＿Ｂ＿あ＿200＿（２００）＿＿＿＿（２００）＿＿＿＿（２００）　
7＿北海道Ａ＿い＿300
8＿東京＿Ｂ＿あ＿500
9＿沖縄＿Ａ＿い＿400

でG列を合計すれば結果として求める集計が出来るのでは？

お礼

教えていただきありがとうございます。
誰にでも分かるようにしていたほうがいいですよね。
本当にそうです。
thenなどを使ったことがなかったので、今度勉強してみます。
ありがとうございます。