プログラム作成アドバイス下さい（初心者）

質問

N88互換BASICのフリーソフトにて作成しています。

正の実数aの平方根ルートa（a^1/2）をニュートンラプソン法で求めるプログラムを組む問題です。下記が手順です。

1、定数aを入力（a>0）、今回解くべき方程式は、f(x)=x^2-a=0であるから、その導関数はf(x)=2xである。
2、初期値X0にaを代入し、X1を求める。
3、X0とX1から、相対誤差E=|(X1-X0)/X0|を求める。
4、X1とEを画面表示する。
5、収束判定定数EPSの値を10^-5とし、これと相対誤差を比較する。
6、EがEPSより大きければ、得られた根は収束が足りないと思われるので、次のX2を求める。（2、へ移動）
EがEPSより小さければ、十分な精度で収束したと考え、7へ。
7、最後にSQR(a)を画面表示して終了。

とりあえず下記のように進めましたが続きが分かりません。続きはどのような計算ですか？

10 Rem 正の実数a平方根a^1/2を、ニュートン・ラプソン法で求めるプログラムを組む問題。
20 Cls
30 Print "正の実数の平方根を求めます。"
40 EPS = 0.00001
50 INPUT "a=";A
60 IF A<=0 THEN END ELSE GOTO 70
70 Print "a=";
80 Print USING; "#.####^^^^"; A

面倒なプログラムですが、宜しくお願いします。

回答No.1

JaritenCat · ベストアンサー

手順1～7のうち、1の半分までできているようですね。
ニュートン法ですから、x1=x0-f(x0)/f'(x0)を計算してx0とx1がほぼ同じ値になるまで繰り返します。繰り返すときは、今計算したx1をx0に入れて次のx1を計算するわけです。

参考まで。
100 rem 正の実数aの平方根ルートa（a^1/2）をニュートンラプソン法で求めるプログラムを組む問題
110 rem 1、定数aを入力（a>0）、今回解くべき方程式は、f(x)=x^2-a=0であるから、その導関数はf'(x)=2xである。
120 input "a=? ",a
130 if a<=0 goto 120
140 rem 2、初期値X0にaを代入し、X1を求める。
150 x0 = a
160 fx = x0^2-a
170 ffx = 2*x0
180 x1 = x0-fx/ffx
190 rem 3、X0とX1から、相対誤差E=|(X1-X0)/X0|を求める。
200 e=abs((x1-x0)/x0)
210 rem 4、X1とEを画面表示する。
220 print "X1=";x1,"E=";e
240 rem 5、収束判定定数EPSの値を10^-5とし、これと相対誤差を比較する。
250 rem 6、EがEPSより大きければ、得られた根は収束が足りないと思われるので、次のX2を求める。（2、へ移動）
260 rem EがEPSより小さければ、十分な精度で収束したと考え、7へ。
270 if e >= 10E-05 then x0=x1:goto 160
280 rem 7、最後にSQR(a)を画面表示して終了。
290 print "SQR(";a;")=";x1
300 end

お礼

毎回面倒なプログラムのアドバイス有難うございます。
とても助かります。感謝致します。

200のe=abs((x1-x0)/x0)の「abs」と、290のprint "SQR(";a;")=";x1の「SQR」は何を示しているのでしょうか？

今後、まだ質問があるかと思いますが、アドバイスを頂けると光栄です。

回答No.2

JaritenCat

「abs」
absは絶対値(absolution value)を計算します。
相対誤差は負になる場合もあるので、収束判定する場合は絶対値の計算が必要です。

「SQR」
print文のなかで"に囲まれているので、単純に文字列ですが、もともとの意味は、平方根(square root)です。
BASICではsqr(2)と書けば√2の値を計算してくれるsqr関数もあるのですが・・・

お礼

絶対値と平方根の意味だったのですね。
絶対値はabsではなく、||のバーで挟んでも結果表示されるんでしょうか。
ありがとうございました。