スクリプト3.0

質問

本のスクリプトが記述してある本やネットのページ探してます。
その他、スクリプト見本ページ

回答No.1

BlurFiltan · ベストアンサー

ActionScript 3.0 設定の 新規ドキュメント を作成し，
メインタイムライン の フレーム1 に書く(コピペする)スクリプト例です↓。

//========================================
//---ムービーの設定---
[SWF(backgroundColor="#FFFFFF",frameRate="20",width="400",height="300")]

//---XMLのURLの設定---
var xml_url:URLRequest=new URLRequest("http://www3.nhk.or.jp/rss/news/cat5.xml");

//---テキストフィールドの用意---

//テキストフィールドの参照を入れる配列
var txt_arr:Array = new Array();

//各テキストフィールドの作成＆配置
for (var i:int = 0; i<=9; i++) {
txt_arr[i] = new TextField();
txt_arr[i].width=380;
txt_arr[i].height=25;
txt_arr[i].x=10;
txt_arr[i].y=40+25*i;
txt_arr[i].border=true;
txt_arr[i].background=true;
txt_arr[i].backgroundColor=0xFFFFFF;
txt_arr[i].selectable=false;
addChild(txt_arr[i]);
//マウスオーバー時に関数 overFunc を実行
txt_arr[i].addEventListener(MouseEvent.MOUSE_OVER,overFunc);
//マウスアウト時に関数 outFunc を実行
txt_arr[i].addEventListener(MouseEvent.MOUSE_OUT,outFunc);
}

//関数 overFunc の定義
function overFunc(e:MouseEvent):void {
e.currentTarget.backgroundColor=0xCCCCCC;
}

//関数 outFunc の定義
function outFunc(e:MouseEvent):void {
e.currentTarget.backgroundColor=0xFFFFFF;
}

//---XMLのロード＆表示---

//XMLのローダーを作成
var xml_ld:URLLoader = new URLLoader();

//XMLオブジェクトの宣言
var xml_obj:XML;

//開くページのURLを入れるDictionaryを用意
var page_dic = new Dictionary();

//XMLのロードを開始
xml_ld.load(xml_url);

//XMLのロード完了時に関数 compFunc を実行
xml_ld.addEventListener(Event.COMPLETE, compFunc);

//関数 compFunc の定義
function compFunc(e:Event):void {
//XMLオブジェクトにXMLデータを代入
xml_obj=new XML(xml_ld.data);
//
for (i=0; i<=9; i++) {
//各テキストフィールドにタイトルを表示
txt_arr[i].text=xml_obj.children()[0].child("item")[i].child("title")[0];
//Dictionaryの各テキストフィールドキーにURLRequestを代入
page_dic[txt_arr[i]]=new URLRequest(xml_obj.children()[0].child("item")[i].child("link")[0]);
//各テキストフィールドクリック時に関数 openPage を実行
txt_arr[i].addEventListener(MouseEvent.CLICK,openPage);
}
}

//関数 openPage の定義
function openPage(e:MouseEvent):void {
navigateToURL(page_dic[e.currentTarget],"_blank");
}
//========================================

あとは
パブリッシュやムービープレビューするなどして
動作確認をしてみてください。

※ XMLのURLが途中省略されてもし見えない場合↓
エイチティーティーピー://www3.nhk.or.jp/rss/news/cat5.xml
です。

※ グローバルセキュリティ警告が出た場合
「グローバルセキュリティ設定パネル」で
http://www.macromedia.com/support/documentation/jp/flashplayer/help/settings_manager04a.html
作成した SWF を含むフォルダなどのセキュリティを解除(登録)してください。

お礼

基本コピペ魔改造なんで
勉強になります。
いろいろやり方学べて助かりました。
ｂｙ、ＳＭ