ツールを探しています。指定フォルダ配下のサイズ・ファイル数

質問

Win2000です。
指定フォルダ配下のファイル数とサイズをテキストベースで一度に返すようなコンソール系のフリーソフトで、
良いものがあれば教えてください。

GUI形式のものはたくさんあるのですが、バッチ処理などから呼び出して、結果だけをレポートする目的で、
テキストベースで応答を返してくれるものを探しています。

→もし自作する場合など、VC等で目的に適した関数（ないしは、自作支援HPなど）があれば教えてください。

検索サイト等で、ありそうで、なかなか見つけられません。よろしくお願いします。

回答No.4

BLUEPIXY · ベストアンサー

#3>集計結果は、一度に、
なるほど、勘違いしていましたすみません。
以下修正してみました。
----------------------------------------------------------------
'指定したフォルダのサブフォルダを含めたファイル件数とサイズを表示する
'cscript //nologo GetFsize.vbs FOLDER
Dim fso, wsho, folderList, folder
Dim i, count

Set fso = WScript.CreateObject("Scripting.FileSystemObject")
Set wsho = WScript.CreateObject("WScript.Shell")
Set folderList =WScript.Arguments

count=0
for i=0 to folderList.length-1
Set folder = fso.GetFolder(folderList(i))
count = count + auxProc(folder.Path)
next

WScript.Echo(folder.Path & " " & count & " files " & folder.Size & "Bytes")

function auxProc(folderPath)
Dim folder, x, folderName, count

Set folder = fso.GetFolder(folderPath)

count = folder.Files.Count
For Each x in folder.SubFolders 'サブフォルダの処理
count = count + auxProc(x.Path)
next
auxProc = count
End function
----------------------------------------------------------------
＞auxProc(folder.Path)の戻り値等で、ファイル数、サイズ（の２つ）を返して…
フォルダのサイズ自体は、ルートだけでいいので、（ルートのサイズはサブフォルダを含んだサイズなので）、ファイル数を返せば良いです。

＞処理速度的に、VBScriptを使っても、（VC等で作成することに比べ）遅いということは無いでしょうか。
例え、ＶＣを使ったとしても、こうしたディスクアクセスがほとんどの処理は大して変わらないと思います。
内容的にも大したことはやっていないので、ＡＰＩ呼び出しが動作のほとんどを占めると思いますが、それがＡＰＩの直接呼び出しか間接呼び出しかくらいの違いだと思うので、ディスクアクセスに比べれば大した違いにはならないと思います。

お礼

お礼が遅くなりました。
先ほど、動作確認をしました。

D:\test 68837 files 5051663083Bytes
を数十秒で回答してきました。

また、GUIにて該当フォルダを右クリックしてプロパティで求めた結果と比較して、
ファイル数、サイズともに一致することが確認できました。
処理速度的にもほとんど変わりませんでした。
（キャッシュされていたのか、後から実行した方が体感的に速かったですが、
あらためて上記VBSを走らせたら、更に速く数秒で答えを返してきましたので、問題なしと思っています）

やりたかったことがこんなに簡単にできて、大変うれしいです。

私のほうでも、#3でのご回答との違いなどをこれから勉強したいと思います。
以上、懇切に何度もありがとうございました。

補足

引数で複数フォルダが指定できるようなことも考慮されているようだ、と気がつきましたので、部分的にちょっと変えてみました。

'cscript //nologo GetFsize.vbs FOLDER1 [FOLDER2]...
Dim fso, wsho, folderList, folder
Dim i, count, file, size

　　　　：

file = 0
size = 0
for i=0 to folderList.length-1
count=0
Set folder = fso.GetFolder(folderList(i))
count = count + auxProc(folder.Path)
WScript.Echo(folder.Path & " " & count & " files " & folder.Size & " Bytes")
file = file + count
size = size + folder.Size
next

WScript.Echo("Total " & file & " files " & size & " Bytes")
　　　　：

そうすると、こんな感じにできました。

D:\>cscript //nologo GetFsize.vbs D:\test D:\Becky
D:\test 68836 files 5051662329 Bytes
D:\Becky 9899 files 2194430933 Bytes
Total 78735 files 7246093262 Bytes