エクセルで指定フォルダ内の増加ファイルの一覧を作る

質問

• エクセルで特定のフォルダ内に新しく追加されるファイルの一覧を作成する方法について教えてください。
• 特定のフォルダ内に不定期に新しいフォルダが作成され、その中にPDFファイルが保存されています。エクセルでその新しく追加されるファイルの一覧を作成する方法を教えてください。
• サーバ上の特定のフォルダ内に新しく追加されるファイルのフルパスとファイル名をエクセルシートに追加する方法について教えてください。

回答No.9

HohoPapa · ベストアンサー

・6行目から出力
・D列にPDFファイルの作成日時を出力
を仕込みました。

Option Explicit

'以下を参照設定
'Microsoft Scripting Runtime

Dim BaseDir As String　'親フォルダー名
Dim BorderDay As Date
Dim RowCount As Long

Sub sample()

　With ThisWorkbook.Sheets("Sheet2")　　'フォルダー名、日付格納シート
　　BaseDir = .Cells(1, 1).Value
　　BorderDay = .Cells(2, 1).Value
　End With

　' 出力先シートをクリアー
With ThisWorkbook.Sheets(1)
　　Range(.Rows(6), .Rows(Rows.Count)).ClearContents
　End With

　RowCount = 5　　'6行目から出力
　getFilesRecursive (BaseDir)

End Sub

'フォルダー、ファイルを総当たり
Sub getFilesRecursive(path As String)

　Dim FSO As FileSystemObject: Set FSO = New FileSystemObject
　Dim objFolder As folder
　Dim objFile As file

　'フォルダーを個々に取得
　For Each objFolder In FSO.GetFolder(path).SubFolders
　　getFilesRecursive objFolder.path
　Next

　'ファイルを個々に取得
　For Each objFile In FSO.GetFolder(path).Files
　　If UCase(FSO.GetExtensionName(objFile.path)) = "PDF" Then
　　　execute objFile
　　End If
　Next

End Sub

'取得したファイルをリストアップ
Sub execute(f As file)

　Dim FNameParts As Variant
　Dim PartsCount As Long
　Dim MidDir As String
　Dim FName As String

　'作成日時が指定日以前のファイルは無視する
　If f.DateCreated < BorderDay Then Exit Sub

　RowCount = RowCount + 1

　With ThisWorkbook.Sheets("Sheet1")　　　'出力先シート

　　Range(.Cells(RowCount, 1), .Cells(RowCount, 3)).NumberFormatLocal = "@"
　　.Cells(RowCount, 4).NumberFormatLocal = "yyyy/m/d h:mm;@"

　　.Cells(RowCount, 1).Value = BaseDir & "\"
　　MidDir = Mid(f.path, Len(BaseDir) + 2, InStrRev(f.path, "\") - Len(BaseDir) - 1)
　　.Cells(RowCount, 2).Value = MidDir
　　FName = Mid(f.path, InStrRev(f.path, "\") + 1, 256)
　　.Cells(RowCount, 3).Value = FName

　　.Cells(RowCount, 4).Value = f.DateCreated

　　.Hyperlinks.Add Anchor:=.Cells(RowCount, 3), _
　　　　Address:=f.path, TextToDisplay:=FName

　End With

End Sub

お礼

完璧！！

昨夜ご回答があったのを確認したので朝一で先ず確認。
結果が1行目から出力されていると思って、ここは自分で出来ると意気込んでコードを見たら丁寧な解説付きで6行目以下に設定されていました。
原因は前回の検索結果が残っていただけでした。流石の忖度に感心。

また前回言い忘れましたが、パスの区切りが親ホルダ＋その他＋品名の3区分は最高です。
B列で担当部署、顧客名、製品名がフィルタ出来ます。（この作業をAA列以降でセルの結合関数でやるつもりでした）

更に日付が付加されたことで一覧表の使い方が増えます。
これは作業の精度と効率の向上のみならず、作業の質が変わってきます。
重複削除や最新版管理にも可能性が出てきましたし、半年に一度ではなく月報単位で最新版管理ができます。（ボタンをクリックしてトイレに行って帰ってくる頃には完了）

フォルダ、ファイルの増減管理、リンクの生き死にではなく、常に最新版管理出来ればメンテ不要と言うことになってきます。

現状は部署（フォルダ）毎に同じファイルが有ったり旧版と最新版が有ったりしているのを許容していますがこれも改善できる可能性が出て気ました。

お礼と賞賛の言葉が尽きませんが先ずはここまで。

貴方は何をなさっている方なの？（by 和田アキ子）

補足

＞ここは自分で出来る・・
は間違いで、削除範囲の6行目以降の設定との思い違いで、出力範囲の設定ではありません。

興奮気味でした。
このVBA凄くは凄くて他にも使えそうな気がします
当方の知識ではすぐに具体的な用途思いつきませんが。。。
恐らくその時にはまた改定をお願いすることになると思いますので宜しくお願い致します。