Excelでできますか

質問

例えば

番号 * 1 * ２ * 3 * 4 * 5 * 6
得点 * 60 * 100 * 80 * 100 * 100* 80

を昇順で並び替えして、同じ得点の番号を一列に表示させたい
のですがどうしたらいいでしょうか 教えてください

得点 * 番号
100 * 2 * 4 * 5
80 * 3 * 6 *
60 * 1

こんな感じで表示させたいのですが
*は文字間隔が上手く表示できないのでいれました

回答No.1

tom04 · ベストアンサー

こんばんは！
一例です。
Excel2007以降のバージョンをお使いだとして・・・
↓の画像で左側が元データのSheet1で右側のSheet2に表示するとします。

まずSheet1に作業用の行を設けます。
作業用のB3セルに
=IF(COUNTIF($B2:B2,B2)=1,B2,"")
という数式を入れフィルハンドルで右へずぃ～～～！っとコピーしておきます。

次にSheet2のA2セルに
=IFERROR(LARGE(Sheet1!$3:$3,ROW(A1)),"")
とし、フィルハンドルで下へコピー！

最後にB2セルに
=IF($A2="","",IFERROR(INDEX(Sheet1!$1:$1,,SMALL(IF(Sheet1!$2:$2=$A2,COLUMN($1:$1)),COLUMN(A1))),""))
これは配列数式になりますので、Ctrl＋Shift＋Enterで確定！
この画面からコピー＆ペーストする場合
上記数式をドラッグ＆コピー　→　Sheet2のB2セルを選択　→　数式バー内に貼り付け　→　そのまま（編集可能なまま）
Ctrl＋Shiftキーを押しながらEnterキーで確定！
数式の前後に{ }マークが入り配列数式になります。
これを列・行方向にフィルハンドルでコピー！

これで画像のような感じになります。m(_ _)m

お礼

さっそく回答ありがとうございました
上手く質問が書けなかったのですが
質問の意味理解して頂きありがとうございます
そうです！！こんな感じに表示したかつたのです

が 数式の書き間違いか私の知識不足もあり何も表示されません
今度の休みに再挑戦したいと思います

とりあえずお礼まで

回答No.2

bunjii

>昇順で並び替えして、同じ得点の番号を一列に表示させたいのですがどうしたらいいでしょうか
提示の状態は得点が降順で番号が昇順になります。
昇順と降順では処理条件が異なりますので要望事項を読み違えないような表現にしてください。
方法は幾つかありますがその1つとして次の方法を提言します。
元のデータがA1からG2にあるとして、得点を降順でI列に抽出します。
抽出した得点が同じの番号をJ列からM列へ昇順に抽出する処理をExcel 2013で検証しました。
I2=MAX(B2:G2,1)
I3=IFERROR(LARGE(B$2:G$2,COUNTIF(B$2:G$2,">="&MIN(I$2:I2))+1),"")
I3セルを下へ必要数コピーします。
J2=IFERROR(INDEX($A$1:$G$1,,SUMPRODUCT(LARGE(($B$2:$G$2=$I2)*COLUMN($B$2:$G$2),COUNTIF($B$2:$G$2,$I2)-COLUMNS($J2:J2)+1))),"")
J2セルを右と下へ必要数コピーします。
結果は貼付画像のようになりました。
Excel 2007以降のバージョンで再現できるはずです。
尚、元データの範囲に合わせて各数式のセル範囲を修正してください。

お礼

さっそく回答ありがとうございました
上手く質問が書けなかったのですが
質問の意味を理解して頂きありがとうございます
そうです こんな感じで表示したかつたのです

が、数式の書き間違いなのか、私の知識不足もあり
何も表示されません
今度の休みに再挑戦したいと思います

とりあえずお礼まで