エクセルで税抜き価格を入れて自動的に税込み価格に変換させたい

質問

エクセルでセルに税抜き価格を入力したら、自動的に税込価格に
変換されるようにするにはどうすればいいのでしょうか？
よろしくお願い致します。

回答No.6

ka_na_de · ベストアンサー

こんにちは。

補足質問の件ですが、こういう意味です。
Private Sub Worksheet_Change(ByVal Target As Range)
　Application.EnableEvents = False
　If Target.Address = "$B$2" And IsNumeric(Target.Value) Then
　　Target.Value = Int(Target.Value * 1.05)
　End If
　Application.EnableEvents = True
End Sub

このコードを以前の解説に従って貼り付けてください。

（注意）
この例では、B2セルに値を入れた場合のみ税率をかけるように
記述されています。

余談ですが、
もし、B列のどのセルでも税率計算したい場合は、
Target.Address = "$B$2"
の部分を、例えば
Target.Column = Range("B1").Column
に置き換えてください。

以下は、税率なども変数にした場合です。
興味があれば参考にしてください。
Private Sub Worksheet_Change(ByVal Target As Range)
　On Error GoTo ErrorTrap
　Dim TaxRate As Single
　Dim Col As String

　TaxRate = 5　 　'税率５％
　Col = "B" 　　 'B列に適応

　If Selection.Count > 1 Then Exit Sub

　Application.EnableEvents = False
　If Target.Column = Range(Col & 1).Column And IsNumeric(Target.Value) Then
　　Target.Value = Int(Target.Value * (100 + TaxRate) / 100)
　End If
　Application.EnableEvents = True
　Exit Sub

ErrorTrap:
　Application.EnableEvents = True
　MsgBox "エラー番号:" & Err.Number
　Resume Next
End Sub

お礼

この度はとても親切に教えていただきまして
ありがとうございました。
結局B列に適応できるようにコードを貼り付けましたら
無事にできました。
本当に助かりました。