データを抽出したいのです

質問

以下のようなデータがあり抽出したいのです（エクセルもしくはアクセス）。実際は何千件もあります。
2007年生まれで、その子どもの続柄が「3」ならば世帯主（1）または妻（2）以外の1987生まれ以前の人がいる世帯。
またはその子どもの続柄が「子の子」ならばその世帯。
この例の場合、世帯番号で２、５、８が該当世帯です。
よろしくお願いします。

1:世帯主
2:妻
3:子
4:子の子
5:その他

世帯番号　　生年　　続柄
1 1967 1
1 1972 2
1 2001 3
1 2007 3
2 1948 1
2 1950 2
2 1972 3
2 1974 3
2 2005 4
2 2007 4
3 1968 1
3 1973 2
3 2007 3
4 1974 1
4 2007 3
5 1968 1
5 1973 2
5 2007 3
5 1940 5
6 1975 1
6 2003 3
6 2007 3
7 1970 1
7 1974 2
7 2007 3
7 1995 5
8 1949 1
8 1969 3
8 1974 3
8 2007 4
9 1974 1
9 1975 2
9 2006 3
10 1949 1
10 1950 2
10 1970 3
10 1975 3
10 2005 4

回答No.6

fumufumu_2006

excelのVBAです。
元データはsheet1にあるとします。
抽出結果はsheet2のA列の2行目からに表示します。
checkを実行してください。

Sub check()
Sheet2.Cells.Clear
Dim lastRow As Integer
Dim sRow As Integer
Dim eRow As Integer
Dim i As Integer

lastRow = Sheet1.Cells(Sheet1.Rows.Count, 1).End(xlUp).Row
sRow = 2
For i = 2 To lastRow
If Sheet1.Cells(i, 1) <> Sheet1.Cells(sRow, 1) Then
eRow = i - 1
checkFamily sRow, eRow
sRow = i
End If
Next
checkFamily sRow, lastRow
End Sub

'1世帯チェック
Sub checkFamily(sRow As Integer, eRow As Integer)
Dim 子2007年生まれ As Boolean
Dim 子の子2007年生まれ As Boolean
Dim 世帯主または妻以外の1987生まれ以前の人 As Boolean

Dim i As Integer
For i = sRow To eRow
If (Sheet1.Cells(i, 2) = 2007) And (Sheet1.Cells(i, 3) = 3) Then
子2007年生まれ = True
End If
If (Sheet1.Cells(i, 2) = 2007) And (Sheet1.Cells(i, 3) = 4) Then
子の子2007年生まれ = True
End If
If (Sheet1.Cells(i, 3) <> 1) And (Sheet1.Cells(i, 3) <> 2) And (Sheet1.Cells(i, 2) < 1987) Then
世帯主または妻以外の1987生まれ以前の人 = True
End If
Next
If ((子2007年生まれ = True) And (世帯主または妻以外の1987生まれ以前の人 = True)) Or (子の子2007年生まれ = True) Then
Sheet2.Cells(Sheet2.Cells(Sheet2.Rows.Count, 1).End(xlUp).Row + 1, 1) = Sheet1.Cells(sRow, 1)
End If
End Sub

お礼

遅くなって申し訳ありません。回答ありがとうございました。