エクセルVBAで検索結果セル位置抽出時、実行時エラーが出ます。

質問

エクセルＶＢＡで
　・シート"log"のA列にある文字列(A1="AB<CD>EF")を２つにわけて、それぞれシート"edit"のセルに保存(A1="<CD>")(B1="EF")し
　・さらにA1セルをシート"NameList"にあるリストを元に置換する
という作業をさせるマクロを組んでいるのですが、
途中で「アプリケーション定義またはオブジェクト定義のエラーです」が出て困ってます。
組んだマクロは下記の通りです。

Option Explicit
Option Base 1

Sub Edit()

Dim i As Integer
Dim log_lastrow As Integer
Dim list_lastrow As Integer
Dim all As String
Dim main As String
Dim hn As String
Dim chr() As Variant
Dim j As Integer
Dim k As Integer
Dim chrname As String
Dim cell As Range
Dim line As Integer

log_lastrow = 100
list_lastrow = 100
ReDim chr(list_lastrow, 4)
For j = 1 To list_lastrow
For k = 1 To 2
chr(j, k) = Sheets("NameList").Cells(j , k).Value
Next
Next

For i = 1 To log_lastrow
all = Sheets("log").Cells(i, 1).Value
hn = Mid(all, InStr(all, "<"), (InStr(all, ">") - 2))
main = Right(all, Len(all) - InStr(all, ">"))
Set cell = Sheets("NameList").Columns("A:A").Find(what:=hn, lookat:=xlWhole, MatchCase:=True, matchbyte:=True)
line = Sheets("NameList").Range(cell).Row
　chrname = chr(line, 2)
Sheets("edit").Cells(i, 1).Value = chrname
Sheets("edit").Cells(i, 2).Value = main
Set cell = Nothing
Next
End Sub

下から７行目の
line = Sheets("NameList").Range(cell).Row
１行上で検索されたセル位置情報の行番号をlineに入れようと思ったのですが、ここでエラーが出ます。何が悪いのかよろしくご教授願います。

回答No.2

papayuka · ベストアンサー

#1です。

Set cell = Sheets("NameList").Columns("A:A").Find(what:=hn, lookat:=xlWhole, MatchCase:=True, matchbyte:=True)
line = Sheets("NameList").Range(cell).Row

この２行を下の６行にしてみて下さい。

Set cell = Sheets("NameList").Columns("A:A").Find(what:=hn, lookat:=xlWhole, MatchCase:=True, matchbyte:=True)
If cell Is Nothing Then
　 MsgBox hn & "は見つかりません"
　 Exit Sub
End If
line = cell.Row

恐らく「見つかりません」メッセージが出ると思いますが如何ですか？
Findは見つからない場合にNothingを返します。
変数 cell に発見した range が Set されないままでは当然
「オブジェクト変数またはwithブロック変数が設定されていない」
と言うエラーが出ます。

各シートにどんなデータが入っているか解らないので、これ以上は検証出来ませんけど。

お礼

ありがとうございました。
MsgBoxのお陰で原因がNameListにあることが判明しました！

お陰で、マクロ完成しました。ありがとうございました！！！

回答No.3

papayuka

#1です。

推測だけで書換えてみました。
シートの状況が解らないので上手く動く保障はありません。
試すならテスト環境で。

Sub Test()
Dim log_lastrow As Long, i As Long, myCell As Range
Dim all As String, hn As String

log_lastrow = Worksheets("log").Range("A65536").End(xlUp).Row

For i = 1 To log_lastrow
　　all = Worksheets("log").Cells(i, 1).Value
　　hn = Mid(all, InStr(all, "<"), (InStr(all, ">") - 2))
　　Set myCell = Worksheets("NameList").Columns(1).Find _
　　　　　　　　 (what:=hn, lookat:=xlWhole, MatchCase:=True, matchbyte:=True)
　　If Not myCell Is Nothing Then
　　　 Worksheets("edit").Cells(i, 1).Value = myCell.Offset(0, 1).Value
　　　 Worksheets("edit").Cells(i, 2).Value = Right(all, Len(all) - InStr(all, ">"))
　　Else
　　　 Worksheets("edit").Cells(i, 1).Value = Null
　　　 Worksheets("edit").Cells(i, 2).Value = Null
　　End If
Next i

End Sub

回答No.1

papayuka

通読してませんが、cell as range ですから、
　line = Sheets("NameList").Range(cell.address).Row
または
　line = cell.Row
にしたらどうなります？

お礼

早速のご回答ありがとうございます。
残念ながら、いずれも、
「オブジェクト変数またはwithブロック変数が設定されていない」
と出ます。よろしくご教授願います。