for & duplicateMovieClip & function

質問

for & duplicateMovieClip & function

// == info用テキスト作成 ====================
/**/
var H_TextFieldInfo = _root.createTextField("I_textField",1001 ,10 ,10 ,690 ,20);
_root.H_TextFieldInfo.text = ""; // 文字列を表示 テキスト表示テスト

// == データ読み込み ==============================
for(Hi=2; Hi<=10; Hi++){
H_name01 = "I_MC"+ Hi;
H_gFX = I_MC01._width * Hi;
H_gFY = 10;

// ************
_root.I_MC01.duplicateMovieClip (H_name01, (201+Hi), {_x:H_gFX ,_y:H_gFY });
H_num = Hi;
_root[H_name01].onRelease = function(){
_root.H_TextFieldInfo.text = H_num;
}
// ************
}

ステージ上に I_MC01 というインスタンス名でムービークリップを配置して、上記のようなアクションスクリプトを書きました。for分の_root.I_MC01.duplicateMovieClip でI_MC01を複製し、その複製したムービークリップをクリックすると、テキストに番号が入力されるようにしたつもりなのですが、出来ませんでした。
いくつか思いつくことをやってみたのですが、出来ませんでした。

このようなときムービークリップをクリックすると、個別の番号をテキスト欄に表示させるにはどうしたらよいのでしょうか？

ご教授よろしくお願いします。

回答No.1

BlurFiltan · ベストアンサー

各ムービークリップ内の変数として Hi を保存し
各ムービークリップクリック時に
個々内の変数 を参照で呼びださせれば良いと思います。
※イメージは下図↓

具体的には次の部分↓を

// ************
_root.I_MC01.duplicateMovieClip (H_name01, (201+Hi), {_x:H_gFX ,_y:H_gFY });
H_num = Hi;
_root[H_name01].onRelease = function(){
_root.H_TextFieldInfo.text = H_num;
};
// ************

次のように↓換えればできます。

// ************
_root.I_MC01.duplicateMovieClip(H_name01, (201 + Hi), {_x:H_gFX, _y:H_gFY});
//↓各 MC 内の 変数H_num に個別の Hi を代入
_root[H_name01].H_num = Hi;
_root[H_name01].onRelease = function() {
//↓各 MC 内の変数 H_num をテキストフィールドに表示
_root.H_TextFieldInfo.text = this.H_num;
};
// ************

＝＝＝ 別法1 ＝＝＝＝＝＝

関数の中に Hi を固定してしまっても良いと思います。

具体的には次の部分(最後の部分)↓を

// ************
_root.I_MC01.duplicateMovieClip (H_name01, (201+Hi), {_x:H_gFX ,_y:H_gFY });
H_num = Hi;
_root[H_name01].onRelease = function(){
_root.H_TextFieldInfo.text = H_num;
};
// ************
}

次のように↓書き換えればできます。

// ************
_root.I_MC01.duplicateMovieClip(H_name01, (201 + Hi), {_x:H_gFX, _y:H_gFY});
//↓各MCクリック時の関数として 関数closureFunc の戻り値を代入
_root[H_name01].onRelease = closureFunc(Hi);
// ************
}

//関数 closureFunc の定義
function closureFunc(H_num) {
//関数を返す
return function () {
//渡された H_num の値をテキストフィールドに表示
_root.H_TextFieldInfo.text = H_num;
};
}

＝＝＝ 別法2 ＝＝＝＝＝＝

「個別の番号をテキスト欄に表示させる」"だけ" でしたら
MCの名前の最後をテキスト欄に表示させても良いですね。

具体的には次の部分↓を

// ************
_root.I_MC01.duplicateMovieClip (H_name01, (201+Hi), {_x:H_gFX ,_y:H_gFY });
H_num = Hi;
_root[H_name01].onRelease = function(){
_root.H_TextFieldInfo.text = H_num;
};
// ************

次のように↓書き換えればできます。

// ************
_root.I_MC01.duplicateMovieClip(H_name01, (201 + Hi), {_x:H_gFX, _y:H_gFY});
_root[H_name01].onRelease = function() {
_root.H_TextFieldInfo.text = this._name.split("I_MC")[1];
};
// ************

this._name で 「I_MC○」 という自分の名前を取得し
その名前を文字列 「I_MC」 で区切って配列にし
その配列の 2つめの要素 [1] を取って来るという内容です。
※配列の要素番号は 0 から始まるので 1 は２つ目

お礼

書き込みありがとうございます。

問題解決できました。大変助かりました。
今回は1を例にやりました。他例も試してみたいと思います。

ありがとうございました。