画像をランダムに表示させたい（ＶＢ6.0）

質問

A、B、C、D、E、Fの６枚の画像を用意して
ボタンを押すごとにA、B、Cの3枚の画像をランダムに表示させる方法を教えて下さい。

また、
Aが表示されたとき、キーボードの「Ａ」を押すとDを表示
Bが表示されたとき、キーボードの「Ｂ」を押すとEを表示
Cが表示されたとき、キーボードの「Ｃ」を押すとFを表示
としたいのですが・・・。

どなたかご教授お願いします。

回答No.4

kabilunlun · ベストアンサー

#1です。訂正版です。
前準備として、
　1.フォーム上にピクチャーボックス(Picture1)、コマンドボタン(Command1)を配置。
　2.フォームのKeyPreviewプロパティをTrueにする。(KeyPressイベントを他のコントロールより先に受け取るため。)
次にフォームモジュールに以下のように記述することでできました。

Dim strABC As String '(フォーム)モジュールレベルの変数

Private Sub Command1_Click()
　　Dim intRND As Integer

　　Randomize '乱数発生ルーチンを初期化

　　intRND = Int(3 * Rnd + 1) '1～3の間で乱数を発生

　　'intRND(1～3の整数)の値からA,B,Cの画像を表示。strABCにどの画像を表示したか設定。
　　Select Case intRND
　　　　Case 1
　　　　　　Picture1.Picture = LoadPicture("C:\A.BMP")
　　　　　　strABC = "A"
　　　　Case 2
　　　　　　Picture1.Picture = LoadPicture("C:\B.BMP")
　　　　　　strABC = "B"
　　　　Case 3
　　　　　　Picture1.Picture = LoadPicture("C:\C.BMP")
　　　　　　strABC = "C"
　　End Select
End Sub

Private Sub Form_KeyPress(KeyAscii As Integer)
　　If UCase(Chr(KeyAscii)) = "A" And strABC = "A" Then
　　　　Picture1.Picture = LoadPicture("C:\D.BMP")
　　ElseIf UCase(Chr(KeyAscii)) = "B" And strABC = "B" Then
　　　　Picture1.Picture = LoadPicture("C:\E.BMP")
　　ElseIf UCase(Chr(KeyAscii)) = "C" And strABC = "C" Then
　　　　Picture1.Picture = LoadPicture("C:\F.BMP")
　　End If
End Sub

お礼

回答ありがとうございます！
訂正版ありがとうございました。
また、KeyPreviewプロパティについても教えて頂きありがとうございました。