イメージギャラリーの最後までいったら「次へ」ボタンを消す

質問

イメージギャラリーを制作中です。

配置する要素は「写真」、「前へ」ボタン、「次へ」ボタン、で写真は40枚です。
写真は外部読み込みではなくてphoto_mcに入れ込んでいます。

最後の写真になったら「次へ」ボタンを消して表示されないようにしたいのですがどうしたらよろしいでしょうか？
一部ですが以下が「next_btn」のスクリプトです。

//---ボタン「next_btn」に関して---
//x座標をステージ右より55px左にする
next_btn.x = stage.stageWidth-55;
//ｙ座標をステージ下より15px上にする
next_btn.y = stage.stageHeight-15;

～～～～～～

//関数 nextClick の定義
function nextClick(evt:MouseEvent):void{
// 写真入り「photo_mc」内を次のフレームに戻して停止
photo_mc.nextFrame();
}

環境はWin XP、Flash CS3、actionscript3、flashplayer9
です。
よろしくお願いします。

回答No.1

BlurFiltan · ベストアンサー

「次へ」ボタンを消すだけでしたら，
単純に書かれてある通りにそのままをコーディングすれば良いと思います。
　↓関数 nextClick を変更↓
--------------------------
//関数 nextClick の定義
function nextClick(evt:MouseEvent):void {
// 写真入り「photo_mc」内を次のフレームに戻して停止
photo_mc.nextFrame();
// もしそのフレーム↑が「photo_mc」の最終フレームであれば
if (photo_mc.currentFrame==photo_mc.totalFrames) {
// イベントターゲット(next_btn)を非表示にする
evt.target.visible=false;
}
}
--------------------------

しかし，
このままだと一度消えた「next_btn」が現れることはありません。
「next_btn」を再出現させるとなるとムービー全体の連動を考える必要があります。

　↓表示/非表示 連動部分の全体例↓
------------------------------------
// 写真入り「photo_mc」の再生を停止
photo_mc.stop();

// 前へボタン「prev_btn」を非表示にしておく
prev_btn.visible=false;

// 次へボタン「next_btn」にクリック時のイベントリスナーを登録
next_btn.addEventListener(MouseEvent.CLICK,nextClick);

//関数 nextClick の定義
function nextClick(evt:MouseEvent):void {
// 写真入り「photo_mc」内を次のフレームに戻して停止
photo_mc.nextFrame();
// もしそのフレーム↑が「photo_mc」の最終フレームであれば
if (photo_mc.currentFrame==photo_mc.totalFrames) {
// イベントターゲット(next_btn)を非表示にする
evt.target.visible=false;
}
// 前へボタン「prev_btn」を表示する
prev_btn.visible=true;
}

// 前へボタン「prev_btn」にクリック時のイベントリスナーを登録
prev_btn.addEventListener(MouseEvent.CLICK,prevClick);

//関数 prevClick の定義
function prevClick(evt:MouseEvent):void {
// 写真入り「photo_mc」内を前のフレームに戻して停止
photo_mc.prevFrame();
// もしそのフレーム↑が「photo_mc」の最初のフレームであれば
if (photo_mc.currentFrame==1) {
// イベントターゲット(prev_btn)を非表示にする
evt.target.visible=false;
}
// 次へボタン「next_btn」を表示する
next_btn.visible=true;
}
------------------------------------

取得したり操作したりするプロパティは次の３つです。

currentFrame
MC(ムービークリップ)の再生中フレームプロパティ

totalFrames
MCのフレーム数(=最終フレーム番号)プロパティ

visible
MCやボタンなどの 表示/非表示 プロパティ

あとは，
「いつ」・「どうしたいか」 を考えながら場合に応じてコーディングします。

お礼

度々ご丁寧にご解説いただきありがとうございます。
ただ僕のやり方が間違っているのか、
下記のようなエラーが出てしまいます。。

関数の定義が重複しています。
function nextClick(evt:MouseEvent):void {
function prevClick(evt:MouseEvent):void {

お分かりになりますでしょうか？

回答No.2

BlurFiltan

＃１です
補足を拝見しました。

> 関数の定義が重複しています。
> function nextClick(evt:MouseEvent):void {
> function prevClick(evt:MouseEvent):void {

それは文字通り(エラーメッセージ通り)
function nextClick と function prevClick を二重(または三重 以上)定義しているからでしょう。
日本語のエラーメッセージくらい理解してくださいよ。

同じ関数名の関数を同じフレームにコピペして増やしてもダメです。
(仮にエラーが出なくても最後に定義した同名の関数しか有効になりません。)

スクリプトを変更するか，
元あった同じ関数名の関数を削除して＃１で書いた２つのスクリプトのうちどちらかコピペで使用するとかしないと...。