エクセルでの重複セルの削除

質問

こんにちは　いつもお世話になっています。

エクセル2003を使っています。
A列に文字列があり、条件付書式で重複データのセルに背景色を付けています。
A列は、ふりがなで昇順でソートしてあります。
条件付書式は数式に　=COUNTIF(A:A,A1)>1としています。
B列にはA列の特定セルの行にだけ数字データがあります　
A列の特定セルとはA列の重複セルの下側のセルです。
重複データは常に2つだけ出てきます。ソートしてあるのでB列にデータの無いセルが上側に配置されているのだと思います。

例えば、
A　　　　B
事項　該当箇所　（見出しです）
愛知　
秋田
秋田　12.23.34.
石川
愛媛
愛媛　5.68.78.

（A列の秋田、愛媛のセルの背景色が条件付書式で黄色くなっています）
という具合です。

ここで質問ですが、
重複セルの上側のセルだけを削除する方法を教えてください。上の例ではB列にデータの無い秋田、愛媛です。
フィルタオプションで「重複セルを無視する」にチェックをいれても重複セルの下側のセルが無視されてしまいます。また、検索で色つきセルだけを表示しようとしても条件付書式ではできないようです。

わかりにくい説明ですみません。よろしくお願いします。

回答No.4

KURUMITO · ベストアンサー

削除したデータを並べるということはフィルタ操作を行った場合でもそれをコピーして別のシートに貼り付けることが必要でしょう。関数のみを使って別のシートに表示させるようにすればフィルタなどの操作を全く必要としません。次のように作業列を作って対応してはどうでしょう。
例えばシート1のAおよびB列にお示しのデータが1行目は項目名で、2行目から下方にあるとします。
C2セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A2="","",IF(OR(COUNTIF(A:A,A2)=1,COUNTIF(A$2:A2,A2)=2),MAX(C$1:C1)+1,""))

その後に別のシートでA列およびB列の1行目には項目名を入力します。
A2セルには次の式を入力してからB2セルまでオートフィルドラッグしたのちに下方にもオートフィルドラッグします。

=IF(ROW(A1)>MAX(Sheet1!$C:$C),"",IF(INDEX(Sheet1!$A:$B,MATCH(ROW(A1),Sheet1!$C:$C,0),COLUMN(A1))=0,"",INDEX(Sheet1!$A:$B,MATCH(ROW(A1),Sheet1!$C:$C,0),COLUMN(A1))))

お礼

KURUMITO　様　ありがとうございました。お蔭様で解決しました。
フィルタを使わなくてもできるんですね。大変勉強になりました。
複雑な関数を教えていただき恐れ入ります。とても使いやすいです。
簡単で恐縮ですが、お礼申し上げます。

回答No.3

mshr1962

C列に
=COUNTIF(A:A,A1)<COUNTIF(A$1:A1,A1)
と式を設定
オートフィルタでC列がTrueとなったセルを選択
F5キーを押して、選択セルから「可視セル」を選択してOKし、クリアしてください。
後はオートフィルタの解除後に並び替えを行えばいいかと．．．

お礼

mshr1962　様　ありがとうございました。
急いでいるせいか失敗しています。
もちろん、やり方が悪いのだと思います。
あらためて、使わせていただきます。
簡単で恐縮ですが、お礼申し上げます。

回答No.2

keithin

猿でも出来る方法としては
C2:
=COUNTIF(A:A,A2)
以下コピーしておいてC列をオートフィルタの２で絞り込み
更にB列を空白で絞り込み，
まとめて選んで行番号右クリックの削除で上に詰める

で，オートフィルタを解除して出来上がり。

お礼

keithin　様　ありがとうございました。お蔭様で解決しました。
丁寧に教えていただき助かりました。簡単で使いやすかったです。
大切に使わせていただきます。
簡単で恐縮ですが、お礼申し上げます。

回答No.1

imogasi

関数で行削除は出来ないのだ。
関数はセルの値を使って計算や処理をして、式を入れているセルの値を決める働きしかない。存在を消す行削除や追加する行挿入は関数では絶対にできない。関数の基本だ。
条件付書式と結びつけるのも難しい
ＶＢＡでやったりするが、質問者にはお呼びで無いだろう。
あとは操作に頼るらなければ仕方がない。
ーー
例データ
Ａ列　Ｂ２以下行にデータあり
a
b
b
c
d
d
e
f
Ｂ列に列挿入して
Ｂ２に　=IF(A2=A3,1,"")
下方向に式を複写
結果
a
b 1
b
c
d 1
d
e
f
ーーー
Ｂ列を範囲指定して
編集ージャンプーセル選択（ボタン）ー数式で数値のみチェックを残す。ーＯＫ
２行だけが選択状態になる。
編集ー削除ー行全体ーＯＫ
その後、Ｂ列全体を削除する
結果
a
b
c
d
e
f

お礼

imogasi　様　ありがとうございました。お蔭様で解決しました。
丁寧に教えていただき助かりました。
大切に使わせていただきます。
簡単で恐縮ですが、お礼申し上げます。