コモンダイアログを表示したい

質問

Windows98／VisualBasic5.0を使用しています。
ファイル名を指定させるために、コモンダイアログを表示したいのですが方法がわかりません。
コントロールを貼り付ければよいのでしょうか？
初歩的な質問で申し訳ありませんが、よろしくお願いします。

回答No.1

sienna · ベストアンサー

標準ではありません。
使用する前にプロジェクトに追加する必要があります。

http://homepage1.nifty.com/Wan/vbb/vbb026-030.htm

参考URL：

http://homepage1.nifty.com/Wan/vbb/vbb026-030.htm

お礼

ありがとうございました。

回答No.3

noname#4564

> ファイル名を指定させるために、コモンダイアログを表示したいのですが方法がわかりません。

GetOpenFileNameを使います。
サンプルコードは書籍、WEB等で多数公開されています。
一例ですが、下記の要領。

Option Explicit

'[ファイルを開く]と[ファイルを保存]ダイアログボックスの為の構造体宣言
Private Type OPENFILENAME
lStructSize As Long '構造体のサイズ
HWndOwner As Long 'ダイアログボックスを所有するウィンドウのハンドル
hInstance As Long 'アプリケーション インスタンス
lpstrFilter As String 'フィルター
lpstrCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long 'デフォルトのフィルタ
lpstrFile As String '選択されたファイル名
nMaxFile As Long 'ファイル名の最大長
lpstrFileTitle As String
nMaxFileTitle As Long
lpstrInitialDir As String
lpstrTitle As String
flags As Long 'オプション
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type

'[ファイルを開く]ダイアログボックスを呼び出すAPI
Private Declare Function GetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" _
(pOpenfilename As OPENFILENAME) As Long

'OPENFILENAME構造体のflagsで指定する定数
Private Const OFN_READONLY As Long = &H1 '[読み取り専用]チェックボックスをオンにする
Private Const OFN_OVERWRITEPROMPT As Long = &H2 '選択したファイルが存在する場合の上書確認する
Private Const OFN_HIDEREADONLY As Long = &H4 '[読み取り専用]チェックボックスを表示しない
Private Const OFN_NOCHANGEDIR As Long = &H8 'ダイアログボックスを開いたときに現在のディレクトリを表示する
Private Const OFN_SHOWHELP As Long = &H10 'ダイアログ ボックスに [ヘルプ] ボタンを表示する
Private Const OFN_NOVALIDATE As Long = &H100 '無効な文字を含むファイル名を指定出来るようにする
Private Const OFN_ALLOWMULTISELECT As Long = &H200 'ファイル名リストボックスで複数選択を可能にする
Private Const OFN_EXTENSIONDIFFERENT As Long = &H400 'ファイル名の拡張子とlpstrDefExtで指定された拡張子が異なる
Private Const OFN_PATHMUSTEXIST As Long = &H800 '無効なパスを入力したときに警告メッセージを表示する
Private Const OFN_FILEMUSTEXIST As Long = &H1000 '既存のファイルだけ入力できるようにする
Private Const OFN_CREATEPROMPT As Long = &H2000 '現在存在しないファイルを作成するかを確認する
Private Const OFN_SHAREAWARE As Long = &H4000 '共有違反エラーを無視する
Private Const OFN_NOREADONLYRETURN As Long = &H8000 '読み取り専用属性を持たず、読み取り専用フォルダにないファイルを取得する
Private Const OFN_EXPLORER As Long = &H80000 'エクスプローラに似たダイアログボックスにする
Private Const OFN_NODEREFERENCELINKS As Long = &H100000 'ショートカットを実行しない
Private Const OFN_LONGNAMES As Long = &H200000 '長いファイル名を使用する

Public Function ShowOpenFileDlg(ByRef HWnd As Long, _
ByVal strDefault As String) As String
'****************************************************************************************
'機能概要：　[ファイルを開く]ダイアログを表示してファイル名を取得する。
'
'引　　数： HWnd ダイアログの親ウィンドウのハンドル
' strDefault デフォルトのパス。(ダイアログを開いた際に初期値として表示)
'
'
'戻 り 値： 選択されたファイル名。キャンセルされた場合は何も戻らない
'
'備　　考： 文字列の取り扱いに注意。
'
'****************************************************************************************

Dim ofn As OPENFILENAME
Dim strPath As String
Dim strTmp As String
Dim lngRet As Long
Dim i As Long

' ダイアログ ボックスのオプションを設定します。
With ofn
'親Windowの指定
.HWndOwner = HWnd
'アプリケーションのインスタンスを指定
.hInstance = 0
.lpstrCustomFilter = vbNullString
.nMaxCustFilter = 0
.lpfnHook = 0
.lpTemplateName = 0
.lCustData = 0
'フィルタの種類を設定
.lpstrFilter = "すべてのファイル (*.*)" & vbNullChar & "*.*" & vbNullChar
'アクティブなフィルタの番号を設定
.nFilterIndex = 1
'最大ファイル長の設定
.nMaxFile = 511
'ファイルのタイトルを受け取るポインタ
.lpstrFileTitle = String$(512, 0)
'ファイル名の最大長を設定
.nMaxFileTitle = 511
'デフォルトディレクトリの設定
.lpstrInitialDir = "" & strDefault
.lpstrDefExt = ""
'サイズの設定
.lStructSize = Len(ofn)
'ダイアログのタイトルを設定
.lpstrTitle = "ファイルを選択してください。"
'オプションの設定
.flags = OFN_HIDEREADONLY
End With

lngRet = GetOpenFileName(ofn)

If lngRet = 0 Then
ShowOpenFileDlg = ""
Exit Function
End If

' パスとファイル名を返します。
lngRet = InStr(ofn.lpstrFile, vbNullChar)

If lngRet <> 0 Then
strPath = Trim$(Left$(ofn.lpstrFile, lngRet - 1))
End If

ShowOpenFileDlg = strPath

End Function

補足

先ほどの質問にもご回答くださり、感謝いたします。
この場合、コモンダイアログコントロールがなくてもできるということでしょうか？

回答No.2

taknt

貼り付けるものは 参考ＵＲＬを見てみてください。

ページを戻ってけば ソースもあるので参考にしてみてください。

参考URL：

http://www.yecc.gr.jp/vb/prog/pricla/pri013.html

お礼

ありがとうございました。