2つのswfファイルをつなげている場合の一括ローディング方法

質問

お世話になります。
この質問の下の質問で、外部JPGファイル読み込みのローディング方法を質問しておられますが、そこを読んでも、外部swfファイル読み込みの際のローディング方法に応用することが出来ませんでした。

700Kのswfの最後のフレームに、

loadMovieNum("img/next.swf", 0);

として、500kのnext.swfファイルとつなげています。

最初のswfファイルの1シーン目で、2つのswfを全て読み込み、再生時のつながりをスムーズにしたいと考えています。

最初のswfの1シーン目に、
ローディングオブジェクトを置き、

onClipEvent (load) {
_root.stop();
par = 0;
bar._xscale = 1;
}

onClipEvent (enterFrame) {
par = parseInt((_root.getBytesLoaded() / _root.getBytesTotal()) * 100);
if (par == 0) {
par = 1;
} else if (par >= 100) {
par = 100;
_root.gotoAndPlay("start");
}
bar._xscale = par;
}

ローディングすると、フレームラベル「start」
に飛び、
そのフレームに置いているオブジェクトに

onClipEvent (load) {
par = 100;
bar._xscale = 100;
}
onClipEvent (enterFrame) {
_alpha -= 5;
}

を書き込んでいます。

そして、2シーン目に飛び、
2シーン目の最後のフレームに、

loadMovieNum("img/next.swf", 0);

を置いてつなげています。

FLASH本を数冊持っているのですが、2つのswfを
同時にローディングする方法が載っておらず、
こちらに質問を書かせていただきました。

もしかしたらこの質問の下質問JEPファイルの
ローディングと内容がかぶってるかもしれませんが、
よろしくお願い致します。

【制作環境】
Win XP
FLAS MX

回答No.1

DPE · ベストアンサー

ロードの進捗状況は、loadMovie などのダウンロード命令を出した後でなければ取得できません。
例えば、ムービー１の最後で loadMovie でムービー２を読み込む場合でも、ムービー１の最初でロード画面を再生している間は、ムービー２のロードは実行されていません。
そのため、ムービー２の容量や進捗状況を、ムービー１自体の進捗状況と同時に把握することはできないのです。

Flash での読み込みは、loadMovie で読み込み命令を出した後、読み込みが終わるまでそこでスクリプトの実行が止まることはなく、読み込みを裏で進めながら次のスクリプトが並行して実行されます。
つまり、loadMovie を２件続けて実行することで、２つのムービーを同時に読み込むことができます。

２つの読み込みを同時に実行するには、ムービーの受け皿となるムービークリップを２つ用意し、それぞれにムービーを読み込むようにします。
この場合は、２つのロードの進捗状況を把握し、２つ分の容量を合わせた完了率を算出することも可能です。
ただし、２つのムービーが同時にステージに存在することになりますから、ムービー１が再生されている間はムービー２を待機状態にし、ムービー１が終了したらムービー２を再生させるといった、再生するムービーを任意のタイミングで切り替えられる仕組みも必要になります。

------------------------

ムービー１の中で全て実現しようとすると難しいので、読み込みやムービーの切り替えなど、全体を指揮するムービーを１つ作ってはいかがでしょうか。

例えば、全体の指揮を執るムービーを main.swf 、読み込むムービーを sub1.swf と sub2.swf とします。
main.swf の中にムービークリップを２つ用意し、これにムービーを読み込みます。
このムービークリップを仮に load_area1 と load_area2 とします。
sub1.swf を再生している間、sub2.swf は待機となります。
この２つは main.swf に読み込まれた時点で、main.swf にある load_area1 と load_area2 というムービークリップとして制御できるようになります。
再生するムービーは、ムービークリップの表示・非表示を決める _visible 属性を操作して、簡単に切り替えることができます。
また、再生するフレームに関しては、stop(); や play(); を利用して再生／停止を制御できます。

sub1.swf が終了した後で sub2.swf に切り替えるには、sub1.swf の再生が終了したかどうかを main.swf が検出できるようにしなければなりません。
いろいろな方法がありますが、main.swf に変数を１つ用意し、この値を sub1.swf の最後のフレームで書き換えて終了を知らせる方法が簡単だと思います。
例えば、この変数を end_flg とし、最初は false を入れておくとします。
sub1.swf が main.swf に読み込まれた時は、main.swf のムービークリップ load_area1 として扱われますので、sub1.swf からこの変数を操作するには、main.swf の load_area1 からメインのタイムラインまでのターゲットパスが必要になります。
load_area1 から見ますと、end_flg は親の階層にあります。親の階層を表す相対表現 _parent を使って、

