FLASHでHPのメニュー画面

質問

FLASHを使って、ホームページのメニューを作りたいと思っています。
そこで、SONYのホームページのようにボタンを押すと、メニュー画面がスクロールして表示され、もう一度ボタンを押したらフレームが逆再生されてメニュー画面が消えるようにしたいと思い下記のように作成しました。
（suzuki-_-さんの方法を参考にして作らせていただきました。QNo.2540039）

MC１に
this.onEnterFrame=function(){
if(aaa%2==0){
this.prevFrame();
}if(aaa%2==1){
this.nextFrame();
}
}

ボタン１に
on(press){
aaa=aaa+1;
｝

としていました。
これでうまく動いていたのですが、ここでボタン２を作り、もう一つ同様のアクションをするものを作ったのですが、この場合MC１が表示されている場合、MC１を引っ込めてから、MC２を実行しようとして、以下のようにしたのですがうまく動作しません。どのようにしたらいいかアドバイスをお願いします。

MC1
this.onEnterFrame=function(){
if(aaa%2==0){
this.prevFrame();
}if(aaa%2==1){
this.nextFrame();
}
}

ボタン１
on(press){
aaa=aaa+1;

if(bbb%2==1){
bbb=bbb+1;
}
}

MC２
this.onEnterFrame=function(){
if(bbb%2==0){
this.prevFrame();
}if(bbb%2==1){
this.nextFrame();
}
}

ボタン２
on(press){
bbb=bbb+1;

if(aaa%2==1){
aaa=aaa+1;
}
}

これをメインのフレームに配置したのですがうまく動作しませんでした。
一応調べてみると、変数は定義したMCの中だけでしか有効ではないらしいということがわかりました。どうすれば、目的の動作が動くか教えていただきたいです。よろしくお願いします。

回答No.1

suzuki-_-

> 一応調べてみると、変数は定義したMCの中だけでしか有効ではないらしいということがわかりました。

定義したMCの中だけで有効なのは、その変数名"のみ"での参照のことです
例えば、MC1(インスタンス名)の中で A = 1; とし、他の階層で B = A としても、Bの中に 1 は代入されません
しかし、その変数名"のみ"で呼び出せないだけで、その階層を指定して変数名を呼び出せば代入することができます
_root（仕様で決まっている最上階層（名））にMC1が置いてある状態で、MC1の変数Aを呼び出したい場合は _root.MC1.A となります
なので、先ほどのBにMC1のAを代入したいならば、 B = _root.MC1.A とすることで、Bに 1 を入れることが出来ます

_rootからの指定は、絶対パス（絶対指定）等と呼ばれます

絶対に対して、相対というのも存在します
これは、自分の階層から見てのパスです
先ほどのMC1から _root へのパスは _parent( = 一個上階層と覚えると早い)となり、MC1から見た_root.B の相対パスは _parent.B となります

_root（ここから見る変数Aは _root.MC1.A or MC1.A or this.MC1.A etc）
　├ 変数B
　└ MC1（この中から見る変数Bは_parent.B or _root.B etc）
　　　└変数A

//
ここからが本題です
ちなみに「うまくいきません」というのは質問の際はタブーです
回答側はどううまくいっていないのか（エラー？一部だけ動く？等）わかりませんので。。。

基本的に質問者さんのスクリプトを使用して、前途のパスも使いつつ解決策を記述します

■mc1（プロパティのインスタンス名に付ける名前）の"中"のフレーム１に記述
stop();
this.onEnterFrame = function() {
if ((_parent.aaa%2 == 0 || _parent.targetMC != this._name) && _currentframe != 1) {
this.prevFrame();
if (_currentframe == 1 && _parent.targetMC != this._name) {
_parent.aaa = 1;
}
} else if (_parent.aaa%2 == 1) {
if (_parent.mc2._currentframe == 1 && _parent.targetMC == this._name) {
this.nextFrame();
}
}
};

■mc2（同上）の中のフレーム１に記述
mc1と同じものを記述して、下から５行目のmc2をmc1に変更

■ボタン１（インスタンス名は特になし）に記述
on (press) {
aaa = aaa%2+1;
targetMC = "mc1";
}
■ボタン２（同上）に記述
on (press) {
aaa = aaa%2+1;
targetMC = "mc2";
}
■ボタン１．ボタン２、mc1、mc2を置いている階層のフレームに記述
aaa = 0;

想定する階層は下記のような感じです
_root
　├ mc1
　├ mc2
　├ ボタン１
　└ ボタン２

内容は説明するとすごく長くなりそうなので、ヘルプを参照したりして解読しながら進めてみてください

//おまけ（ActionScriptに慣れてきたら）

■各配置は一緒
■ボタン１にbt1というインスタンス名を、ボタン２にはbt2をつける
■全てを置いてある階層のフレームに以下を記述
bt1.onPress = function() {
MC_MOVE(this._parent.mc1);
};
bt2.onPress = function() {
MC_MOVE(this._parent.mc2);
};
function MC_MOVE(TARGET) {
if (SET_MC == undefined) {
TARGET.onEnterFrame = MC_GO;
SET_MC = TARGET;
TARGET.FLAG = "GO";
} else if (TARGET == SET_MC && TARGET.FLAG != undefined) {
switch (TARGET.FLAG) {
case "GO" :
TARGET.onEnterFrame = MC_BACK;
TARGET.FLAG = "BACK";
break;
case "BACK" :
TARGET.onEnterFrame = MC_GO;
TARGET.FLAG = "GO";
break;
}
} else {
SET_MC.onEnterFrame = MC_BACK;
SET_MC = TARGET;
SET_MC.FLAG = "WAIT";
}
}
function MC_GO() {
this.nextFrame();
if (this._currentframe == this._totalframes) {
delete this.onEnterFrame;
}
}
function MC_BACK() {
this.prevFrame();
if (this._currentframe == 1) {
delete this.onEnterFrame;
if (SET_MC != this) {
SET_MC.onEnterFrame = MC_GO;
SET_MC.FLAG = "GO";
} else {
SET_MC = undefined;
}
this.FLAG = undefined;
}
}

他は特に記述なし（mc1/2のフレーム１にstop();位）