ファイルを一つにまとめるためのバッチ処理方法

質問

• フォルダ内にツリー状に振り分けられた数千個のファイルから、エクセルに記載された同じファイル名のファイルのみを取り出し、別のフォルダにコピーして集める方法を解説します。
• エクセルに記載されたファイル名には重複や存在しないものがあるかもしれませんが、それらを考慮しながら効率的にファイルをまとめる手順を紹介します。
• 外付けHDD_Aの中のmainフォルダ内にあるツリー状のフォルダから、外付けHDD_Bのmatomeフォルダにファイルを移動する方法も説明します。

回答No.4

Gotthold

以下の記述を
拡張子bat (filecopy.batとか) のテキストファイルとして保存し
実行すれば、目的のことはできると思います。

バッチファイルの最初の方にある
copy_from、copy_to、list_file、work_fileに指定しているパスは
そちらの環境に合わせて書き換えてください、

また、エクセルのA列は
バッチファイル内のset list_fileで指定するファイルにコピーしておきます。

==ここから====================================
@echo off

rem copy_fromにmainフォルダ、copy_toにmatomeフォルダを設定する
set copy_from=D:\Temp\main
set copy_to=D:\Temp\matome

rem エクセルのA列をテキストファイルにコピーして
rem そのテキストファイルのパスを指定する
set list_file=D:\Temp\filelist.txt

rem work_fileには作業用に生成されるファイル名を適当に指定
set work_file=D:\Temp\fullpathlist.txt

rem 作業ファイルが存在するなら削除
del "%work_file%"

rem dirでファイルを探すためコピー元フォルダに移動
pushd "%copy_from%"

rem コピーするためのファイルリスト（フルパス）をwork_fileに出力
for /f "delims= usebackq" %%F in ("%list_file%") do (
dir /b /s "%%~F" >> "%work_file%"
)

rem コピーを実行
for /f "delims= usebackq" %%G in ("%work_file%") do (
copy "%%~G" "%copy_to%\%%~nxG"
)

rem 元のフォルダに戻る
popd
==ここまで====================================

[D:\Temp\filelist.txt の内容]
aaa.txt
ccc.txt
ggg.txt
hhh.txt
kkk.txt
mmm.png

これって、今までは手動でやってたんでしょうか。
だとしたら私の感覚だと信じられない時間の無駄遣い・・・。
何でも良いからプログラミング勉強しようよ。

お礼

す、すごい！！
一日がかりの作業が一瞬で終わってしまいました。

Gotthold さんは天才ですか？
大変助かりました。

同じようなことができる
何かオススメのプログラミングありますでしょうか？

補足

丁寧に、なんのコマンドが何の処理をしているかまで
書かれていますね！

ご親切に説明まで書いていただきありがとう御座います。

神様だ！