ユーザーフォームのテキストボックスに配列の値を読み込む方法を教えて下さい

質問

お世話になります
ユーザーフォームのリストボックスにAddItemで記述したデータを表示するような形で、ユーザーフォームのテキストボックスに配列にとりこんであるデータの値を順番に読み込むようにしたいのですが、このようなことができるのでしょうか？
どなたか教えて頂けないでしょうか

回答No.5

maruru01

再びmaruru01です。

標準モジュール

'ユーザーフォームでも使用するので、Publicで宣言。
'データ数が分からないでの動的に宣言。
Public Data1() As String
'データ数
Public DataCount As Long

Sub input1()

'以下の変数はこのプロシージャでしか使用しないので、中に入れます。
'ループカウンタはInteterよりLongの方がいい。
Dim i As Long
Dim j As Long

Sheets("Sheet1").Select

'表形式の場合は、CurrentRegionプロパティでデータ数を取得出来る。
'見出し行の分-1する。
DataCount = Range("B10").CurrentRegion.Rows.Count - 1
'配列の再宣言
Redim Data1(1 To 5, 1 To DataCount)

'（b～f列なら、列番号は2～6ですよね？）
For i = 2 To 6
'最終データ行数は、データ数+開始行-1で取得出来る
For j = 11 To DataCount + 11 - 1
'- 1、- 10は、配列のインデックスが1から始まっているから
Data1(i - 1, j - 10) = Cells(j, i)
Next j
Next i
End Sub

ユーザーフォームのコードモジュール

'宣言部に
Private myCollect As New Colletion　'コレクションオブジェクトの宣言
Private ViewNumber As Long　'現在表示されているデータの行番号

'Initializeイベントに
Private Sub UserForm_Initialize()

Dim i As Long

’コレクションの追加
With myCollect
.AddItem:=text1　'ID
.AddItem:=text2　'氏名
.AddItem:=text3　'部署
・・・略（シートの項目列の順に追加する、もちろん配列の列数と追加するテキストボックスの数は一致すること）
End With

'とりあえず何かデータを表示（とりあえず、先頭のデータ）
ViewNumber = 1
For i = 1 To 5
myCollect(i).Text = Data1(i, 1)
Next i

End Sub

'次のデータへ移動するボタン
Private Sub CommandBUtton1_Click()

Dim i As Long

If ViewNumber = DataCount Then
'最後のデータの場合は移動しない
MsgBox "最後のデータです。"
Exit Sub
Else
ViewNumber = ViewNumber + 1
For i = 1 To 5
myCollect(i).Text = Data1(i, ViewNumber)
Next i
End If

End Sub

'前のデータへ移動するボタン
Private Sub CommandBUtton2_Click()

Dim i As Long

If ViewNumber = 1 Then
'先頭のデータの場合は移動しない
MsgBox "先頭のデータです。"
Exit Sub
Else
ViewNumber = ViewNumber - 1
For i = 1 To 5
myCollect(i).Text = Data1(i, ViewNumber)
Next i
End If

End Sub

なお、こちらの都合で、配列の行と列の順番を入れ替えました。

お礼

maruru01様
身勝手なお願いにもかかわらず、根気よく丁寧にご指導いただき本当にありがとうございます。
おかげさまで、目的をはたすことができました。
maruru01様はじめお二人の方にご指導いただき、今回も書籍では得られない勉強をさせていただきました。
いつかは、私もmaruru01様の1/100でも人様にアドバイスできるようにがんばりたいと思いますので、今後ともよろしくお願いします。
心より感謝します。
tomosato