入力規制について教えてください。

質問

どうしてもできなければいけないわけではないのですが、できればいいなと思ってご質問してます。

入力規制でリストから選択して入力した後に、入力済みの分をリストから消す事はできるのでしょうか？
具体的にいうと、No.１～１４０というリストがあってその中から選択したら次の人はその番号は選択できないようにリストから消すといった感じです。

方法があれば教えていただけると嬉しいです。

回答No.2

ham_kamo · ベストアンサー

Ａ列のA1～A140にリストがあり、Ｂ列に入力し、Ｃ列を補助列として使うと仮定します。

まず、「挿入」＞「名前」＞「定義」を選択し、
「名前」欄に「選択範囲」と入力し、
「参照範囲」に、以下の数式をコピーして貼りつけ、OKを押します。

=OFFSET($A$1,,,COUNTA($A:$A))

C1を選択して以下の数式を数式バーにコピーし、配列数式なのでCtrl+Shift+Enterで入力します。（数式バーの数式が{}で囲まれていることを確認してください）

=IF(ROW(A1)<=COUNTA($A:$A)-SUM(COUNTIF($B:$B,選択範囲)),INDEX(選択範囲,SMALL(IF(COUNTIF($B:$B,選択範囲),COUNTA($A:$A)+1,ROW(選択範囲)),ROW(A1))),"")

このセルを元のデータが入っている最後の行までマウスでドラッグしてコピーします。

Ｂ列の入力規則でリストを選択し、「元の値」の欄に以下の数式をコピーします。

=OFFSET($C$1,,,COUNTA($C:$C)-COUNTIF($C:$C,""))

これで一度選択したものはリストから除外されるようになります。

C列が見えるのがじゃまであれば、C列を選択して右クリック＞「表示しない」を選んで見えなくするとよいでしょう。

お礼

早速の回答、ありがとうございます。
他のスタッフと相談して試してみます。

回答No.1

hyorono

こんばんわ。
たとえば、
A列　　　　　　　　　　　B列　　　　　　　　 　　　 　　　　　　　 　C列
だいこん　　　　=IF(COUNTIF(C:C,A1)=0,A1,"") 　　　 入力規則(B列参照）
にんじん　　　　=IF(COUNTIF(C:C,A2)=0,A2,"")
たまねぎ　　　　=IF(COUNTIF(C:C,A3)=0,A3,"")
きゅうり　　　　=IF(COUNTIF(C:C,A4)=0,A4,"")
しいたけ　　　　=IF(COUNTIF(C:C,A5)=0,A5,"")

と、すれば出来ますよ！入力済みで選択できない部分は空欄になってしまいますが・・・
どうでしょう？

お礼

早速の回答、ありがとうございます。
他のスタッフと相談してやってみます。