AS3.0にて、if...else if...を使いたいのですが、、

質問

AS3.0にて、if...else if...を使いたいのですが、、

"A_btn"を押すと"A"をaddChildします。
"B_btn"を押すと"B"をaddChildします。

"A"をaddChildする際に"B"がステージにあれば、まず"B"をremoveChildします。
"B"をaddChildする際に"A"がステージにあれば、まず"A"をremoveChildします。

今はaddChildは省略させていただきますが、

if("A"がステージにある場合){
removeChild(A);
}else if("B"がステージにある場合){
removeChild(B);
}

この("A"がステージにある場合)の部分はどう書けば良いのか分かりません。。
どなたか助けていただけないでしょうか？
よろしくお願いいたします。

回答No.2

BlurFiltan · ベストアンサー

「A」 が addChild されている状態とは
「A」 がどこかの階層の表示リストに存在するということです。
そたがってこの辺↓が使えると思います。

「ActionScript 3.0のイベント処理について デベロッパーセンター」
http://www.adobe.com/jp/devnet/actionscript/articles/event_handling_as3_08.html
> 表示オブジェクトがこのような表示リストに含まれていない場合、
> そのstageプロパティはNullです。

◎新規ドキュメントのフレーム1などに書くスクリプト例↓
----------------------
var A:Sprite = new Sprite();
A.graphics.beginFill(0xFF0000);
A.graphics.drawRect(0, 0, 50, 50);

trace(A.stage);
this.addChild(A);
trace(A.stage);
this.removeChild(A);
trace(A.stage);
----------------------

「制御」→「ムービープレビュー」 での出力結果↓

　 null
　 [object Stage]
　 null

◎if文を使った判定例↓
----------------------
var A:Sprite = new Sprite();
A.graphics.beginFill(0xFF0000);
A.graphics.drawRect(0, 0, 50, 50);

this.addChild(A);

//↓ 「//」 を付けたり取ったりして検証
//this.removeChild(A);

if(A.stage == null){
trace("Aはありません");
}

if(A.stage != null){
trace("Aはあります");
}
----------------------

～～～ 別法 ～～～～～～～～～～～～

getChildByName() を使っても調べられます。

「FlashゲームPG講座 For AS3.0」
より「インスタンスが表示リストに存在するか調べる」
http://hakuhin.jp/as3/container.html#CONTAINER_04

◎新規ドキュメントのフレーム1などに書くスクリプト例↓
----------------------
var A:Sprite = new Sprite();
A.graphics.beginFill(0xFF0000);
A.graphics.drawRect(0, 0, 50, 50);
A.name = "A";

trace(this.getChildByName("A"));
this.addChild(A);
trace(this.getChildByName("A"));
this.removeChild(A);
trace(this.getChildByName("A"));
----------------------

「制御」→「ムービープレビュー」 での出力結果↓

　 null
　 [object Sprite]
　 null

◎if文を使った判定例↓
----------------------
var A:Sprite = new Sprite();
A.graphics.beginFill(0xFF0000);
A.graphics.drawRect(0, 0, 50, 50);
A.name = "A";

this.addChild(A);

//↓ 「//」 を付けたり取ったりして検証
//this.removeChild(A);

if(this.getChildByName("A") == null){
trace("Aはありません");
}

if(this.getChildByName("A") != null){
trace("Aはあります");
}
----------------------

お礼

すごく丁寧なご回答どうもありがとうございます。
助かりました！

回答No.1

taregin

的外れな回答になっているかもしれませんが、
ステージ上にあるということは、ボタンが表示されているということなので、
A.visibleがtrueかfalseかで処理すればいいんじゃないでしょうか？

参考URL：

http://flashrave.org/as/visible/

お礼

すごく丁寧なご回答どうもありがとうございます。
助かりました！