オブジェクトの選択によるグラフ操作マクロの作成

質問

• オブジェクトの選択によるグラフ操作マクロを作成します。単一選択や複数選択に対応し、グラフオブジェクトが含まれていない場合でもエラー終了しません。また、グループ化されたオブジェクト内のグラフオブジェクトも操作することができます。
• エクセルの2007（または2003）バージョンに対応したマクロです。シート上の全てのグラフに一括処理をしたり、単一選択したグラフに処理をすることができます。
• このマクロを使用することで、選択したオブジェクトに含まれるグラフオブジェクトの名前を取得することができます。マクロに渡された名前を用いて一定の処理を行うことができます。

回答No.1

end-u

Option Explicit

Private col As Collection

Sub test()
　　Dim c

　　Set col = New Collection
　　Call chkTypename(Selection)
　　If col.Count > 0 Then
　　　　For Each c In col
　　　　　　Debug.Print c
　　　　Next
　　End If
　　Set col = Nothing
End Sub

Function chkTypename(x)
　　Dim xi

　　Select Case TypeName(x)

　　　　　 Case "ChartArea"
　　　　　　　　col.Add x.Parent.Parent.Name
　　　　　 Case "ChartObject"
　　　　　　　　col.Add x.Name
　　　　　 Case "DrawingObjects"
　　　　　　　　For Each xi In x
　　　　　　　　　　Call chkTypename(xi)
　　　　　　　　Next
　　　　　 Case "GroupObject"
　　　　　　　　For Each xi In x.ShapeRange.GroupItems
　　　　　　　　　　Call chkTypename(xi)
　　　　　　　　Next
　　　　　 Case "Shape"
　　　　　　　　If x.Type = msoChart Then
　　　　　　　　　　col.Add x.Name
　　　　　　　　End If
　　　　　 Case Else
　　　　　　　　'Debug.Print TypeName(x)
　　End Select
End Function

こんな感じで。
基本的には、TypeName関数を使って調べると良いかと。

複数選択時のSelectionは"DrawingObjects"になりますから
そこから再度、単体別にチェックすれば良いです。

GroupObjectについては.ShapeRange.GroupItemsをチェックすれば良いですが
各GroupItemはTypeName"Shape"しか返さないので
Shape.Type が msoChart かどうかを追加で調べてます。