解決済み

エクセルの表引き

  • すぐに回答を!
  • 質問No.7315510
  • 閲覧数109
  • ありがとう数2
  • 気になる数0
  • 回答数2
  • コメント数0

お礼率 82% (265/321)

こんにちは いつもお世話になっています。

Sheet1に以下の表があります。
すみません、表示がうまくいかず、A列には文字列、B列には数字が入ります。
A列に数字があるように表示されていましたらB列に表示されているものとしてみてください。

Sheet1
A        B
和歌山   2
愛知   3
東京   1
大阪   2
栃木   1
石川   3

A列のデータに重複はなく、B列のデータには重複があります。
B列の数字を検索値として振り分けるような形でA列の値を表引きしたいです。
表引き先は
Sheet2のB列の複数セルに1が入力済みの状態。
Sheet3のB列の複数セルに2が入力済みの状態。
Sheet4のB列の複数セルに3が入力済みの状態。
例えば
Sheet2
A        B
   1
   1
   1
   1
   1

Sheet3
A        B
   2
   2
   2
   2
   2

Sheet4
A        B
   3
   3
   3
   3
   3

以上の各シートが以下のようになるようにしたいです。

Sheet2
A     B
東京1
栃木1
1
1
1

Sheet3
A     B
和歌山2
大阪2
2
2
2

Sheet4
A     B
愛知3
石川3
3
3
3


Sheet2-4のA列に各B列のデータに一致する値をSheet1から表引きしたいです。例えばSheet2に関して、東京、栃木と出てしまったら後のA列は空欄になるようにしたいです。A列数字が表示されていたらB列にあるものとしてください。

フィルタとかでの手作業でなく、何とか関数で持ってこられないでしょうか。
作業列とか必要でしたら教えてください。
わかりにくい表現ですみません。
よろしくお願いします。

質問者が選んだベストアンサー

  • 回答No.2

ベストアンサー率 66% (5277/7940)

ご利用のエクセルのバージョンは幾つですか。ご相談投稿では,必ずご利用のソフトのバージョンまで明記することも憶えてください。

例えばExcel2007以降なら,各シートのA1に
=INDEX(Sheet1!A:A,SMALL(IF(Sheet1!B:B=B1,ROW(B:B),9999),ROW(A1)))&""
と記入してコントロールキーとシフトキーを押しながらEnterで入力し,下向けにコピーして入れておきます。


Excel2003までを使っているなら,
シート1のC1に
=B1&TEXT(COUNTIF($B$1:B1,B1),"-0000")
と記入してリスト下端までコピーして埋めておき,

各シートのA1には
=IF(ROW(A1)>COUNTIF(Sheet1!B:B,B1),"",INDEX(Sheet1!A:A,MATCH(B1&TEXT(ROW(A1),"-0000"),Sheet1!C:C,0)))
と記入してリスト下端まで埋めておきます。
お礼コメント
5goma

お礼率 82% (265/321)

keithin 様 ありがとうございました。お蔭様で解決しました。
バージョンを書かなくてすみませんでした。
両方作っていただいてありがとうございました。
大切に使わせていただきます。
簡単で恐縮ですが、お礼申し上げます。
投稿日時 - 2012-02-20 07:25:27
感謝経済

その他の回答 (全1件)

  • 回答No.1

ベストアンサー率 38% (1910/4994)

一例です。
配列数式を使用していますので若干処理が遅くなります。
各シートのA1に次の数式を貼り付け、入力完了時にShift+Ctrl+Enterキーを
同時押下後、下方向に必要分コピーして下さい。
対象範囲は100行としていますので数式内の100の値を変更して下さい。
=IF(COUNTIF(Sheet1!B:B,B1)>=ROW(A1),INDEX(Sheet1!A:A,SMALL(IF(Sheet1!$B$1:$B$100=B1,ROW(Sheet1!$A$1:$A$100),9999),ROW(A1))),"")
お礼コメント
5goma

お礼率 82% (265/321)

mu2011 様 ありがとうございました。お蔭様で解決しました。
大変勉強になりました。
簡単で恐縮ですが、お礼申し上げます。
投稿日時 - 2012-02-20 07:22:54
AIエージェント「あい」

こんにちは。AIエージェントの「あい」です。
あなたの悩みに、OKWAVE 3,500万件のQ&Aを分析して最適な回答をご提案します。

関連するQ&A
このやり方知ってる!同じこと困ったことある。経験を教えて!
このQ&Aにはまだコメントがありません。
あなたの思ったこと、知っていることをここにコメントしてみましょう。

その他の関連するQ&A、テーマをキーワードで探す

キーワードでQ&A、テーマを検索する

特集


感謝指数によるOK-チップ配布スタート!

ピックアップ

ページ先頭へ