EXCELVBA 自動で表にカンマ・罫線を入れたい

質問

お世話になります。

添付の左図の様な表があります。

この表に対して「罫線」というマクロのボタンをクリックしたら右図のようにしたいのです。

列は[担当者]・[区分]＋該当月のカレンダー分あります。(1日～30日or31日)

やりたいこと

・一人の担当者につき区分がA～Jまであります(固定)。A～Fまでカンマ表示させたい。
(添付左図はすでにカンマ表示になっていますが、本当はカンマ表示されていません)
このA～Fのカンマ処理を人数分繰り返す(人数は可変)
・担当者毎(A～J)に太枠で囲みたい

お忙しいところ恐縮ですが、どなたかロジックをご教授いただけますでしょうか。
よろしくお願い致します。

環境 EXCEL2013 Windows7

回答No.2

nishi6 · ベストアンサー

最初、A～Jを何度も列だと間違えていました。そのため「A～Fまでカンマ表示」を失念してしまいました。
添付図をよく見ると「G～J」列は小数点２桁ですね。

一括にカンマを設定していた処理を担当者ごとにしました。

Sub 罫線()
　　Dim columnsCnt As Integer　　'列数

　　Application.ScreenUpdating = False

　　Range("A1").CurrentRegion.Select
　　With Selection
　　　　columnsCnt = .Columns.Count
　　　　'罫線
　　　　.Borders.LineStyle = xlContinuous
　　End With

　　Dim rw As Long　　'行カウンタ

　　With Range("A2")
　　　　While .Offset(rw, 0) <> ""
　　　　　　'カンマ(設定箇所を修正)
　　　　　　With Range(.Offset(rw, 2), .Offset(rw + 5, columnsCnt - 1))
　　　　　　　　.Style = "Comma [0]"
　　　　　　End With

　　　　　　With Range(.Offset(rw, 0), .Offset(rw + 9, columnsCnt - 1))
　　　　　　　　'担当者ごとに囲む
　　　　　　　　.Borders(xlEdgeLeft).Weight = xlMedium
　　　　　　　　.Borders(xlEdgeTop).Weight = xlMedium
　　　　　　　　.Borders(xlEdgeBottom).Weight = xlMedium
　　　　　　　　.Borders(xlEdgeRight).Weight = xlMedium
　　　　　　End With

　　　　　　rw = rw + 10
　　　　Wend
　　End With

　　Range("A1").Select
　　Application.ScreenUpdating = True
End Sub

お礼

nishi6さん、ご連絡ありがとうございました！

ご教授いただきました方法で理想通りの結果になりました！！

このたびは何度も細かなご説明いただきまして本当にありがとうございました！！助かりました。

回答No.1

nishi6

こんな感じでしょうか。標準モジュールです。（Excel2010)

Sub 罫線()
　　Dim columnsCnt As Integer　　'列数

　　Application.ScreenUpdating = False

　　Range("A1").CurrentRegion.Select
　　With Selection
　　　　columnsCnt = .Columns.Count
　　　　'罫線
　　　　.Borders.LineStyle = xlContinuous
　　　　'カンマ
　　　　.Offset(1, 2).Resize(.Rows.Count - 1, .Columns.Count - 2).Select
　　　　Selection.Style = "Comma [0]"
　　End With

　　Dim rw As Long　　'行カウンタ

　　With Range("A2")
　　　　While .Offset(rw, 0) <> ""
　　　　　　With Range(.Offset(rw, 0), .Offset(rw + 9, columnsCnt - 1))
　　　　　　　　'担当者ごとに囲む
　　　　　　　　.Borders(xlEdgeLeft).Weight = xlMedium
　　　　　　　　.Borders(xlEdgeTop).Weight = xlMedium
　　　　　　　　.Borders(xlEdgeBottom).Weight = xlMedium
　　　　　　　　.Borders(xlEdgeRight).Weight = xlMedium
　　　　　　End With

　　　　　　rw = rw + 10
　　　　Wend
　　End With

　　Range("A1").Select
　　Application.ScreenUpdating = True
End Sub

補足

nishi6さん、ご連絡ありがとうございました。
お返事が遅くなりまして大変申し訳ございませんでした。

細かなロジックをご提示いただきましてありがとうございました！

早速試してみたのですが、私のやり方がまずいのか、区分A～Fのみカンマ表示にしたかったのですが、A～Jまで全てカンマが入ってしまいました・・・

何度も申し訳ありません。。