Excel2000のセル内の文字列の数字の先の２桁を取り出す方法について

質問

年のいった初心者です。
以前の質問に対する回答有難うございます。また、教えてください。
　エクセル2000です。セル内に数字の文字列で、４桁、６桁、８桁のものが有ります。４桁のものには"01"を、６桁のものには"60"を、表示し、８桁のものには数種類あり、８桁の場合は、各文字列で上位の２桁を表示したいのです。
=IF(LEN(A1)=4,"01",IF(LEN(A1)=6,"60",IF(LEN(A1)=8,??????
４桁、６桁については以前に教えていただいた、関数等でいけたのですが、８桁のときが分かりません。困っています。お願いします。
　　　 A列　　　　B列
1 7532 →→ 01
2 280573 →→ 60
3 34964821 →→ 34
4 06839775 →→ 06
5 67500023 →→ 67

回答No.1

hirorin00 · ベストアンサー

はじめまして

これでいかがでしょうか？

=IF(LEN(A1)=4,"01",IF(LEN(A1)=6,"60",IF(LEN(A1)=8,LEFT(A1,2))))

なお
=IF(LEN(A1)=4,"01",IF(LEN(A1)=6,"60",IF(LEN(A1)=8,LEFT(A1,2),"")))
にすると、4桁、６桁、8桁以外の時に「FALSE」は出なくなります。

的外れでしたらごめんなさい

お礼

すぐに回答頂き有難うございます
おかげさまで解決しました

回答No.5

sige1701

回答がたくさんでていますので、お遊びで
=LEFT(RIGHT("0160"&A1,8),2)

お礼

すぐに回答頂き有難うございます
おかげさまで解決しました

回答No.4

imogasi

例データ
A1:A5
A列　　B列
7532 01
280573 60
34964821 34
06839775 06
67500023 67
B1に
=LEFT(IF(LEN(A1)=4,"01"&A1,IF(LEN(A1)=6,"60"&A1,A1)),2)
と入れて、B5まで式を複写。
結果
上記B列

お礼

すぐに回答頂き有難うございます
おかげさまで解決しました

回答No.3

redowl

=IF(OR(LEN(A1)=4,LEN(A1)=6,LEN(A1)=8),CHOOSE(LEN(A1)/2-1,"01","60",LEFT(A1,2)),"")

IF関数で
４桁、６桁、８桁　ならば　CHOOSE関数を実行。　出なければブランク

A1文字数を２で割り　１をマイナス　で、
　４桁の時は１、６桁の時は２、８桁の時は３
それに対応した
"01","60",LEFT(A1,2)　　を表示

お礼

すぐに回答頂き有難うございます
おかげさまで解決しました

回答No.2

heygoro

とりあえず、8ケタの数字について。
=IF(LEN(A1)=8,LEFT(A1,2))
アタマだししたければ、left関数を使えば意図したことは表現できます。
逆におしりから出したければleft→right関数で同じようになります。

お礼

すぐに回答頂き有難うございます
おかげさまで解決しました