ドラッグ＆ドロップ＆拡大できる地図

質問

actionscript初心者です。。
ただいま
ドラッグ＆ドロップ＆拡大できる地図を
某サイトを参考に作成しています。

教えていただきたいのですが、
このサイトの
http://hfm-kenchan.com/Lesson/contents/index.htm

Q&Aサンプル作品集のNo.837「ドラッグ可能な二段階拡大画像」
を参考に地図を作成しておりました。。

なにぶん初心者なので
いきなりのつまづき。。。

拡大前の画像（最初の100%の画像）もドラッグできるようにするにはどうすれば良いでしょう？

最初に50%
次に70%
そして100%にしたいのですが。。。

50%の画像がドラッグできなくなってしまいます。

いろいろと調べてもわからず
途方にくれています。

教えてください、よろしくおねがいします。

回答No.4

BlurFiltan

＃１・２・３ です。
返事（回答）がおそくなってしまいました。

「作りかえなんか簡単だろう」 と思っていましたが，実際にやってみたら難しかったです。
変なところで色々連動していて頭がごちゃごちゃになりましたし，
仮にできても，
サイズや座標を変えたいような場合は使えなくなると思いました。

したがって，
基本的にスクリプトの作りかえはせずに最初から作成してみました↓。

////////////////////////////////////////////////////
/*
親子MC とも基準点は中心で 子MC に書くスクリプト です
親MCの初期配置座標はマスク内であれば任意です
*/
// このMC（子MC）が表示されたとき
onClipEvent (load) {
//---↓初期設定↓-------------
// 拡大スピードの設定（※変更可）
spd = 1/2;
// 拡大率の設定（※変更可）
size0 = 100;
size1 = 150;
size2 = 250;
// マスクの 左上x座標・左上y座標 と
// 横幅・高さ の設定（※変更可）
msk_x = 50.5;
msk_y = 49.5;
msk_w = 699;
msk_h = 499;
//---↑初期設定↑-------------
//
// ハンドカーソルにしない
this.useHandCursor = false;
// クリックをカウントする変数 cnt の初期化
cnt = 0;
// 親の初期座標を記録
p_x = _parent._x;
p_y = _parent._y;
// 親の縦横サイズの記録
p_w = _parent._width;
p_h = _parent._height;
// 最初のサイズを設定
size = size0;
}

// この MC プレスしたとき
on (press) {
// プレスフラグを true にする
press_flg = true;
// プレス時の座標を記録
mos_x = _parent._xmouse;
mos_y = _parent._ymouse;
}

// この MC を放したとき
on (release, dragOut) {
// プレスフラグを false にする
press_flg = false;
if (!drag_flg) {
// cnt が2未満でカウントアップ
cnt = (cnt<2) ? cnt+1 : 0;
// 目標サイズを切り替える
size = this["size"+cnt];
if (cnt != 0) {
this._x = this._x-mos_x;
this._y = this._y-mos_y;
_parent._x = _root._xmouse;
_parent._y = _root._ymouse;
} else {
this._x = this._y=0;
_parent._x = p_x;
_parent._y = p_y;
}
}
// ドラッグフラグを false にする
drag_flg = false;
}

// マウスが動いたとき(主にドラッグに関して)
onClipEvent (mouseMove) {
if (press_flg) {
// ドラッグフラグを true にする
drag_flg = true;
// 横長になるので 現在の親のサイズ を変数化
npw = _parent._width;
nph = _parent._height;
// 取りあえずドラッグ
_parent._x = _root._xmouse-mos_x*npw/p_w;
_parent._y = _root._ymouse-mos_y*_parent._height/p_h;
// ドラッグしたときの補正（ドラッグ制限）
if (_parent._x>=msk_x+npw/2-this._x*npw/p_w) {
_parent._x = msk_x+npw/2-this._x*npw/p_w;
} else if (_parent._x<=msk_x+msk_w-npw/2-this._x*npw/p_w) {
_parent._x = msk_x+msk_w-npw/2-this._x*npw/p_w;
}
if (_parent._y>=msk_y+nph/2-this._y*nph/p_h) {
_parent._y = msk_y+nph/2-this._y*nph/p_h;
} else if (_parent._y<=msk_y+msk_h-nph/2-this._y*nph/p_h) {
_parent._y = msk_y+msk_h-nph/2-this._y*nph/p_h;
}
updateAfterEvent();
}
}

// 随時実行(拡大縮小に関して)
onClipEvent (enterFrame) {
if (!drag_flg) {
_parent._xscale = _parent._yscale
+= (size-_parent._yscale)*spd;
}
}
////////////////////////////////////////////////////

色んな場合でも，
//---↓初期設定↓-------------
　　この間
//---↑初期設定↑-------------
の数値を書き替えるだけで使用できると思います。

大きな変更がなければ他は触る必要はないと思います。

お礼

>BlurFiltanさん

わお～
すっご～い。。
バッチリでっす。。

解説も付けてもらって嬉しいっす。。
BlurFiltanさんのスクリプトを調べながら
自分でも考えてみます。

的確な応対ですごく助かりました。
ほんとうにありがとうございます。