エクセルでの桁数一致セルの個数

質問

エクセルで、いくつか数字のデータがあるのですが、
そこから（例えば）３桁の数字が入ったセルがいくつあるのかを知りたい時は、どの様に関数を作ればよいのでしょうか。

データ数が多いので、
IF(AND(A1>=100,A1<1000),1,0)+IF(AND(B1...
というようなふうには作れません。

うまく処理できないでしょうか。お願いします。

回答No.5

grumpy_the_dwarf

数値の桁数はint(log(数値))+1で出るんだけど、logを含むから文字
列や空白や0があるとエラーになるんですよね。lenは小数点がある
と使えないし。というわけで、ksishiさんの回答をベースにして、

moji　　　　　0　　 　1780
5780　 　　1260　　　10440
135.2　　　2500　　 　8000
500　　　　1360　　　　600
10560　　　1050　　　　640
2210　　　 1260　　　　370

=sumproduct((A1:C6>=10^(桁数-1))*1, (A1:C6<10^桁数)*1)

回答No.4

imogasi

例データ
112 232 23 45 678
112 2 2323 145 678
23 4567 23 45 34
112 56 45 1 1567
２桁の数の数
=SUMPRODUCT((LEN(A1:E5)=2)*1)
結果
８
ーー
３桁なら
=SUMPRODUCT((LEN(A2:E5)=3)*1)
結果
７
ーー
配列数式では
=SUM(IF(LEN(A2:E6)=2,1,0))
SHIFT、CTRL,ENTERキーを同時押し。
文字列があれば
=SUMPRODUCT((LEN(A2:E5)=3)*(ISNUMBER(A2:E5))*1)

回答No.3

ksishi

Ｎｏ１です。
条件式は文字列のようですね。

""の位置を変えてと文字列をつなぐ＆で数式をいれることができました。（カッコが増えましたが）

=COUNTIF($Sheet1!A1:$Sheet1!A300,">="&(10^(A1-1)))-COUNTIF($Sheet1!A1:$Sheet1!A300,">="&(10^A1)）

他にもイイ方法があるかもですが、countifにこだわってみました^^

回答No.2

mu2011

次の方法は如何でしょうか。
=SUMPRODUCT(ISNUMBER(A1:A100)*(LENB(A1:A100)=3))

回答No.1

ksishi

もっとイイ方法があるかも知れませんが・・・

=COUNTIF(A1:A300,">100")-COUNTIF(A1:A300,">999")

で、どうでしょうか？

補足

なるほど！countifで範囲指定が出来たんですね。
ありがとうございます。
countifの条件式で他のセルを参照させることは出来ないのでしょうか。
結果画面に

　 　Ａ　　Ｂ
１ ２桁　○個
２ ３桁　○個
３ ４桁　○個
：　：　　：
の様に表示させたいのです。

=COUNTIF($Sheet1!A1:$Sheet1!A300,">=10^(A1-1)")-COUNTIF($Sheet1!A1:$Sheet1!A300,">=10^(A1)")
の様な感じで実装したいのですが、無理みたいです。。