エクセルで指定フォルダ内の増加ファイルの一覧を作る

質問

• エクセルで特定のフォルダ内に新しく追加されるファイルの一覧を作成する方法について教えてください。
• 特定のフォルダ内に不定期に新しいフォルダが作成され、その中にPDFファイルが保存されています。エクセルでその新しく追加されるファイルの一覧を作成する方法を教えてください。
• サーバ上の特定のフォルダ内に新しく追加されるファイルのフルパスとファイル名をエクセルシートに追加する方法について教えてください。

回答No.8

HohoPapa

こんな感じでどうでしょうか。

Option Explicit

'以下を参照設定
'Microsoft Scripting Runtime

Dim BaseDir As String　'親フォルダー名
Dim BorderDay As Date
Dim FileCount As Long

Sub sample()

　With ThisWorkbook.Sheets("Sheet2")　　'フォルダー名、日付格納シート
　　BaseDir = .Cells(1, 1).Value
　　BorderDay = .Cells(2, 1).Value
　End With

　' 出力先シートをクリアー
　With ThisWorkbook.Sheets("Sheet1")　　'出力先シート
　　.Cells.ClearContents
　End With

　FileCount = 0
　getFilesRecursive (BaseDir)

End Sub

Sub getFilesRecursive(path As String)

　Dim FSO As FileSystemObject: Set FSO = New FileSystemObject
　Dim objFolder As folder
　Dim objFile As file

　'フォルダーを個々に取得
　For Each objFolder In FSO.GetFolder(path).SubFolders
　　getFilesRecursive objFolder.path
　Next

　'ファイルを個々に取得
　For Each objFile In FSO.GetFolder(path).Files
　　If UCase(FSO.GetExtensionName(objFile.path)) = "PDF" Then
　　　execute objFile
　　End If
　Next

End Sub

'取得したファイルをリストアップ
Sub execute(f As file)

　Dim FNameParts As Variant
　Dim PartsCount As Long
　Dim MidDir As String
　Dim FName As String

　'作成日時が指定日以前のファイルは無視する
　If f.DateCreated < BorderDay Then Exit Sub

　FileCount = FileCount + 1

　With ThisWorkbook.Sheets("Sheet1")　　　'出力先シート

　　Range(.Cells(FileCount, 1), .Cells(FileCount, 3)).NumberFormatLocal = "@"
　　.Cells(FileCount, 1).Value = BaseDir & "\"
　　MidDir = Mid(f.path, Len(BaseDir) + 2, InStrRev(f.path, "\") - Len(BaseDir) - 1)
　　.Cells(FileCount, 2).Value = MidDir
　　FName = Mid(f.path, InStrRev(f.path, "\") + 1, 256)
　　.Cells(FileCount, 3).Value = FName

　　.Hyperlinks.Add Anchor:=.Cells(FileCount, 3), _
　　　　Address:=f.path, TextToDisplay:=FName

　End With

End Sub

お礼

朝から作業していて、D列にファイルの作成日を拾うことができればお願いします。
手数が多くなるようなら現状でも十分＾充分です。

6行目以降へのデータ抽出も＋２行程度で可能なら教えてください。 これは別シートのA5以降に参照でも良いので。
抽出しながら別シートへの転記で負荷が増えて時間がかかるような気がしたのですが、やってみたら時間は変わらない感じ（体感）でしたので

このお礼へのご回答の有無にかかわらず、金曜日に一旦締め切って今回の新書式のリストの作成にかかります。

今回もほんとーーにありがとうございました。
少し古い流行語で申し訳ありませんが・・・
HohoPapa はんぱね～～～～

補足

おはようございます。

朝一で確認してスッキリ！！ & 最後のお願いです。

出力を6行目以降にするにはどこを書き換えれば良いのでしょう。

上の5行に項目や、オートフィルタを仕込んでしまえばファイルの増減監視・メンテではなく、毎回一定期間の最新版の更新で済んでしまうようにできることに気付きました。
Bookを目的別に複数用意（コピー）すれば、検索時間は現状で最大でも2分以内。

今までは、増減した結果を全項目の一覧表に反映していく作業をイメージしてのデータ抽出でしたが、今回の検索結果を見たら、この結果の上の行に使い方等とオートフィルタを見やすくすればそのまま一覧表として使えます。

実は昨夜、クリア範囲をA:Z列にして、前回のご回答の検索結果シートのAA列以降にいくつか細工したので、出力が６行目以降になれば、マクロボタンをクリックするだけで一覧表の60%以上がマクロで、後はVLOOKUP等の関数でホボ完成してしまうと思います。

今回も後知恵のオンパレードになってしまい本当に申し訳ありませんが、何卒宜しくお願い致します。

やはり当方のスキルが決定的に不足しているため発想が後追いになってしまいました。
ご容赦！！！！！！！！！！！！