円拡大（スクリプト制御）

質問

ステージ（０，０）の位置に10pxの円、右に２００ｐｘ移動後下に１００ｐｘ移動後、左上基準点で50pxに拡大したいしてストップさせてロールオーバーしたら、逆再生して最初に戻すには、どうしたらいいのでしょうか？拡大してストップまでは分かるのですが、もとに戻すには、トゥイーンではなく、スクリプトではどうしたらいいのでしょうか？

回答No.3

BlurFiltan

すみません。＃１と＃２で回答した者です。

「"ロールオーバー"で逆再生を開始」 でしたね。ロールオーバーのことを忘れていました。
＃２の回答の続きということで、
さらに on (rollOver) で flag の値を変えるという部分を付け加えます。

＃２ の下の方のスクリプトだと、flag だけで動きをコントロールしているので、
さらに付け加えをするのが簡単になります。

on (rollOver) がムービークリップに書けるようになったのは Flash MX以降なので、
勝手にバージョンを上げさせてもらって、Flash MX 以降対応のスクリプトにしました。

───────────────────
// === MCが表示されたときに実行 ===
onClipEvent (load) {
// このMCの初期サイズを記録
var myW = this._width;
var myH = this._height;
// on(event)ハンドラ を無効に
this.enabled = false;
// 変数 flag の初期値を設定
var flag = 0;
//--- 各 myFunc0～6 の関数を定義　---
// 右へ移動する関数の定義
function myFunc0() {
this._x += (200-this._x)/3;
}
// 下に移動する関数の定義
function myFunc1() {
this._y += (100-this._y)/3;
}
// 拡大する関数の定義
function myFunc2() {
this._width += (50-this._width)/3;
this._height += (50-this._height)/3;
}
// サイズを固定する関数の定義
function myFunc3() {
// on(event)ハンドラ を有効に
this.enabled = true;
this._width = this._width;
this._height = this._height;
}
// 縮小する関数の定義
function myFunc4() {
// on(event)ハンドラ を無効に
this.enabled = false;
this._width += (myW-this._width)/3;
this._height += (myH-this._height)/3;
}
// 上に移動する関数の定義
function myFunc5() {
this._y += (0-this._y)/3;
}
// 左に移動する関数の定義
function myFunc6() {
this._x += (0-this._x)/3;
}
}

// === ロールオーバーで flag を 4 にする ===
on (rollOver) {
flag = 4;
}

// === 随時実行 ===
onClipEvent (enterFrame) {
// 条件による flag の切り換え
if (flag == 0 && this._x>199) {
flag = 1;
} else if (flag == 1 && this._y>99) {
flag = 2;
} else if (flag == 2 && this._width>49) {
flag = 3;
} else if (flag == 4 && this._width<myW+1) {
flag = 5;
} else if (flag == 5 && this._y<1) {
flag = 6;
}
// 関数 myFunc? を実行 (? は flag の値によって変わる)
this["myFunc"+flag]();
}
───────────────────

↑ムービークリップにコピー＆ペーストしてもらうと、
Flash MX 以降(Flash Player 6 以上) では動作すると思います。

on (rollOver) で
「flag が 3 のときだけ、flag を 4 にする」 というスクリプトにしても良かったのですが、
また if文が増えることにもなりますし、ボタンとして機能しないときにカーソルが変わるのも変ですから、
初期設定で enabled = false; の状態にしておいて、
定義関数で enabled = true; と enabled = false; を切り換える方法にしました。
enabled = true;　で on(event)ハンドラ が有効になり、
enabled = false;　で on(event)ハンドラ が無効になります。
ですから、拡大した状態で初めて on (rollOver) が有効になります。

補足

とてもわかりやすい説明ありがとうございます。

こういう基本的な動きの場合を、応用する時も含めてなのですが、
やり方はいろいろあると思うのですが、プロ中のプロが、動かす場合
どういった方法が、一般的なのでしょうか？