Excel vba ListVew 右揃え

質問

Excel vba ユーザーフォームにListVewを作成し、数値の部分は「，」付で右揃えにしたいのですが、全て左揃えで表示されます。右揃えにするにはどうしたら良いでしょうか？
以下のコードで使用しています。
　 'ListVew1に書出し
Set rng = ActiveSheet.Cells(1, 1).CurrentRegion
With 実績データ確認.ListView2
For i = 2 To rng.Rows.Count
.ListItems.Add.Text = rng(i, 18).Value
k = 1
For j = 19 To 28
.ListItems(i - 1).SubItems(k) = rng(i, j).Value
.ListItems(i - 1).ListSubItems(k).ForeColor = rng(i, j).Font.Color
k = k + 1
Next
Next
End With

回答No.2

imogasi

Private Sub CommandButton2_Click()
With ListView1
''プロパティ
.View = lvwReport ''表示
.LabelEdit = lvwManual ''ラベルの編集
.HideSelection = False ''選択の自動解除
.AllowColumnReorder = True ''列幅の変更を許可
.FullRowSelect = True ''行全体を選択
.Gridlines = True ''グリッド線
''列見出し
.ColumnHeaders.Add , "_コード", "コード", 46
.ColumnHeaders.Add , "_View", "名称", 46
.ColumnHeaders.Add , "_Text", "計数", 60
.ColumnHeaders(3).Alignment = lvwColumnRight '<==ポイント．計数列を右詰めにする例。

End With

'---
Dim i As Long, WS As Worksheet
Set WS = Worksheets("Sheet1")

'２～６行目のセルを追加
For i = 2 To 6
'左からText,SubItems(index…)の順
With ListView1
.AllowColumnReorder = False
End With
With ListView1.ListItems.Add
.Text = WS.Cells(i, 1)
.SubItems(1) = WS.Cells(i, 2)
.SubItems(2) = WS.Cells(i, 3)
End With
Next i
End Sub
ーーー
エクセルのＳｈｅｅｔ１のＡ１：Ｃ６に
コード 名称 　計数
111 あ 123
222 い 234
333 う 456
444 え 3456
777 お 23456
とテストデータを置いて、実行しました。
第3列は右詰めになりました。
（注）上記CommandButton2の２には意味はありません。
ユーザーフォｒムに１つのリストビューと１つのコマンドボタンを貼り付け
コマンドボタンをクリックして、内容を表示させる例です。
ＷＥＢ記事を寄せ集めて修正したものです。言いたいことは、WEB記事を検索すればわかるということです。

回答No.1

imogasi

listbox なら
ユーザーフォームに
リストボックス１つ
コマンドボタン１つ
設けて、コマンドボタンのクリックイベントに
Private Sub CommandButton1_Click()
UserForm1.ListBox1.AddItem Format(12333, "#,##0")
UserForm1.ListBox1.TextAlign = 3
UserForm1.ListBox1.AddItem Format(1233344, "#,##0")
UserForm1.ListBox1.AddItem Format(123, "#,##0")
End Sub
で右詰めになったが。
リストビューではどうかな。

お礼

解決しました。有難うございます。