エクセルの関数教えてください

質問

いつもお世話になっております。

郵便料金を反映させようと思い
ここで皆様のお力を借りて

=IF(AND(Q7<=30,Q7<=0),0,CHOOSE(Q7,180,210,290,290,340,340,340,340,340,450,450,450,450,"要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力"))

という数式を入れて1～29までは反映させることが
出来たんですが30以上に「0」又は「宅急便」と表示させるにはどうしたら
いいでしょうか？

よろしくお願い致します。

ＯＳは98　エクセルは97です。

回答No.3

aptiva · ベストアンサー

まず最初のANDは間違ってませんか？
OR(Q7>=30,Q7<=0)のつもりだったのでは？

もし、Q7が30以上の時、「0」と表示させるのであれば、

=IF(OR(Q7>=30,Q7<=0),0,CHOOSE(Q7,180,210,290,290,340,340,340,340,340,450,450,450,450,"要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力"))

もし、Q7が30以上の時、「宅急便」と表示させるのであれば、

=IF(Q7<=0,0,IF(Q7>=30,"宅急便",CHOOSE(Q7,180,210,290,290,340,340,340,340,340,450,450,450,450,"要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力")))

で、いいはずです。

お礼

ありがとうございます。

すいません「30以上」というのを汲んでくださって
助かりました。30以上は弊社負担なのをきれいさっぱり
忘れていたのでとても助かりました。

まさにこの通りです(~_~;)
感謝感謝です。

回答No.5

aptiva

もう一度です。

質問の内容が、Q7が30以上の時ということなので、

#2の方の式を補足させて頂くと

=IF(ISNUMBER(Q7),IF(Q7<=0,0,IF(Q7>=30,"宅急便",VLOOKUP(Q7,Sheet2!$A$1:$B$29,2))),"")

あと、参照するシート(Sheet2)のデータは以下のようになりますね。(15～29の分）

A　　B
1　180
2　210
3　290
4　290
5　340
6　340
7　340
8　340
9　340
10　450
11　450
12　450
13　450
14　要手入力
15　要手入力
16　要手入力
17　要手入力
18　要手入力
19　要手入力
20　要手入力
21　要手入力
22　要手入力
23　要手入力
24　要手入力
25　要手入力
26　要手入力
27　要手入力
28　要手入力
29　要手入力

お礼

すぐのレスありがとうございます。

料金変わった時のメンテナンスを楽にするために
時間見つけてこっちに変更します。
（この仕事の〆切午前中なんですよ）

しかしみなさまの知識には脱帽です。
（私がおばかなんですが）

どうもありがとうございます。

回答No.4

aptiva

#3のものです。

なるほど、
#2の回答いいですね。
CHOOSE関数だと、29個までの条件しか指定できないですし、料金が変わった時のメンテナンスも、楽そうですね。

#2の回答に一票です。

お礼

maruru01さんにはいつも助けてもらってます。

爪の垢が欲しいくらいです

回答No.2

maruru01

こんにちは。maruru01です。

あまりたくさんの条件をCHOOSE関数で記述すると、見づらいので、別の場所に対応表を作成しておいて、それを参照するのはどうでしょうか。
例えば、Sheet2のA1～B15に、

A　　B
1　180
2　210
3　290
4　290
5　340
6　340
7　340
8　340
9　340
10　450
11　450
12　450
13　450
14　要手入力
30　宅急便

と入力しておきます。
そして、郵便料金を表示させるセルに、

=IF(ISNUMBER(Q7),IF(Q7<=0,0,VLOOKUP(Q7,Sheet2!$A$1:$B$15,2)),"")

と入力します。
一応、Q7が数値以外の場合（空白も含む）は、「""」にする処理も付けておきました。

お礼

maruru01さんいつもありがとうございます♪

本当に助かります。
ＬＯＯＫＵＰ機能って便利ですね。
参考本読んでてもよく出てきますし。
問題はそれを理解できる脳みそが私に備わってないことですね。(T_T)

これからもよろしくお願い致します。

回答No.1

hinebot

IFの中のAND関数が変に思います。

AND(Q7<=30,Q7<=0)
となってますが、これだと「30以下かつ0以下」すなわち「0以下」で真(TRUE)、それ以外は偽(FALSE)ということです。
「30以上または0以下」と「1～29」で別けるべきと思われますので、式を

=IF(OR(Q7>=30,Q7<=0),0,CHOOSE(Q7,180,210,290,290,340,340,340,340,340,450,450,450,450,"要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力"))

とすれば、30以上でも"0"　となります。

応用として、いったん空いているセルに
=CHOOSE(Q7,180,210,290,290,340,340,340,340,340,450,450,450,450,"要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力","要手入力")
と入れます。仮にこのセルを"R7"としますね。

で目的のセルには
=IF(Q7<=0,0,IF(Q7>=30,"宅急便",R7))
と入れれば0以下なら「0」、1～29なら反映値、30以上なら「宅急便」とすることができます。
いったん、分割したのは、CHOOSE関数が長いためすっきりさせるためです。

お礼

hinebotさんありがとうございます。

なるほどこういうやり方もあるんですね。
勉強になります。