flashで箱の真上にくるまで○を移動させる。

質問

○

■
このような状態の時に○を■の上までアクションスクリプトを用いて移動させたいのです。線を引いてモーションテゥーインの方法で動かすのは分かるのですが、これをアクションスクリプトを用いてやりたいと思ったのですがどのようにやったらよいのか全く分からず困っています。どなたか教えてください。お願いします。

回答No.1

BlurFiltan · ベストアンサー

○を■の上までと書かれている文章が，
○と■をまったく同じ座標に重ねる（レイヤー的に上）と言う意味で書かれたのか，
モニタ上で見たとき■の上まで○を持ってくる（ｘ座標を左に移動するだけ）と言う意味で書かれたのか，わかりかねましたので，両方回答しておきます。

まず，○も■も，ムービークリップシンボルにしてください。してあったらそのままでかまいません。

次に，○を目標物体である■に近づけるため，■にインスタンス名を付けてください。
インスタンス名はプログラム的に何の意味も持たない文字列であれば何でも良いですが，
ここでは■に「square」というインスタンス名をつけたとしておきます。

◎ 一定の速度で近づけるスクリプト

○に以下のようなスクリプトを書けば，
その○が画面に表示されたとたんに■に向かって動きだし，■と重なれば止まるスクリプトになります。

onClipEvent (load) {
//スピードの設定（変更箇所）
spd = 20;
//移動距離の算出
movement_x = (_root.square._x-this._x)/spd;
movement_y = (_root.square._y-this._y)/spd; //※
//変数counter（カウンタ）を初期化
counter = 0;
}
//１フレーム時間に毎回計算
onClipEvent (enterFrame) {
//カウンタを1ずつ加算
counter++;
//ｘ座標とｙ座標を移動
this._x += movement_x;
this._y += movement_y; //※
//もしcounterがspdを上回れば
if (counter>=spd) {
//重なった位置を保持
this._x = _root.square._x;
this._y = _root.square._y; //※
}
}

このスクリプトで変更する箇所は１箇所です。
変数 spd の値を仮に 20 としていますが，この値を変えてください。
一応スピードの設定のつもりで書いたので spd としていますが，
spd の値が大きいほど遅く，小さいほど速くなります。逆数になっています。

//※と書いた行が３行あります。
モニタ上で見たとき■の上まで○を持ってくる（ｘ座標を左に移動するだけ）と言う意味で質問を書かれていた場合，この※の行を消してください。※の行はｙ座標を変化させる部分です。

◎ 近づくにつれてだんだん減速するスクリプト

これがActionScriptでよく見かける動きで，
FlashMX2004まででは，モーショントゥイーンでは表現できない動きです。
これも，○に書いてください。

onClipEvent (load) {
//スピードの設定（変更箇所）
spd=10;
}
//１フレーム時間に毎回計算
onClipEvent (enterFrame) {
//座標を徐々に近づける
this._x += (_root.square._x-this._x)/spd;
this._y += (_root.square._y-this._y)/spd;//※
}

このスクリプトで変更する箇所も１箇所です。
変数 spd の値を仮に 10 としていますが，この値を変えてください。
これもスピードの設定のつもりで書いたので spd としていますが，
spd の値が大きいほど遅く，小さいほど速くなります。

//※と書いた行が１行あります。
モニタ上で見たとき■の上まで○を持ってくる（ｘ座標を左に移動するだけ）と言う意味で質問を書かれていた場合，この※の行を消してください。

動き自体は面白いですが，スクリプトは上のものより簡単になります。

上のスクリプトも下のスクリプトも，小学算数のレベルで書ける四則演算です。
一度，したいことを計算式で書いてみて，スクリプトにすると良いかもしれません。

お礼

質問文が不十分で申し訳ありませんでした。丁寧に両方の場合について回答していだたきましてありがとうございました。早速明日、両方をやってみようと思ってます。丁寧なわかりやすい回答をありがとうございました。