""の中身を取得する方法

質問

VBAを使っています。

htmlファイルを読み込んで
href="http://www.xxxx.html"
の
http://www.xxxx.html
このURLの部分だけを順番に抽出し配列に保存するプログラムを書きたいのですが
どのように書けば良いですか？

回答No.4

mitarashi

過去の回答を引っ張りだしてみました。
１．テキストファイルとして正規表現で取り出す方法
http://okwave.jp/qa/q5651487.html

２．IEのDOMを利用する方法
http://okwave.jp/qa/q8648361.html

DOMパターンで、このVisual Basicの回答一覧のページをIE11で表示してやってみました
http://okwave.jp/c257.html

'Microsoft Internet Control
'Microsoft HTML Object Library
'に参照設定
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long

Sub getHrefFromOpenPage()
Dim ie As InternetExplorer
Dim myElements As IHTMLElementCollection
Dim myElement As IHTMLElement
Dim i As Long

i = 1
Set ie = getTopIeTab
If ie Is Nothing Then Exit Sub

' 真っ新のシートを表示して実行しないと、泣けます。
Cells.Clear
Set myElements = ie.document.getElementsByTagName("a")
If myElements.Length = 0 Then Exit Sub
For Each myElement In myElements
Cells(i, 1).Value = myElement.href
i = i + 1
Next myElement

'OKWaveの一覧ページだと、<linkのパターンもあり
Set myElements = ie.document.getElementsByTagName("link")
If myElements.Length = 0 Then Exit Sub
For Each myElement In myElements
Cells(i, 1).Value = myElement.href
i = i + 1
Next myElement

Set ie = Nothing
End Sub

'IEの最前面Tabを取得
Function getTopIeTab(Optional matchWord As String) As WebBrowser
Dim hWnd As Long
Dim ie As WebBrowser
Dim targetIe As WebBrowser
Const IEClassName As String = "IEFrame" 'IEのClass名

hWnd = FindWindow(IEClassName, vbNullString)
If hWnd = 0 Then Exit Function
For Each ie In CreateObject("Shell.Application").Windows()
If hWnd = ie.hWnd Then
ie.StatusBar = True
ie.statusText = CStr(hWnd)
If ie.statusText = CStr(hWnd) Then
If matchWord = "" Then
Set getTopIeTab = ie
Exit Function
Else
If InStr(ie.LocationURL, matchWord) > 0 Then
Set getTopIeTab = ie
Exit Function
End If
End If
End If
End If
Next ie
Set getTopIeTab = Nothing
End Function

全部抽出できたか、複雑なソースで把握しきれませんが、ご参考まで。