Arduinoでタンクに自動補給

質問

回路図の様にフロートSW2個を水を入れるタンクの上と下にセット
タンクが空になったら（上のSW1オフ、下のSW2オフ）ポンプ稼働させて
満タン（上のSW1オン、下のSW2オン）になったらポンプ停止するスケッチを作りたいです。
水が減っていく途中の状態ではポンプ停止のままで
水を補給している途中の状態ではポンプ稼働にしたままにしたいのですがどちらの状態も（上のSW1オフ、下のSW2オン）になりますがどうスケッチを書いたら良いのか解りません

基本的にArduinoのスケッチを理解できてませんのでネット上の参考になりそうなコードをコピーして利用してます。
参考例がありそうで見つからないので宜しくおねがいします。

回答No.3

koujikuu · ベストアンサー

モーター稼働時間制限を入れてあります (現在60秒)
最大稼働時間を過ぎるとモーターを停止し、エラーランプ D13 が点滅します
復帰にはリセットスイッチを押します

シリアルモニタに状況を出力して確認
スイッチ用 内蔵プルアップでは弱いので、外部プルアップ抵抗が必要になると思われます。

#define SW1 2 // D2 full on
#define SW2 3 // D3 empty off
#define SW_ON LOW
#define SW_OFF HIGH
#define SW1_READ() digitalRead( SW1 )
#define SW2_READ() digitalRead( SW2 )
#define MOTOR 6 // D6
#define MOTOR_ON() digitalWrite( MOTOR , HIGH )
#define MOTOR_OFF() digitalWrite( MOTOR , LOW )
#define MOTOR_CNT_MAX 60 // 60s モーター最大稼働時間

unsigned int motor_cnt = 0;

void setup() {
Serial.begin(9600);
Serial.println("Arduino Program Start !!");
pinMode( SW1 , INPUT_PULLUP );
pinMode( SW2 , INPUT_PULLUP );
pinMode( MOTOR , OUTPUT );
pinMode( 13 , OUTPUT ); // error lamp
MOTOR_OFF();
}

void loop() {
if ( SW1_READ() == SW_ON ){ // 上部フロートSWチェック
Serial.println("motor off");
MOTOR_OFF();
motor_cnt = 0;
}
if ( SW2_READ() == SW_OFF && SW1_READ() == SW_OFF ){ // 下部フロートSWチェック
MOTOR_ON();
}
if ( digitalRead( MOTOR ) == HIGH ){ // モーター稼働時間チェック
Serial.print("motor on ");
Serial.print( motor_cnt , DEC );
Serial.println(" s ");
motor_cnt++;
if ( motor_cnt > MOTOR_CNT_MAX ){
MOTOR_OFF();
Serial.println(" --- SENSOR ERROR !! --- ");
while(1){
digitalWrite( 13 , 1 - digitalRead( 13 ) ); // エラーランプ点滅
delay(200);
} // while
}
}
delay( 1000 ); // 1s
}

お礼

思い通りの動作できました。エラーランプまで付加して頂きごありがとうございます。
タンクの満タンまでのタイムを測り実際より長めの時間を設定します。
基板への作り込みの際にはプルアップ抵抗も外付けにします

koujikuuさんには以前もお世話になりましたけどプログラムが自由に書ける人って羨ましいです。少しでも理解して今後役立てるようがんばります。
本当にご親切に感謝いたします。

回答No.2

cwdecoder

Ｎｏ．１です。
フロートスイッチが壊れた場合の対策も考えておいたほうがいいでしょうね。
一定時間以上のポンプ動作続いた場合は停止させて、万一、オーバーフローしたとしても被害を最小限にするなど・・・。

回答No.1

cwdecoder

SW1,SW2が何を意味しているのか分かりませんが、ＳＷ１とＳＷ２が違う高さについていて、ＳＷ１、ＳＷ２が両方オフになったら、ポンプを始動、ＳＷ１、ＳＷ２両方オンになれば、ポンプ停止したいということでしょうか？

であれば、一旦ＳＷ１＝オンになったらＳＷ２＝オフになるまでポンプ停止。
一旦ＳＷ２＝オフになったら、ＳＷ１＝オンになるまでポンプ稼働すればいいだけの話ではないでしょうか。

私はＣ言語やアセンブラしか知りませんが、何の言語でも一緒だと思います。

お礼

SW1,SW2は磁石を内臓したフロートでその浮き沈みでリードスイッチが動作するものです

〇〇になるまで動作（HIGHとかLOW）を継続するというプログラムをどう書いた良いのか解りません
宜しくお願いします。