Excelでの文字抽出

質問

おはようございます。

以下のような操作をしたいのですが、
アドバイスをよろしくお願いします。
テキストファイルになります。

変更前
日本,a,b,c
中国,a,d,f,g
ソ連,b,f,h

変更後
a 日本 中国
b 日本 ソ連
c 日本
d 中国
f 中国 ソ連
g 中国
h ソ連

回答No.3

marumaru_a_w · ベストアンサー

Public Sub Test()
Const intGStartCol As Integer = 1 'A グループ名開始列位置
Const intGStartRow As Integer = 1 ' グループ名開始行位置
Const intMStartCol As Integer = 1 'A メンバー名開始列位置
Const intMStartRow As Integer = 5 ' メンバー名開始行位置
Dim shtTestIn As Excel.Worksheet
Dim shtTestOut As Excel.Worksheet
Dim varValue As Variant ' データ取得変数
Dim strGName As String ' グループ名退避
Dim strMName As String ' メンバー名退避
Dim intGCol As Integer ' グループ名列位置
Dim intGRow As Integer ' グループ名行位置
Dim intMCol As Integer ' メンバー名列位置
Dim intMRow As Integer ' メンバー名行位置

'読み込みSheetを設定
Set shtTestIn = Excel.ActiveSheet
'書き込みSheetを設定
Set shtTestOut = Excel.ActiveSheet

'初期値を設定
intMRow = intMStartRow
Do
'メンバーの出力先を初期値
intMCol = intMStartCol + 1
varValue = shtTestOut.Cells(intMRow, intMStartCol).Value
If VBA.VarType(varValue) = VBA.vbEmpty Then
'値がなくなったら終了
Exit Do
End If
'メンバー名退避
strMName = VBA.CStr(varValue)
'グループの読み取り行を初期化
intGRow = intGStartRow
Do 'グループの行読み取り
varValue = shtTestIn.Cells(intGRow, intGStartCol).Value
If VBA.VarType(varValue) = VBA.vbEmpty Then
'値がなくなったら終了
Exit Do
End If
'グループ名退避
strGName = VBA.CStr(varValue)
'グループの読み取り列を初期化
intGCol = intGStartCol + 1
Do 'グループの列読み取り
varValue = shtTestIn.Cells(intGRow, intGCol).Value
If VBA.VarType(varValue) = VBA.vbEmpty Then
'値がなくなったら終了
Exit Do
End If
'メンバーの比較
If VBA.StrComp(strMName, varValue) = 0 Then
'メンバーの横にグループをセット
shtTestOut.Cells(intMRow, intMCol).Value = strGName
intMCol = intMCol + 1
Exit Do
End If
intGCol = intGCol + 1
Loop
intGRow = intGRow + 1
Loop
intMRow = intMRow + 1
Loop

End Sub

一応、VBEでソースを書いてみました
ソースに手を加えないとだめですが大体の動きはしていると思います。
Office2003で確認しましたが新しい関数を使用してないので大丈夫だと思います

お礼

早速のご回答および
丁寧なご指導ありがとうございました。

おかげさまで、うまくいきました。
本当に感謝です。

回答No.2

marumaru_a_w

はじめまして、marumaru_a_wといいます。
Ecxelですよね？
日本,a,b,c
中国,a,d,f,g
ソ連,b,f,h
とあるのは
----------------
| A |B|C|D|E|
----------------
1|日本|a|b|c| |
----------------
2|中国|a|d|f|g|
----------------
3|ソ連|b|f|h| |
----------------
上記のようにすべてセルごとに分かれているのでしょうか？
それとも
---------------
| A |
---------------
1|日本,a,b,c |
---------------
2|中国,a,d,f,g|
---------------
3|ソ連,b,f,h |
---------------
上記のように１セルに情報がすべて入っているのでしょうか？
データの入り方によっても処理が変わってくると思いますのでその辺をはっきり教えてもらえるとアドバイスがしやすくなると思います。

補足

最初の方で、すべてセルごとに分かれています。
よろしくお願いします。

回答No.1

うぃず（@Wizard_Zero）

Wizard_Zeroと申します。

「アドバイス」と言われても、この処理を最初から最後まで説明すると、結構な量になりますよ・・・。

どこまで考えて、どこが出来ないのか教えてください。

流れを簡単に書くとすれば・・・
1.文字列配列を用意
2.ファイルを読み込みながら、記号にあわせて配列に分配
3.ファイルに出力

補足

すいません。
流れは以下のようにしたいと思っています。
よろしくお願いします。

まず、グループが日本で、メンバーが、a,b,cという前提になります。

1.最初にシート1にメンバ(a,b,c)を入力しておきます。
2.次にシート2にグループとメンバ(変更前)を出力しておく。
3.シート1のメンバが、シート2のグループ(行を検索)に所属しているか、全部のグループ(行)を検索する。
4.所属しているグループがあれば(一致)、メンバの横のセルに付け加えていく

疑問点
・行の中に、特定の値が含まれているかを検索する方法