　//終了をメインのムービーに知らせる
　_parent.end_flg = true;

で書き換えることができます。
main.swf ではこの変数を監視し、true に変わった時に、sub2.swf （が読み込まれている load_area2 ）を再生するようにします。

ところで、Flash には、全データを読み終わらなくとも、読み込みの済んだフレームから順に再生できるという特長があります。
これは loadMovie で読み込む場合でも同じです。
しかし今回の場合は、ムービーの読み込みが全て終わった時点で再生させたいので、この特長がかえってアダになります。
簡単にできる対策としては、ムービーが読み込まれた時点で、ムービーのタイムラインをとりあえず止めておくといった方法があります。
loadMovie を実行すると、ダウンロード演算が行われるたびに data というイベントが発生します。
このイベントを利用して stop(); を実行するか、あるいは、sub1.swf と sub2.swf のフレーム１に stop(); を入れて、最初は止まるようにしておくといいでしょう。

------------------------

以上のような方針に従って、main.swf のレイヤー構成を考えますと。

　アクション：スクリプト用
　ムービー１：ムービークリップ load_area1 を配置
　ムービー２：ムービークリップ load_area2 を配置
　完了率表示：ロード中に実行するアニメ等を描画

スクリプトは、

　フレーム１：初期設定とムービーの読み込み
　フレーム２：読み込み完了を待つ（スクリプトはなし）
　フレーム３：ロード完了率の算出と、ロード完了時の処理など
　フレーム４：ムービー１の再生終了を待つ（スクリプトはなし）
　フレーム５：ムービー１の終了を待って、ムービー２に切り替える

このような流れになるかと思います。

スクリプトにしてみますと、大体、次のようになります。
（↓各行頭に全角のスペースが入っています。コピーする際はご注意ください）

　・フレーム１

　　//ムービー１の再生終了フラグ
　　//再生終了時true、それ以外はfalse
　　end_flg = false;

　　//それぞれのロード領域にムービーを読み込む
　　load_area1.loadMovie( "sub1.swf" );
　　load_area2.loadMovie( "sub2.swf" );

　・フレーム３

　　//完了率の算出
　　//ムービー１と２の合算で出す
　　loaded = load_area1.getBytesLoaded() + load_area2.getBytesLoaded();
　　total = load_area1.getBytesTotal() + load_area2.getBytesTotal();
　　per = Math.floor( loaded / total * 100 );

　　//プログレスバーの描画
　　bar._xscale = per;

　　//両方のムービーのロードが終了した場合
　　if( per == 100 )
　　{
　　　//ムービー１を表示し、再生する
　　　load_area1._visible = true;
　　　load_area1.play();
　　}
　　//終わらないうちは終了を待つ
　　else
　　{
　　　gotoAndPlay( 2 );
　　}

　・フレーム５

　　//ムービー１の再生が終了した場合
　　if( end_flg )
　　{
　　　//ムービー１を非表示・停止し、ムービー２を再生する
　　　load_area1._visible = false;
　　　load_area1.stop();

　　　load_area2._visible = true;
　　　load_area2.play();

　　　//メインのタイムラインはここで止める
　　　stop();
　　}
　　else
　　{
　　　//ムービー１の再生終了を待つ
　　　gotoAndPlay( 4 );
　　}

完了率は、ムービー１とムービー２を合わせた完了率が、per という変数にパーセントで入ります。ダイナミックテキストで表示するか、プログレスバーの描画などに利用してください。
ロード中に実行するアニメはフレーム３まで、load_area1 と 2 はフレーム５まで表示するようにします、

先述の通り、loadMovie を実行すると、ダウンロード演算が行われるたびに data というイベントが発生します。
このイベントを利用して、load_area1 と 2 はロードが完了するまで非表示にし、タイムラインを止めておきます。
次のスクリプトを、それぞれに設定してください。

　onClipEvent(data)
　{
　　//最初は非表示にし、タイムラインを止めておく
　　this._visible = false;
　　this.stop();
　}

あとは必要に応じて、load_area1 と 2 の表示／非表示を切り替えたり、タイムラインを動かしたりするだけです。
どちらのムービーも、読み込まれた後は同じステージに並んだムービークリップ同士になり、スクリプト自体はそれほど難しくはないと思います。

長くなってすみませんでした。
不明な点がありましたら、補足してください。